Countdown Timer with the option to add Time

[mcgill]

Looking for a countdown timer to be used with applying certain installations prior to reaching zero/no time left. I am not looking for a countup function. With this function I would like to be able to add time to it incase a user wants to increase the countdown timer, example being countdown timer of 60 minutes/1 hour, user wants to increase by 60 minutes/1 hour. The only information I have come across on the forums is for minutes and seconds only. Any helps/assistance in the right direction would be great, thanks

Example on forums:

*******************

$new = TimerDiff ($timer)

$new = (60*60*1000)-$new

$seconds = Round ($new/1000)

$newMin = Floor ($seconds/60)

$newSec = Mod ($seconds, 60)

If $newSec < 10 Then $newSec = "0"&$newSec

$LabelTime = $newMin & ":" & $newSec

GUICtrlSetData ($TimeLimit, $LabelTime)

[somdcomputerguy]

Search the Example Scripts forum with the keywords countdown timer. I'm sure thru the lengthy results page you'll find several posts that help you out.

Edited April 27, 2011 by somdcomputerguy

[UEZ]

Try this:

expandcollapse popup

#include <GUIConstantsEx.au3>
Opt('MustDeclareVars', 1)

Global $msg
Global $hGUI = GUICreate("Simple Countdown by UEZ 2011", 350, 150)
Global $label = GUICtrlCreateLabel("", 30, 30, 260, 80)
;~ GUICtrlSetBkColor(-1, 0x808080)
GUICtrlSetFont(-1, 50, 400)
Global $button = GUICtrlCreateButton("Add 1h", 295, 120, 50)
GUISetState()

Global $countdown = 1 ;minutes for countdown
Global $seconds = $countdown * 60 ;convert to seconds

Countdown()
AdlibRegister("Countdown", 1000)

Do
    $msg = GUIGetMsg()
    Switch $msg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $button
            $seconds += 3600
    EndSwitch
Until False

AdlibUnRegister("Countdown")
GUIDelete($hGUI)
Exit

Func Countdown()
    Local $sec, $min, $hr
    $sec = Mod($seconds, 60)
    $min = Mod($seconds / 60, 60)
    $hr = Floor($seconds / 60 ^ 2)
    GUICtrlSetData($label, StringFormat("%02i:%02i:%02i", $hr, $min, $sec))
    If $seconds <= 0 Then
        AdlibUnRegister("Countdown")
        MsgBox(0, "Information", "Countdown reached 00:00:00")
        Exit
    EndIf
    $seconds -= 1
EndFunc

Br,

UEZ

[JScript]

@UEZ

Nice example! You're awesome...

[mcgill]

Thank you UEZ, your assistance is much appreciated.