Does anyone know how to add custom button on title bar with out having to draw while bar myself

[E1M1]

I cant figure out how this window roll up is made. http://www.actualtools.com/windowrollup/ Only method I know is how to draw title bar completely myself. I know that I can set ws_popup and then I am able to use my custom image as title bar, and draw buttons on it, but how is it possible to draw buttons with out such trick?

Window rollup I linked somehow creates button on title bar with out changing window style. Also it doesnt draw it's own window over target window.

Does anyone know how it's being done?

[guinness]

This might get you started >>

[Melba23]

guinness,

Good find.

I am constantly amazed at what AutoIt can do in the right hands.

M23

[E1M1]

This works but not the way I am looking for. This http://www.actualtools.com/windowrollup/ doesn't create any window over original window. It just acts as control.

[GEOSoft]

A long time back someone wrote a function to add things like a combobox to the title bar and I can't find it now. Perhaps someone else has saved the link or you may find it with enough searching.

I'm reasonably sure the principal would be the same.

[E1M1]

I remember I once saw example script that used winapi/uxtheme calls to draw custom title bar with out having to draw extra window or with out turning part of client area into title bar but I don't remember what keywords I used to search. Of if I searched for something at all. Sadly I dint add it into bookmarks. I usually add interesting finds to my bookmarks.

If I had that script I could try to write my script based on this..

All I remember is that scipt wasn't xskin or any other well known script.

Edited April 17, 2011 by E1M1

[jlv]

