Display IP Address, Default Gateway & DNS Servers

[guinness]

The numbers should be: Description [0], IP Address [1], Default Gateway [3], DNS Servers [4], Mac [2], Obtain DNS Automatically [5].

OK, thanks I changed all my Examples in this thread. It was a simple mistake that I overlooked.

I have looked into using Global and Local instead of Dim but, to be honest, it seems like too much of a learning curve for me right now.

This does concern me a little because I take it you are getting paid by your customers for this Script? Messing with Network Adapters settings isn't for the novice coder or the faint hearted.

I even tried to add another WMIRegRead line but, it didn't like 2 lines of WMIRegRead or, it would only read one but, not both.

How can we add "Obtain IP Address Automatically" and show in the message box right above "Obtain DNS Server Automatically"?

I was kind of hoping you would learn from the Example and integrate into your version

Is this what you were looking for? >>

expandcollapse popup

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <Array.au3>

Global $aArray = _IPDetails(), $sData
_ArrayDisplay($aArray)

For $A = 1 To $aArray[0][0]
    $sData &= "Description: " & $aArray[$A][0] & @CRLF & "IP Address: " & $aArray[$A][1] & @CRLF & "MAC: " & $aArray[$A][2] & _
            @CRLF & "Default Gateway: " & $aArray[$A][3] & @CRLF & "DNS Servers: " & $aArray[$A][4] & @CRLF & "Obtain DNS Automatically: " & $aArray[$A][5] & _
            @CRLF & "Auto IP: " & $aArray[$A][6] & @CRLF & @CRLF
Next
$sData = StringTrimRight($sData, 4)

MsgBox(0, "_IPDetails()", $sData)

Func _IPDetails()
    Local $iCount = 0
    Local $oWMIService = ObjGet("winmgmts:{impersonationLevel = impersonate}!\\" & "." & "\root\cimv2")
    Local $oColItems = $oWMIService.ExecQuery("Select * From Win32_NetworkAdapterConfiguration Where IPEnabled = True", "WQL", 0x30), $aReturn[1][7] = [[0, 7]]
    If IsObj($oColItems) Then
        For $oObjectItem In $oColItems
            $aReturn[0][0] += 1
            $iCount += 1

            If $aReturn[0][0] <= $iCount + 1 Then
                ReDim $aReturn[$aReturn[0][0] * 2][$aReturn[0][1]]
            EndIf

            $aReturn[$iCount][0] = _IsString($oObjectItem.Description)
            $aReturn[$iCount][1] = _IsString($oObjectItem.IPAddress(0))
            $aReturn[$iCount][2] = _IsString($oObjectItem.MACAddress)
            $aReturn[$iCount][3] = _IsString($oObjectItem.DefaultIPGateway(0))
            $aReturn[$iCount][4] = _WMIArrayToString($oObjectItem.DNSServerSearchOrder(), " - ") ; You could use _ArrayToString() but I like creating my own Functions especially when I don't need alot of error checking.
            $aReturn[$iCount][5] = _WMIRegRead($oObjectItem.SettingID)
            $aReturn[$iCount][6] = _IsString($oObjectItem.DHCPEnabled)
        Next
        ReDim $aReturn[$aReturn[0][0] + 1][$aReturn[0][1]]
        Return $aReturn
    EndIf
    Return SetError(1, 0, $aReturn)
EndFunc   ;==>_IPDetails

