Resize without stretching!

[JScript]

Hello,

I know how to load this image from a file or a resource, just do not know how to show only the top or the bottom of image and how to resize without stretching!

In other words, keeping the edges and stretching the middle of the picture...

Note: This image is used by WinXP theme and the image is resized the way I am wondering, if someone could help me I will be grateful!

[Yashied]

expandcollapse popup

#Include <Constants.au3>
#Include <GUIConstantsEx.au3>
#Include <WinAPIEx.au3>

Global Const $STM_SETIMAGE = 0x0172

$hForm = GUICreate(0, 400, 400, -1, -1, $WS_POPUP)
$Pic = GUICtrlCreatePic('', 0, 0, 400, 29, -1, $GUI_WS_EX_PARENTDRAG)

$hCaption = _WinAPI_LoadImage(0, @ScriptDir & '\BLUE_FRAMECAPTION_BMP.bmp', $IMAGE_BITMAP, 0, 0, $LR_LOADFROMFILE)
$tSize = _WinAPI_GetBitmapDimension($hCaption)
$iWidth = DllStructGetData($tSize, 1)
$dW = Round($iWidth / 4)
$hDC = _WinAPI_GetDC(0)
$hActive = _WinAPI_CreateCompatibleBitmap($hDC, 400, 29)
$hSrcDC = _WinAPI_CreateCompatibleDC($hDC)
$hSrcSv = _WinAPI_SelectObject($hSrcDC, $hCaption)
$hDstDC = _WinAPI_CreateCompatibleDC($hDC)
$hDstSv = _WinAPI_SelectObject($hDstDC, $hActive)
_WinAPI_ReleaseDC(0, $hDC)
_WinAPI_SetStretchBltMode($hDstDC, $STRETCH_HALFTONE)
_WinAPI_StretchBlt($hDstDC, $dW, 0, 400 - 2 * $dW, 29, $hSrcDC, $dW, 0, $iWidth - 2 * $dW, 29, $SRCCOPY)
_WinAPI_BitBlt($hDstDC, 0, 0, $dW, 29, $hSrcDC, 0, 0, $SRCCOPY)
_WinAPI_BitBlt($hDstDC, 400 - $dW, 0, $dW, 29, $hSrcDC, $iWidth - $dW, 0, $SRCCOPY)
_WinAPI_SelectObject($hDstDC, $hDstSv)
_WinAPI_DeleteDC($hDstDC)
_WinAPI_SelectObject($hSrcDC, $hSrcSv)
_WinAPI_DeleteDC($hDstDC)

$hRgn = _WinAPI_CreateRectRgn(0, 5, 400, 400)
$hTmp = _WinAPI_CreateRectRgn(5, 0, 400 - 5, 400)
_WinAPI_CombineRgn($hRgn, $hRgn, $hTmp, $RGN_OR)
_WinAPI_DeleteObject($hTmp)
$hTmp = _WinAPI_CreateEllipticRgn(_WinAPI_CreateRectEx(0, 0, 15, 15))
_WinAPI_CombineRgn($hRgn, $hRgn, $hTmp, $RGN_OR)
_WinAPI_DeleteObject($hTmp)
$hTmp = _WinAPI_CreateEllipticRgn(_WinAPI_CreateRectEx(400 - 15 + 1, 0, 15, 15))
_WinAPI_CombineRgn($hRgn, $hRgn, $hTmp, $RGN_OR)
_WinAPI_DeleteObject($hTmp)
_WinAPI_SetWindowRgn($hForm, $hRgn)

GUICtrlSendMsg($Pic, $STM_SETIMAGE, $IMAGE_BITMAP, $hActive)
GUISetState()

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

[UEZ]

Hello,

...just do not know how to show only the top or the bottom of image and how to resize without stretching!

What do you mean with this? The image has 2 buttons, blue and lighter blue and you want show one of them by resizing it but the aspect ratio should be the same. Right?

In other words, keeping the edges and stretching the middle of the picture...

This is completely different from your statement above.

Can you show how the image should look like?

Br,

