Search in a Array

[Vision]

Hello,

is is possible to search in a array for a specific number ?

for exsample:

the array has 50 values from 11.5 - 2.0

and i want to find the number of array whats 6.0 or the nearest value in range of 6.0

so if there are only arrays with 5.8 and 6.1 he should pick 6.1 as value?

hope u understand my problem^^

[Melba23]

Vision,

This should give you the idea:

#include <Array.au3>

; Create array with random values from 0 to 10
Global $aArray[10]
For $i = 0 To 9
    $aArray[$i] = Random(0, 100, 1) / 10
Next

$iTgtValue = 6   ; Value to match
$nTgtDelta = 100 ; How close we have got to this value
$iTgtIndex = -1  ; Which index is closest to the value

For $i = 0 To 9
    ; How close is this element?
    $nDelta = Abs($iTgtValue - $aArray[$i])
    ; If it is the closest
    If $nDelta < $nTgtDelta Then
        ; Reset the results
        $iTgtIndex = $i
        $nTgtDelta = $nDelta
    EndIf
Next

; Display the result
_ArrayDisplay($aArray, "Nearest: " & $iTgtIndex)

Please ask if you have any questions.

M23

[hannes08]

Hi Vision,

for an exact search you can use _ArraySearch()

If you want a "similar" or "nearest hit" search, you need to write your own function.

[jchd]

Beware of instability inherent to computations done in floating-point representations.

Then decide by yourself which one of 5.5 or 6.5 the function should select when supplied the value 6.0

[Vision]

Vision,

This should give you the idea:

#include <Array.au3>

; Create array with random values from 0 to 10
Global $aArray[10]
For $i = 0 To 9
    $aArray[$i] = Random(0, 100, 1) / 10
Next

$iTgtValue = 6   ; Value to match
$nTgtDelta = 100 ; How close we have got to this value
$iTgtIndex = -1  ; Which index is closest to the value

For $i = 0 To 9
    ; How close is this element?
    $nDelta = Abs($iTgtValue - $aArray[$i])
    ; If it is the closest
    If $nDelta < $nTgtDelta Then
        ; Reset the results
        $iTgtIndex = $i
        $nTgtDelta = $nDelta
    EndIf
Next

; Display the result
_ArrayDisplay($aArray, "Nearest: " & $iTgtIndex)

Please ask if you have any questions.

M23

thanks much ! works prfect

one additional question: is that possible to say that he cant select a value below the "6" just the neartest above 6 ?

[Melba23]

Vision,

is that possible to say that he cant select a value below the "6" just the neartest above 6 ?

Just adjust the comparision logic a bit:

For $i = 0 To 9
    ; Is element greater than or equal to the target value?
    If $aArray[$i] >= $iTgtValue Then
        ; So how close is this element?
        $nDelta = $aArray[$i] - $iTgtValue
        ; If it is the closest yet
        If $nDelta < $nTgtDelta Then
            ; Reset the results
            $iTgtIndex = $i
            $nTgtDelta = $nDelta
        EndIf
    EndIf
Next

And note what jchd said about floating point computations - you might not get the value you imagine if there are a couple of very close possibilities.

All clear?

M23

[Vision]

thank you.

everything clear.