Func _WMIRegRead($iGUID)
    If RegRead("HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\Tcpip\Parameters\Interfaces\" & $iGUID & "\", "NameServer") = "" Then
        Return True
    EndIf
    Return False
EndFunc   ;==>_WMIRegRead

Func _IsString($sString)
    If IsString($sString) Or IsBool($sString) Then
        Return $sString
    EndIf
    Return "Not Available"
EndFunc   ;==>_IsString

Func _WMIArrayToString($aArray, $sDelimeter = "|")
    If IsArray($aArray) = 0 Then
        Return SetError(1, 0, "Not Available")
    EndIf
    Local $iUbound = UBound($aArray) - 1, $sString
    For $A = 0 To $iUbound
        $sString &= $aArray[$A] & $sDelimeter
    Next
    Return StringTrimRight($sString, StringLen($sDelimeter))
EndFunc   ;==>_WMIArrayToString

[wowmarkb]

Guinness - Thanks, it works great.

This little tool will help my customers complete the tasks in the book I am writing about fixing your Internet connection.

I tried to add to your last script- I just kept getting too many errors.

Thanks again.

[guinness]

What was the error because this worked on Windows XP SP3 & Windows 7 x64?

Edited May 17, 2011 by guinness

[wowmarkb]

guinness, the script on this forum page (page 3) works fine, no errors.

I am now trying to put it into the previous script (the one with the GUI and all the buttons) and make the "Check Addresses" button when pressed, run this latest script.

Last night I removed some old lines we had about description, IP Address, etc. from the GUI script but, it either opened a blank window or, this new message window opened without waiting for a button press.

So, I need to link the lines about button press of the GUI script to this new script for this new message window to open.

After I get home from work, I should be able to get it all working together since I am getting an education on what the lines of code are doing. FYI- I work at a Cable TV/Internet provider and help people get back on the Internet.

[guinness]

OK so you do you know a bit then

If you add and have a problem then post here. But of course I think you get the idea of what to do.

[wowmarkb]

I can understand some of what is in the script. Like MsgBox- I have played with settings so I know how to change appearance, the GUI- size and placemwent, colors, button press action- but how to make it read the IP Address and then put it in a message box- that's where I needed help.

Now that I have your script I can kinda see how it works. Before, you had a Dim statment- I read up on that and now, this version has array statements so, a little differrent.

[guinness]

I don't use Dim ever, only Local & Global. If I have to resize the Array I use ReDim, but I make sure this isn't done everytime in a loop. Also my Examples labeled 1 through 3 have stayed pretty much the same.

Have you thought about using @IPAddress in a MsgBox()?

Edited May 17, 2011 by guinness

[wowmarkb]

If I remember correctly, back in 2008 when I started playing with this little tool, the @IPAddress did not accurately give the current IP. I forget how I came across this but, I wanted to find another way. (I think I set some static ip address and it could read it correctly.)

[guinness]

AutoIt has been updated quite a bit since 2008

[briandoc]

I came across this while looking for some examples on getting an accurate IP address (since AutoIT documentation for even the most current version still says "@IPADDRESS tends to return 127.0.0.1 on some computers", which is unacceptable).

I have to say that the experts on this forum certainly bend over backwards for posters who are looking to be taught and have their code written and re-written for them and modified to add functionality etc. I could never handle doing someone's work for them. I think it's one thing to ask for a snippet of code or an example or a reference, but basically asking someone to do their job for them because they are just too frazzled to understand basic code or to dive in and learn the basics and progress like the rest of us through trial/error and searching for answers is really unbelieveable.

Hats off to guinness and the others for their patience and generosity.

[JLogan3o13]

You resurrected an eight month old post for that?

[briandoc]

You resurrected an eight month old post for that?

Yes.

If it had been 8 years old, I would have done the same. It doesn't matter hold old a post is, if something needs to be said that wasn't said 8 months ago, I could care less if you were inconvenienced because the post was resurrected.

Edited January 19, 2012 by briandoc

[guinness]

I'm certainly not the best believe you me, but if I learn during the process then I'm happy to help and this was a perfect example of why I helped @wowmarkb.

[tletourneau]

First I'd like to thank everyone that has worked on this code! I was looking for something just like this. I have two questions. The first question is: when I run the code I get an array box that opens and when I close that I get the message window with the data. Is there a way to supress the array window and just have the message window open? Also, is it possible to have the text in the message box selectable so it could be copied and pasted? Here is the code I'm working with:

expandcollapse popup

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <Array.au3>
Global $aArray = _IPDetails(), $sData
_ArrayDisplay($aArray)
For $A = 1 To $aArray[0][0]
    $sData &= "Description: " & $aArray[$A][0] & @CRLF & "IP Address: " & $aArray[$A][1] & @CRLF & "MAC: " & _
            $aArray[$A][2] & @CRLF & "Default Gateway: " & $aArray[$A][3] & @CRLF & "DNS Servers: " & $aArray[$A][4] & @CRLF & @CRLF
Next
$sData = StringTrimRight($sData, 4)
MsgBox(0, "_IPDetails()", $sData)
Func _IPDetails()
    Local $iCount = 0
    Local $oWMIService = ObjGet("winmgmts:{impersonationLevel = impersonate}!\\" & "." & "\root\cimv2")
    Local $oColItems = $oWMIService.ExecQuery("Select * From Win32_NetworkAdapterConfiguration Where IPEnabled = True", "WQL", 0x30), $aReturn[1][5] = [[0, 5]]
    If IsObj($oColItems) Then
        For $oObjectItem In $oColItems
            $aReturn[0][0] += 1
            $iCount += 1
            If $aReturn[0][0] <= $iCount + 1 Then
                ReDim $aReturn[$aReturn[0][0] * 2][$aReturn[0][1]]
            EndIf
            $aReturn[$iCount][0] = _IsString($oObjectItem.Description)
            $aReturn[$iCount][1] = _IsString($oObjectItem.IPAddress(0))
            $aReturn[$iCount][2] = _IsString($oObjectItem.MACAddress)
            $aReturn[$iCount][3] = _IsString($oObjectItem.DefaultIPGateway(0))
            $aReturn[$iCount][4] = _IsString(_WMIArrayToString($oObjectItem.DNSServerSearchOrder(), " - ")) ; You could use _ArrayToString() but I like creating my own Functions especially when I don't need alot of error checking.
        Next
        ReDim $aReturn[$aReturn[0][0] + 1][$aReturn[0][1]]
        Return $aReturn
    EndIf
    Return SetError(1, 0, $aReturn)
EndFunc   ;==>_IPDetails
Func _IsString($sString)
    If IsString($sString) Then
        Return $sString
    EndIf
    Return "Not Available"
EndFunc   ;==>_IsString
Func _WMIArrayToString($aArray, $sDelimeter = "|")
    If IsArray($aArray) = 0 Then
        Return SetError(1, 0, "Not Available")
    EndIf
    Local $iUbound = UBound($aArray) - 1, $sString
    For $A = 0 To $iUbound
        $sString &= $aArray[$A] & $sDelimeter
    Next
    Return StringTrimRight($sString, StringLen($sDelimeter))
EndFunc   ;==>_WMIArrayToString

Any and all help will be greatly appreciated! I'm not a coder but I'm starting to learn.

Thanks,

Tom

[Robjong]

Hi,

Yes, just comment the _ArrrayDisplay line, to be able to select the text you will have to make your own GUI as far I know.

expandcollapse popup

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <Array.au3>

Global $aArray = _IPDetails(), $sData, $nMsg, $hButtonClose
;~ _ArrayDisplay($aArray)

For $A = 1 To $aArray[0][0]
    $sData &= "Description: " & $aArray[$A][0] & @CRLF & "IP Address: " & $aArray[$A][1] & @CRLF & "MAC: " & _
            $aArray[$A][2] & @CRLF & "Default Gateway: " & $aArray[$A][3] & @CRLF & "DNS Servers: " & $aArray[$A][4] & @CRLF & @CRLF
Next
$sData = StringTrimRight($sData, 4)

GUICreate("IP Details", 400, 260) ; create GUI
GUICtrlCreateEdit($sData, 8, 8, 384, 204, BitOR($ES_READONLY, $ES_WANTRETURN), 0) ; place an edit on there
$hButtonClose = GUICtrlCreateButton("&OK", 150, 224, 100, 28) ; and a button to close the window
GUISetState()

While 1 ; keeps script running until window is closed
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE ; window is closed the default way
            Exit
        Case $hButtonClose ; user clicked on the button
            Exit
    EndSwitch
    Sleep(50)
WEnd

MsgBox(0, "_IPDetails()", $sData)

Func _IPDetails()
    Local $iCount = 0
    Local $oWMIService = ObjGet("winmgmts:{impersonationLevel = impersonate}!" & "." & "rootcimv2")
    Local $oColItems = $oWMIService.ExecQuery("Select * From Win32_NetworkAdapterConfiguration Where IPEnabled = True", "WQL", 0x30), $aReturn[1][5] = [[0, 5]]
    If IsObj($oColItems) Then
        For $oObjectItem In $oColItems
            $aReturn[0][0] += 1
            $iCount += 1
            If $aReturn[0][0] <= $iCount + 1 Then
                ReDim $aReturn[$aReturn[0][0] * 2][$aReturn[0][1]]
            EndIf
            $aReturn[$iCount][0] = _IsString($oObjectItem.Description)
            $aReturn[$iCount][1] = _IsString($oObjectItem.IPAddress(0))
            $aReturn[$iCount][2] = _IsString($oObjectItem.MACAddress)
            $aReturn[$iCount][3] = _IsString($oObjectItem.DefaultIPGateway(0))
            $aReturn[$iCount][4] = _IsString(_WMIArrayToString($oObjectItem.DNSServerSearchOrder(), " - ")) ; You could use _ArrayToString() but I like creating my own Functions especially when I don't need alot of error checking.
        Next
        ReDim $aReturn[$aReturn[0][0] + 1][$aReturn[0][1]]
        Return $aReturn
    EndIf
    Return SetError(1, 0, $aReturn)
EndFunc   ;==>_IPDetails

Func _IsString($sString)
    If IsString($sString) Then
        Return $sString
    EndIf
    Return "Not Available"
EndFunc   ;==>_IsString

Func _WMIArrayToString($aArray, $sDelimeter = "|")
    If IsArray($aArray) = 0 Then
        Return SetError(1, 0, "Not Available")
    EndIf
    Local $iUbound = UBound($aArray) - 1, $sString
    For $A = 0 To $iUbound
        $sString &= $aArray[$A] & $sDelimeter
    Next
    Return StringTrimRight($sString, StringLen($sDelimeter))
EndFunc   ;==>_WMIArrayToString

Edit: cleaning, also updated the script to address your second question

Edited February 3, 2012 by Robjong

[tletourneau]

That is perfect, thank you! I was able to see the changes you made, that helps a lot too.

Edited February 3, 2012 by tletourneau

[guinness]

So didn't need to change anything?

[tletourneau]

Hi guinness, the changes that Robjong made did what I asked in my previous post and it is working as expected. The only thing I'm trying to figure out now is how to have it show all gateways for an adapter, not just the default gateway. I'll take any pointers on that!

[tletourneau]

Ok, how would I add the output from win32_IP4PersistedRouteTable (from CIM_LogicalElement or CIM_ManagedSystemElement) to a scrollable table in the output box? I'e tried adding another execquery for the class and adding an isString but that fails. Esentially I'm trying to display the persistent routes in a table under the IP information. Pointers, please...

Thanks,

Tom

[VijayS]

Can you help with this code that I made inspired from this post? The script quits unexpectedly when left clicking or double clicking. If compiled to exe the error is variable used before declaring. But the syntax checker doesn't show any error otherwise. Thanks.

expandcollapse popup

#include 
#include 
#include 
#include 
; This script requires full Administrative rights
#requireadmin
#NoTrayIcon

Opt("TrayOnEventMode", 1)
Opt("TrayMenuMode", 1) ; Default tray menu items (Script Paused/Exit) will not be shown.

TraySetClick(16) ; Only secondary mouse button will show the tray menu.

TrayCreateItem("Info")
TrayItemSetOnEvent(-1, "IP1Pressed")

TrayCreateItem("Renew")
TrayItemSetOnEvent(-1, "RenewPressed")
TrayCreateItem("")

TrayCreateItem("Exit")
TrayItemSetOnEvent(-1, "ExitScript")

TraySetOnEvent($TRAY_EVENT_PRIMARYDOWN, "IP1Pressed")
TraySetOnEvent($TRAY_EVENT_PRIMARYDOUBLE, "RenewPressed")

TraySetState()
IP1Pressed()

Global $oldIP, $newIP, $oldDNS, $newDNS
CheckChange(false)
CheckChange(false)
While 1
Sleep(5000) ; Idle loop
CheckChange()
WEnd

Exit


; Functions

Func ExitScript()
Exit
EndFunc ;==>ExitScript


Func VerPressed()
Run("winver")
EndFunc

Func IP1Pressed($stitle = "IP Addresses", $log = True)
$stmp = _IPDetails(1)
TrayTip($stitle,$stmp,5,1)
if $log then WriteLog($stitle & @CRLF & $stmp)
;MsgBox(64, "IP Addresses",$stmp)
EndFunc

Func CheckChange($log = True)
$oldIP = $newIP
$oldDNS = $newDNS
$newIP = @IPAddress1
$newDNS = GetDNS()
Local $rIP = $oldIP <> $newIP
Local $rDNS = $oldDNS <> $newDNS
if ($log) Then
if $rIP Then
IP1Pressed("IP CHANGED",$log)
MsgBox(64,"Debug IP DNS", "DNS:" & $oldDNS & " " & $newDNS & $rDNS & @CRLF & "IP:" & $oldIP & " " & $newIP & $rIP)
EndIf
if $rDNS Then
IP1Pressed("DNS CHANGED",$log)
MsgBox(64,"Debug IP DNS", "DNS:" & $oldDNS & " " & $newDNS & $rDNS & @CRLF & "IP:" & $oldIP & " " & $newIP & $rIP)
EndIf
EndIf
;$curr = GetIP (or get dns) or whatever else you want to monitor
EndFunc

Func GetDNS ()
;Occasionally returns none!, even when there are valid entries. TOFIX
Local $sResult, $line
$hRun = Run(@ComSpec & " /c netsh interface ip show dns", @SystemDir, @SW_HIDE, $STDERR_CHILD + $STDOUT_CHILD)
While 1
$line = StdoutRead($hRun)
If @error Then ExitLoop
$sResult &= $line
Wend
;$answer1 = StringRegExp($sResult,'((?:d+)(?:.d+){3})',3)
$sString = StringRegExp($sResult,'((?:[1-2]?[0-9]?[0-9].){3}(?:[1-2]?[0-9]?[0-9]))',3)
$sString = _ArrayToString($sString)
;MsgBox(64,"DNS:",$sResult & "capture:" & $sString)
Return $sString
EndFunc

Func WriteLog($Data, $FileName = -1, $TimeStamp = True)
If $FileName == -1 Then $FileName = @ScriptDir & '' & @ScriptName & '.Log'
$hFile = FileOpen($FileName, 1)
If $hFile <> -1 Then
If $TimeStamp = True Then $Data = _Now() & ' - ' & $Data
FileWriteLine($hFile, $Data)
FileClose($hFile)
EndIf
EndFunc
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
Func ReleasePressed()
$IP_Address = _RunStdOutRead('ipconfig /release')
$IP_Address = StringRegExpReplace($IP_Address, "(?i)(?s).*IP.*?(d+.d+.d+.d+).*{:content:}quot;", "1")
MsgBox(64, "Release IP Address", StringFormat("Your IP Address is: %s", $IP_Address))
EndFunc

Func RenewPressed()
$IP_Address = _RunStdOutRead('ipconfig /renew')
$IP_Address = StringRegExpReplace($IP_Address, "(?i)(?s).*IP.*?(d+.d+.d+.d+).*{:content:}quot;", "1")
MsgBox(64, "Renew IP Address", StringFormat("Your IP Address is: %s", $IP_Address))
EndFunc

Func FlushPressed()
$IP_Address = _RunStdOutRead('netsh int ip delete arpcache & ipconfig/flushdns')
$IP_Address = StringRegExpReplace($IP_Address, "(?i)(?s).*IP.*?(d+.d+.d+.d+).*{:content:}quot;", "1")
MsgBox(64, "Flush DNS", StringFormat("%s", $IP_Address))
EndFunc

Func TCPIPPressed()
$IP_Address = _RunStdOutRead('netsh int ip reset resetlog.txt & netsh winsock reset')
$IP_Address = StringRegExpReplace($IP_Address, "(?i)(?s).*IP.*?(d+.d+.d+.d+).*{:content:}quot;", "1")
MsgBox(64, "Reset TCP/IP & Winsock", StringFormat("%s", $IP_Address))
EndFunc

;Function to read from Command Line process.
Func _RunStdOutRead($sRunCmd)
Local $iPID = Run(@ComSpec & ' /c ' & $sRunCmd, @ScriptDir, @SW_HIDE, 4 + 2)
Local $sStdOutRead = ""

While ProcessExists($iPID)
$sStdOutRead &= StdoutRead($iPID)
WEnd

Return $sStdOutRead
EndFunc

Func Ping4Pressed()
$IP_Address = _RunStdOutRead('ping www.google.com')
$IP_Address = StringRegExpReplace($IP_Address, "(?i)(?s).*IP.*?(d+.d+.d+.d+).*{:content:}quot;", "1")
MsgBox(64, "Ping Out By URL", StringFormat("%s", $IP_Address))
EndFunc

Func InetPressed()
Run("control inetcpl.cpl")
WinWait("Internet Options", "", 5)
EndFunc

Func ServPressed()
$File = @SystemDir & "services.msc"
Run(@SystemDir & "mmc.exe " & $File)
EndFunc

Func SpecialEvents()

Select
Case @GUI_CTRLID = $GUI_EVENT_CLOSE
Exit

Case @GUI_CTRLID = $GUI_EVENT_MINIMIZE
MsgBox(0, "Window Minimized", "ID=" & @GUI_CTRLID & " WinHandle=" & @GUI_WINHANDLE)

Case @GUI_CTRLID = $GUI_EVENT_RESTORE
MsgBox(0, "Window Restored", "ID=" & @GUI_CTRLID & " WinHandle=" & @GUI_WINHANDLE)

EndSelect

EndFunc

Func _IPDetails($num=100)
Local $totalReturn=""
Local $oWMIService = ObjGet("winmgmts:{impersonationLevel = impersonate}!" & "." & "rootcimv2")
Local $oColItems = $oWMIService.ExecQuery("Select * From Win32_NetworkAdapterConfiguration", "WQL", 0x30), $aReturn[6] = [5]
Local $count = 0
If IsObj($oColItems) Then
For $oObjectItem In $oColItems
If IsString($oObjectItem.IPAddress(0)) Then
$count += 1
;MsgBox(64,"debug",$count & '/' & $num)
if ($count > $num) then ExitLoop ;limiting the number of adapters to show

If IsString($oObjectItem.Description) Then
$aReturn[1] = "Description:" & @TAB & $oObjectItem.Description
Else
$aReturn[1] = "Description:" & @TAB & "Not Available"
EndIf

If IsString($oObjectItem.IPAddress(0)) Then
$aReturn[2] = "IP Address:" & @TAB & $oObjectItem.IPAddress(0)
Else
$aReturn[2] = "IP Address:" & @TAB & "Not Available"
EndIf

If IsString($oObjectItem.DefaultIPGateway(0)) Then
$aReturn[3] = "Default Gateway:" & @TAB & $oObjectItem.DefaultIPGateway(0)
Else
$aReturn[3] = "Default Gateway:" & @TAB & "Not Available"
EndIf

If IsArray($oObjectItem.DNSServerSearchOrder()) Then
$aReturn[4] = "DNS Servers:" & @TAB & _WMIArrayToString($oObjectItem.DNSServerSearchOrder(), " - ")
Else
$aReturn[4] = "DNS Servers:" & @TAB & "Not Available"
EndIf

If IsString($oObjectItem.MACAddress) Then
$aReturn[5] = "MAC: " & @TAB & @TAB & $oObjectItem.MACAddress
Else
$aReturn[5] = "MAC: " & @TAB & @TAB & "Not Available"
EndIf

$totalReturn &= $aReturn[1] & @CRLF & $aReturn[2] & @CRLF & $aReturn[3] & @CRLF & $aReturn[4] & @CRLF & $aReturn[5] & @CRLF & @CRLF
EndIf
Next
Return StringTrimRight($totalReturn,4)
EndIf
Return SetError(1, 0, $aReturn)
EndFunc ;==>_IPDetails

Func _WMIArrayToString($aArray, $sDelimeter = "|")
If IsArray($aArray) = 0 Then
Return SetError(1, 0, "")
EndIf
Local $iUbound = UBound($aArray) - 1, $sString
For $A = 0 To $iUbound
$sString &= $aArray[$A] & $sDelimeter
Next
Return StringTrimRight($sString, StringLen($sDelimeter))
EndFunc ;==>_WMIArrayToString