UEZ

[guinness]

Nice example Yashied, just what I was looking for.

[UEZ]

@jscript: I think I understood you know after I played around with the image. It is what Yashied already did with WinAPI stuff I think.

Well, here with GDI+ stuff:

expandcollapse popup

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Opt("GuiOnEventMode", 1)

Global $aC
Global Const $STM_SETIMAGE = 0x0172
Global Const $width = 640
Global Const $height = 400

#region GDI+
_GDIPlus_Startup()
Global Const $hImage = _GDIPlus_ImageLoadFromFile("Blue.png")
Global Const $iW = _GDIPlus_ImageGetWidth($hImage)
Global Const $iH = _GDIPlus_ImageGetHeight($hImage) / 2
Global Const $dy = 0 ;$iH ; <- 2nd image
Global Const $aResult = DllCall($ghGDIPDll, "uint", "GdipCreateBitmapFromScan0", "int", $width, "int", $iH, "int", 0, "int", 0x0026200A, "ptr", 0, "int*", 0)
Global Const $hBitmap = $aResult[6]
Global Const $hContext = _GDIPlus_ImageGetGraphicsContext($hBitmap)
_GDIPlus_GraphicsDrawImageRectRect($hContext, $hImage, 5, $dy, $iW - 10, $iH, 5, 0, $width - 10, $iH)
_GDIPlus_GraphicsDrawImageRectRect($hContext, $hImage, 0, $dy, 5, $iH, 0, 0, 5, $iH)
_GDIPlus_GraphicsDrawImageRectRect($hContext, $hImage, $iW - 5, $dy, 5, $iH, $width - 5, 0, 5, $iH)
Global Const $hBrush = _GDIPlus_BrushCreateSolid(0xFFFFFFFF)
Global Const $hFormat = _GDIPlus_StringFormatCreate()
Global Const $hFamily = _GDIPlus_FontFamilyCreate("Arial")
Global Const $hFont = _GDIPlus_FontCreate($hFamily, 14)
Global $tLayout = _GDIPlus_RectFCreate(4, 4, 0, 0)
_GDIPlus_GraphicsDrawStringEx($hContext, "Edit Box v0.01 by UEZ 2011", $hFont, $tLayout, $hFormat, $hBrush)
$tLayout = _GDIPlus_RectFCreate($width - 30, 2, 0, 0)
_GDIPlus_BrushSetSolidColor($hBrush, 0xFFFF4040)
_GDIPlus_GraphicsDrawStringEx($hContext, "[x]", $hFont, $tLayout, $hFormat, $hBrush)
Global Const $hBmp = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hBitmap)
_GDIPlus_FontDispose($hFont)
_GDIPlus_FontFamilyDispose($hFamily)
_GDIPlus_StringFormatDispose($hFormat)
_GDIPlus_BrushDispose($hBrush)
_GDIPlus_BitmapDispose($hBitmap)
_GDIPlus_ImageDispose($hImage)
_GDIPlus_GraphicsDispose($hContext)
_GDIPlus_Shutdown()
#endregion GDI+

Global Const $hGUI = GUICreate("", $width, $height, -1, -1, $WS_POPUP, $WS_EX_LAYERED)
;~ GUISetBkColor(0xFF00FF)
Global Const $lDrag = GUICtrlCreateLabel("", 0, 0, $width- 31, $iH, Default, $GUI_WS_EX_PARENTDRAG)
Global Const $Pic = GUICtrlCreatePic("", 0, 0, $width, $iH)
Global Const $Edit = GUICtrlCreateEdit("", 0, $iH, $width, $height - $iH)
GUICtrlSetFont(-1, 12, 400)
Global Const $lX = GUICtrlCreateLabel("", $width - 30, 4, 19, 18)
GUISetState()

GUICtrlSendMsg($Pic, $STM_SETIMAGE, 0, $hBmp)
_WinAPI_DeleteObject($hBmp)
_WinAPI_SetLayeredWindowAttributes($hGUI, 0xFF00FF)

GUISetOnEvent($GUI_EVENT_CLOSE, "_Quit")