Actualtool's Window Rollup tool is one of the few that seem to get the roll-up/window-shade effect correct for all windows. Most tools that do this (like the Au3 script "Rollup-Pro") simply set the window height to 0 or 1, which works for many but not all windows. On Windows XP, that fails with all the ribbon-based Office programs. On Windows 7, it doesn't work for IE, Explorer and Cmd windows (both of which have a minimum height; e.g,. the Explorer window can't be resized that small). I'm not sure how Actual does it, but their program does this correctly.

(I've tried Rollup-Pro, and am looking for something quicker, less clunky, and that I can add hot-keys to... I actually don't want something that adds it's own titlebar button!)

[rover]

I remember I once saw example script that used winapi/uxtheme calls to draw custom title bar with out having to draw extra window or with out turning part of client area into title bar but I don't remember what keywords I used to search. Of if I searched for something at all. Sadly I dint add it into bookmarks. I usually add interesting finds to my bookmarks.

If I had that script I could try to write my script based on this..

All I remember is that scipt wasn't xskin or any other well known script.

@E1M1

Perhaps this is the post you have in mind.

WM_NCLBUTTONDOWN does not work like expected Costum titlebar

This example uses themes to paint a button on the titlebar caption area.

If this is what you want, see if the amount of code required is worth it to you.

*additional code still required*

*XP Only - does not work on Vista/7*

requires mode code, maybe DWM or another method for Vista/7

Note: The state and behaviour of the button follows titlebar button behaviour (min/max/close)

no focus state or focus highlighting, not clickable with spacebar,

no BCN_HOTITEMCHANGE message handling for dragging held down mouse between buttons

or hot focus transfer to other controls.

Note: This button is not a control so it does not get focus and cannot be tabbed to.

*Some custom themes have not properly handled a titlebar buttons clickable area

and may be clickable past the left border of last button max/min, also some themes do not have a pressed state image.

*Theme change requires code to correct button size/placement as it can move slightly off the titlebar

into the client area and to the left of its previous position.

Theme part metrics required to correct button placement.

You can use 'Window' theme for titlebar buttons that have same theme as min/max/close

or paint your own bitmap button.

*NOTE: This example does not have the required _WinAPI_DrawFrameControl() code

to create the button if the theme service is off or the classic theme is used.

see example in help file for GUIRegisterMsg().

*Gui resizing code should move the button relative to the changed width.

All of the UDF DLLCalls should be modified versions with a DllOpen() handle

for improved optimization.

*XP Only - does not work on Vista/7*

requires mode code, maybe DWM or another method for Vista/7

There is no end to it...

Edit1: additional verbiage

Edit2: removed unfinished/unnecessary code, added theme font code, a few additional changes, still XP only

expandcollapse popup

;Author: coded by rover for themes from example by Funkey 2k11
;WM_NCLBUTTONDOWN does not work like expected Costum titlebar
;http://www.autoitscript.com/forum/topic/125012-wm-nclbuttondown-does-not-work-like-expected/page__p__868177__fromsearch__1#entry868177
;Thanks to Yashied for the theme engine API's in WinAPIEx.au3

;#forceref not used in WinAPIEx.au3 and APIConstants.au3
;too many declared, but not used errors if this line used
;#AutoIt3Wrapper_au3check_parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6


#include <APIConstants.au3>
#include <FrameConstants.au3>
#include <GUIConstantsEx.au3>
#Include <Constants.au3>
#include <WinAPI.au3>
#Include <WinAPIEx.au3>
#include <WindowsConstants.au3>

If @OSVersion <> "WIN_XP" Then
    MsgBox(262144+48, "XP ONLY", "This only works on XP"&@CRLF&"Vista and 7 use DWM,"&@CRLF&"so a different method is required to do this")
    Exit
EndIf

Opt('MustDeclareVars', 1)


;need non-client area dimensions here
Global $tRECT = _WinAPI_CreateRectEx(300, 3, 40, 18)
;quick hack to set rect in non-client area
Global $tRECTx = _WinAPI_CreateRectEx(300, -22, 35, 16)
Global $msg, $nState = 1, $hTheme, $nPrev = -1, $fBtnTFont = True
Global $fNCKeyDn = False, $fNCKeyUp = False, $fBtnHot = False

Global $hGui = GUICreate("Title bar button", 500, 300, -1, -1, BitOR($GUI_SS_DEFAULT_GUI, $WS_SIZEBOX))
Global $cBtn1 = GUICtrlCreateButton("Disable", 40, 40, 100, 25)
Global $cBtn2 = GUICtrlCreateButton("Hide", 40, 100, 100, 25)
Global $cBtnTBar = GUICtrlCreateDummy()

$hTheme = _WinAPI_OpenThemeData($hGui, 'Button')
If @error Then $hTheme = 0
Global $tLOGFONT = _WinAPI_GetThemeFont($hTheme, 1, 1, $TMT_FONT)
;ConsoleWrite('- DllStructGetData($tLOGFONT, "FaceName") = ' & DllStructGetData($tLOGFONT, "FaceName") & @crlf)
Global $hFont = _WinAPI_CreateFontIndirect($tLOGFONT)
ConsoleWrite('@@ Debug(' & @ScriptLineNumber & ') : $hFont = ' & $hFont & @crlf & '>Error code: ' & @error & @crlf) ;### Debug Console
;no theme font, so use default
If $hFont = 0 Then
    $hFont = _WinAPI_GetStockObject($DEFAULT_GUI_FONT)
    $fBtnTFont = False
EndIf


GUIRegisterMsg($WM_THEMECHANGED, "_WinProc")
GUIRegisterMsg($WM_NCMOUSEMOVE, "_WinProc")
GUIRegisterMsg($WM_NCHITTEST, "_WinProc")
GUIRegisterMsg($WM_NCLBUTTONUP, "_WinProc")
GUIRegisterMsg($WM_NCLBUTTONDOWN, "_WinProc")
GUIRegisterMsg($WM_NCLBUTTONDBLCLK, "_WinProc")
GUIRegisterMsg($WM_NCACTIVATE, "_WinProc")
GUIRegisterMsg($WM_NCPAINT, "_WinProc")

GUISetState()

Do
    $msg = GUIGetMsg()
    Switch $msg
        Case $cBtnTBar;title/caption bar button
            ConsoleWrite("+ Title bar button clicked" & @CRLF)
        Case $cBtn1;enable/disable
            If $nState <> -1 Then
                Switch $nState
                    Case 1
                        $nState = 4
                        GUICtrlSetData($cBtn1, "Enable")
                    Case 4
                        $nState = 1
                        GUICtrlSetData($cBtn1, "Disable")
                EndSwitch
                _WinAPI_RedrawWindow($hGui, $tRECT, 0, BitOR($RDW_INVALIDATE, $RDW_FRAME))
            EndIf
        Case $cBtn2;hide/show
            Switch $nState
                Case -1
                    $nState = $nPrev
                    GUICtrlSetData($cBtn2, "Hide")
                    _WinAPI_RedrawWindow($hGui, $tRECT, 0, BitOR($RDW_INVALIDATE, $RDW_FRAME))
                Case Else
                    $nPrev = $nState
                    $nState = -1
                    GUICtrlSetData($cBtn2, "Show")
                    _WinAPI_SetWindowPos($hGui, -1, 0, 0, 0, 0, BitOR($SWP_FRAMECHANGED, $SWP_NOACTIVATE, $SWP_NOMOVE, $SWP_NOSIZE))
            EndSwitch
    EndSwitch

Until $msg = -3

If $hTheme <> 0 Then _WinAPI_CloseThemeData($hTheme)
If $hFont <> 0 Then _WinAPI_DeleteObject($hFont)
Exit

Func _WinProc($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg, $wParam, $lParam
    Local $hDC, $x, $y, $tPoint
    Switch $iMsg
        Case $WM_THEMECHANGED
            If $hTheme <> 0 Then _WinAPI_CloseThemeData($hTheme)
            If $hFont <> 0 Then _WinAPI_DeleteObject($hFont)
            $hTheme = _WinAPI_OpenThemeData($hWnd, 'Button')
            If @error Or $hTheme = 0 Then Return $GUI_RUNDEFMSG
            Local $tLOGFONT = _WinAPI_GetThemeFont($hTheme, 1, 1, $TMT_FONT)
            ;ConsoleWrite('- DllStructGetData($tLOGFONT, "FaceName") = ' & DllStructGetData($tLOGFONT, "FaceName") & @crlf)
            $hFont = _WinAPI_CreateFontIndirect($tLOGFONT)
            If $hFont = 0 Then
                $hFont = _WinAPI_GetStockObject($DEFAULT_GUI_FONT)
                $fBtnTFont = False
            Else
                $fBtnTFont = True
            EndIf
        Case $WM_NCMOUSEMOVE ;when mouse moves over or moves off of button, redraw button in Hot or Normal state
            If $hWnd <> $hgui Then Return $GUI_RUNDEFMSG
            ;when mouse moved off button, redraw button in Normal state
            If ($wParam = $HTCAPTION Or $wParam = $HTTOP) And ($nState = 2 Or $nState = 3) Then
                $nState = 1
                $fBtnHot = False
                _WinAPI_RedrawWindow($hWnd, $tRECT, 0, BitOR($RDW_INVALIDATE, $RDW_FRAME))
            EndIf
            ;when mouse moves over button, redraw button in Hot state
            If $wParam = $HTBORDER And $nState <> 4 And $nState <> -1 Then ;return from WM_NCHITTEST is HTBORDER
                $tPoint = DllStructCreate($tagPOINT)
                DllStructSetData($tPoint, 1, BitAND($lParam, 0x0000FFFF))
                DllStructSetData($tPoint, 2, BitShift($lParam, 16))
                _WinAPI_ScreenToClient($hWnd, $tPoint)
                If _WinAPI_PtInRect($tRECTx, $tPoint) Then
                    If $fBtnHot = False Then
                        $nState = 2
                        $fBtnHot = True
                        _WinAPI_RedrawWindow($hWnd, $tRECT, 0, BitOR($RDW_INVALIDATE, $RDW_FRAME))
                    EndIf
                EndIf
            EndIf
            Return $GUI_RUNDEFMSG
        Case $WM_NCHITTEST
            If $hWnd <> $hgui Then Return $GUI_RUNDEFMSG
            $tPoint = DllStructCreate($tagPOINT)
            DllStructSetData($tPoint, 1, BitAND($lParam, 0x0000FFFF))
            DllStructSetData($tPoint, 2, BitShift($lParam, 16))
            _WinAPI_ScreenToClient($hWnd, $tPoint)
            If _WinAPI_PtInRect($tRECTx, $tPoint) Then
                $fNCKeyDn = True
                Return $HTBORDER ; tell the window the mouse is clicking on the border so we get a WM_NCLBUTTONUP message
            EndIf
            $fNCKeyDn = False ;required to prevent key down message if titlebar clicked after keyup on button
            Return $GUI_RUNDEFMSG
        Case $WM_NCLBUTTONUP
            If $hWnd <> $hgui Then Return $GUI_RUNDEFMSG
            If $nState = 2 Then
                $nState = 1
                $fBtnHot = False
                _WinAPI_RedrawWindow($hWnd, $tRECT, 0, BitOR($RDW_INVALIDATE, $RDW_FRAME))
            EndIf
            If $fNCKeyDn = True And $fNCKeyUp = True Then
                $fNCKeyUp = False
                $nState = 2
                GUICtrlSendToDummy($cBtnTBar)
                _WinAPI_RedrawWindow($hWnd, $tRECT, 0, BitOR($RDW_INVALIDATE, $RDW_FRAME))
                $x = BitAND($lParam, 0x0000FFFF)
                $y = BitShift($lParam, 16)
                ConsoleWrite("+Up at " & $x & "/" & $y & @cr)
            EndIf
            Return $GUI_RUNDEFMSG
        ;WM_NCLBUTTONDBLCLK: optionally allow fast clicking of button, otherwise some repeated clicks are missed.
        Case $WM_NCLBUTTONDOWN, $WM_NCLBUTTONDBLCLK
            If $hWnd <> $hgui Then Return $GUI_RUNDEFMSG
            If $fNCKeyDn = True And $nState <> 4 And $nState <> -1 Then
                $fNCKeyUp = True
                $nState = 3
                _WinAPI_RedrawWindow($hWnd, $tRECT, 0, BitOR($RDW_INVALIDATE, $RDW_FRAME))
                $x = BitAND($lParam, 0x0000FFFF)
                $y = BitShift($lParam, 16)
                ConsoleWrite("-Down at " & $x & "/" & $y & @cr)
            EndIf
            Return $GUI_RUNDEFMSG
        Case $WM_NCACTIVATE, $WM_NCPAINT
            If $hWnd <> $hgui Then Return $GUI_RUNDEFMSG
            If $nState = -1 Then Return $GUI_RUNDEFMSG
            Local $Res = _WinAPI_DefWindowProc($hWnd, $iMsg, $wParam, $lParam)
            ;theme button, theme window caption bar buttons or custom bitmap
            If $hTheme <> 0 Then
                $hDC = _WinAPI_GetWindowDC($hWnd)
                _WinAPI_DrawThemeBackground($hTheme, 1, $nState, $hDC, $tRECT)
                If $fBtnTFont = False Then Local $hOldFont = _WinAPI_SelectObject($hDC, $hFont)
                ;DrawThemeText uses the last font in the DC if no theme font is available.
                ;therefore the DEFAULT_GUI_FONT must be selected into the DC.
                _WinAPI_DrawThemeText($hTheme, 1, $nState, $hDC, 'OK', $tRECT, BitOR($DT_CENTER, $DT_SINGLELINE, $DT_VCENTER))
                If $fBtnTFont = False Then _WinAPI_SelectObject($hDC, $hOldFont)
                _Winapi_ReleaseDC($hWnd, $hDC)
            Else
                ;needs DrawFrameControl code
            EndIf

            Return $Res
    EndSwitch
    Return $GUI_RUNDEFMSG
EndFunc

Edited June 9, 2011 by rover

[E1M1]

rover what that code you posted here supposed to do? Nothing happens when I click enable/disable.

[rover]

rover what that code you posted here supposed to do? Nothing happens when I click enable/disable.

You are running Vista or 7?

This only works on XP.

Vista and 7 use DWM, so a different method is required to do this.

The forum has some examples with DWM code that can be used to do this,

but from what I read on a blog on this subject, it's very involved and there are many fixes

required to make it work on Vista/7, but it can be done.

Setting up a custom title bar on Vista/Windows 7

http://delphihaven.wordpress.com/2010/04/19/setting-up-a-custom-titlebar/

Setting up a custom title bar – reprise

http://delphihaven.wordpress.com/2010/04/22/setting-up-a-custom-title-bar-reprise/

It comes back to what I said in my previous post:

"If this is what you want, see if the amount of code required is worth it to you."

"*additional code still required" - for the above example in XP, and more for Vista/7

and finally, when it comes to customizing like this with all the attendant issues to deal with.

"There is no end to it..."