Good return value practice?

[Tsukihime]

I'm writing a function that checks whether the provided path is a directory or not.

It may already exist, I don't know I didn't look through all of the libraries available.

func isDir($file)
  If FileGetAttrib($file) == "D" Then
    return True
  EndIf
  Return False
EndFunc

This small simple function basically returns True if it's a directory and False otherwise.

I have seen the use of special variables like @error set, but I wasn't sure what are the "proper" things I should do when writing a function.

Edited April 24, 2011 by Tsukihime

[Melba23]

Tsukihime,

what are the "proper" things I should do when writing a function

There are no fixed rules - all you need to do is make clear whether the function was successful or not. The following is my personal interpretation of "best practice":

Expected return    Success    Failure

String             String     ""

Number             Number     0 or -1 depending on valid return values

Array              Array      ""

Boolean            True       False

Special            Value      0
(hWnd, Ptr)

In all failure cases I would set @error using:

Return SetError($iError, $iExtended, Failure_Return)

where $iError and $iExtended give information explaining why the function failed to help debugging.

If you follow these guidelines you will always have 2 ways to tell that the function has worked or not:

- 1. The return value

- 2. @error

As I said these are personal views, but I believe them to be close to a "standard". Please take a look inside the UDFs in my sig to see how I have implemented them in my own functions.

M23

[monoscout999]

I have seen the use of special variables like @error set, but I wasn't sure what are the "proper" things I should do when writing a function.

I think you have to define every error... for ex.

;example

$a = isdir("c:\windows") ; case true
consolewrite("return value "&$a&" error code "&@error&@crlf)
$a = isdir("c:\windows\explorer.exe") ; case false
consolewrite("return value "&$a&" error code "&@error&@crlf)
$a = isdir("c:\windo\") ; case @error
consolewrite("return value "&$a&" error code "&@error&@crlf)

;func

func isDir($file)
    local $fattrib = FileGetAttrib($file)
    select
        case $fattrib == "D" ;is a folder
        return True
    case $fattrib = ""
        seterror(1) ; the file/folder doesn´t exists set error code 1
        return ""
    case Else
        return false ; is NOT a folder
    endselect
EndFunc

I don´t know if is the propper way to do it.... but it works

Edited April 24, 2011 by monoscout999

[Melba23]

monoscout999

Pretty close to what I suggested - but you need to use StringInStr to look for the "D" as you may have other attributes in the return from FileGetAttrib:

I would code it like this:

;example

$fReturn = isdir("C:\Windows") ; True
ConsoleWrite("Return value " & $fReturn & " Error code " & @error & @CRLF)
$fReturn = isdir("C:\Windows\Explorer.exe") ; False and @error = 1
ConsoleWrite("Return value " & $fReturn & " Error code " & @error & @CRLF)
$fReturn = isdir("C:\Windo\") ; Does not exist and @error = 2
ConsoleWrite("Return value " & $fReturn & " Error code " & @error & @CRLF)

;func

Func isDir($sFolder)
    Local $sAttrib = FileGetAttrib($sFolder)
    Select
        Case $sAttrib = ""; the folder does not exist
            Return SetError(2, 0, False)
        Case StringInStr($sAttrib, "D") > 0 ;is a folder
            Return True
        Case StringInStr($sAttrib, "D") = 0 ;is NOT a folder
            Return SetError(1, 0, False)
    EndSelect
EndFunc   ;==>isDir

M23

[GEOSoft]

Of course some of this depends on how you are getting the path.

If you use the FileFindFirstFile/FileFindNextFile method then you don't need a function at all to check it; just check for @Extended

$sSearch = FileFindFirstFile("*") ;; *.* won't help you here because Windows doesn't respect the dot.
If $sSearch <> -1 Then
    While 1
        $hFile = FileFindNextFile($sSearch)
        If @Error Then ExitLoop
        If @Extended Then MsgBox(0, "Folder", $hFile & " is a Folder.")
    WEnd
EndIf

[monoscout999]

monoscout999

Pretty close to what I suggested - but you need to use StringInStr to look for the "D" as you may have other attributes in the return from FileGetAttrib:

I would code it like this:

M23

you have right ... iguess not findig a dir is an error to

[guinness]

I know it's been answered but I just couldn't resist!

Func _IsFolder($sFolder)
    If StringInStr(FileGetAttrib($sFolder), "D") Then
        Return 1
    EndIf
EndFunc   ;==>_IsFolder

[wakillon]

@guinness

I couldn't resist to a shorter version...

Func _IsFolder ( $sFolder )
    Return StringInStr ( FileGetAttrib ( $sFolder ), "D" )
EndFunc ;==> _IsFolder ( )

[guinness]

Stupid me! Why did I add the If ... EndIf Statement???! << Rhetorical question.

[monoscout999]

jajaja I couldn't resist sorry for the spam!