Do
    $aC = GUIGetCursorInfo($hGUI)
    If $aC[4] = $lX And $aC[2] Then _Quit()
Until Not Sleep(10)

Func _Quit()
    GUIDelete($hGUI)
    Exit
EndFunc   ;==>_Quit

I used the image you provided which is in bmp format.

Advantage of GDI+ is that you can use transparent PNGs.

Br,

UEZ

Edited April 23, 2011 by UEZ

[JScript]

@UEZ: Your code does not work for me! Even though as well many thanks.

@Yashied: I have no words to describe ... phenomenal! But it is very code!

How to select the other button (lighter blue)? Have to have that same amount of code?

I'll explain what I'm trying to do: I'm trying to make a script to "skin", is already working...

But I wanted to work with ".msstyles" files, the major problem you ever solved, I just need to examine your code and try to adapt in my script...

[JScript]

@Yashied: I changed your script to the form that I intend to use ...

I wish that you could ever examine this change and give me some more idea of how to make this script better.

expandcollapse popup

#include <Constants.au3>
#include <GUIConstantsEx.au3>
#include <WinAPIEx.au3>

; Disable default Windows theme (uxtheme.dll)
If StringInStr(@OSTYPE, "WIN32_NT") Then
    Local $XS_n = DllCall("uxtheme.dll", "int", "GetThemeAppProperties")
    DllCall("uxtheme.dll", "none", "SetThemeAppProperties", "int", 0)
EndIf

Main()

Func Main()
    Local $hForm, $Button_1, $Button_2, $Button_3, $iToggle, $aPos
    Local $WinWidth, $WinHeight, $Style_old, $hRgn, $hCaption

    $hForm = GUICreate("", 400, 400)

    Opt("GUICoordMode", 2)
    $Button_1 = GUICtrlCreateButton("Apply Skin", 10, 30, 100)
    $Button_2 = GUICtrlCreateButton("Remove Skin", 0, -1)
    GUICtrlSetState(-1, $GUI_DISABLE)
    $Button_3 = GUICtrlCreateButton("Deactive effect", 0, -1)
    GUICtrlSetState(-1, $GUI_DISABLE)
    $iToggle = 0

    GUISetState()

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop

            Case $Button_1
                ;--> Remove Caption style
                $aPos = WinGetPos($hForm)
                $WinWidth = $aPos[2]
                $WinHeight = $aPos[3]
                $Style_old = _WinAPI_GetWindowLong($hForm, 0xFFFFFFF0) ;$GWL_STYLE
                _WinAPI_SetWindowLong($hForm, 0xFFFFFFF0, BitAND($Style_old, BitNOT(0xC0000)))

                If $hRgn Then _WinAPI_DeleteObject($hRgn)
                $hRgn = _WinAPI_CreateRoundRectRgn(0, 0, $WinWidth, $WinHeight + 20, 20, 20)
                _WinAPI_SetWindowRgn($hForm, $hRgn)
                ;<--
                ;$hLib = _WinAPI_LoadLibrary(@ScriptDir & "\Microsoft Windows XP.msstyles")
                ;$hCaption = _WinAPI_LoadImage($hLib, "BLUE_FRAMECAPTION_BMP", 0, 0, 0, $LR_DEFAULTSIZE)
                ;_WinAPI_FreeLibrary($hLib)
                $hCaption = _WinAPI_LoadImage(0, @ScriptDir & '\BLUE_FRAMECAPTION_BMP.bmp', 0, 0, 0, $LR_LOADFROMFILE)
                _Skin_Draw($hForm, $hCaption)
                $iToggle = 1
                GUICtrlSetState($Button_1, $GUI_DISABLE)
                GUICtrlSetState($Button_2, $GUI_ENABLE)
                GUICtrlSetState($Button_3, $GUI_ENABLE)

            Case $Button_2
                _WinAPI_DeleteObject($hCaption)
                _WinAPI_DeleteObject($hRgn)
                _WinAPI_SetWindowLong($hForm, 0xFFFFFFF0, $Style_old)
                $hRgn = _WinAPI_CreateRoundRectRgn(0, 0, $WinWidth, $WinHeight, 0, 0)
                _WinAPI_SetWindowRgn($hForm, $hRgn)
                GUISetState(@SW_SHOW - GUISetState(@SW_HIDE) + 1)
                GUICtrlSetState($Button_1, $GUI_ENABLE)
                GUICtrlSetState($Button_2, $GUI_DISABLE)
                GUICtrlSetState($Button_3, $GUI_DISABLE)

            Case $Button_3
                If $iToggle Then
                    _Skin_Draw($hForm, $hCaption, False)
                    GUICtrlSetData($Button_3, "Activate effect")
                    $iToggle = 0
                Else
                    _Skin_Draw($hForm, $hCaption)
                    GUICtrlSetData($Button_3, "Deactive effect")
                    $iToggle = 1
                EndIf
        EndSwitch
    WEnd
    _WinAPI_DeleteObject($hCaption)
    _WinAPI_DeleteObject($hRgn)
EndFunc   ;==>Main

Func _Skin_Draw($hWnd, $hBmp, $fFlag = True)
    Local $WinWidth = _WinAPI_GetWindowWidth($hWnd)
    Local $tSize = _WinAPI_GetBitmapDimension($hBmp)
    Local $BmpWidth = DllStructGetData($tSize, 1)
    Local $BmpHeight = DllStructGetData($tSize, 2)
    Local $dW = Round($BmpWidth / 4)
    Local $dH = $BmpHeight / 2
    Local $iType = $dH

    Local $hDC = _WinAPI_GetWindowDC($hWnd)
    Local $hActive = _WinAPI_CreateCompatibleBitmap($hDC, $WinWidth, $dH)

    Local $hSrcDC = _WinAPI_CreateCompatibleDC($hDC)
    Local $hSrcSv = _WinAPI_SelectObject($hSrcDC, $hBmp)

    Local $hDstDC = _WinAPI_CreateCompatibleDC($hDC)
    Local $hDstSv = _WinAPI_SelectObject($hDstDC, $hActive)

    If $fFlag Then $iType = 0
    _WinAPI_SetStretchBltMode($hDstDC, $STRETCH_DELETESCANS)
    _WinAPI_StretchBlt($hDstDC, $dW, 0, $WinWidth - 2 * $dW, $dH, $hSrcDC, $dW, $iType, $BmpWidth - 2 * $dW, $dH, $SRCCOPY)
    _WinAPI_BitBlt($hDstDC, 0, 0, $dW, $dH, $hSrcDC, 0, $iType, $SRCCOPY)
    _WinAPI_BitBlt($hDstDC, $WinWidth - $dW, 0, $dW, $dH, $hSrcDC, $BmpWidth - $dW, $iType, $SRCCOPY)

    _WinAPI_SelectObject($hDstDC, $hDstSv)
    _WinAPI_DeleteDC($hDstDC)
    _WinAPI_SelectObject($hSrcDC, $hSrcSv)
    _WinAPI_DeleteDC($hSrcDC)
    ;_WinAPI_DeleteObject($hBmp)

    _WinAPI_DrawBitmap($hDC, 0, 0, $hActive)
EndFunc   ;==>_Skin_Draw

@UEZ : I still can not run your script, some idea?

Thank all,

João Carlos

[UEZ]

What is happening when you start it? Can you see the window but not the titlebar?

I tested it also on WinXP in my vm and it runs properly!

Br,

UEZ

[JScript]

What is happening when you start it? Can you see the window but not the titlebar?

I tested it also on WinXP in my vm and it runs properly!

Br,

UEZ

"Blue.png" ???

[UEZ]

It should look like this: http://img826.imageshack.us/i/windowsh.png/

Just replace Blue.png with the bmp you provided from your 1st post. I converted the bmp to png - that's all.

Br,

UEZ

[JScript]

Ok! Thanks.

[guinness]

I confirm UEZ's version worked too.

Edited April 24, 2011 by guinness