@year but only last digits

[RogerRabbitsClone]

im trying to create a folder on my desktop that has the date as the name. but i want the year to only be the last 2 digits. ie today would be "050511" rather then "05052011".

any ideas? or can someone tell me how the marco works? meaning where it gets the date from. is it like a UDF where i can modify the code for it?

DirCreate(@DesktopDir & $Name & " " & @MON & @MDAY & "10")

[GEOSoft]

MsgBox(0, "Result", StringRight(@Year, 2))

[RogerRabbitsClone]

you're the shit. thank you.

[RogerRabbitsClone]

maybe im applying this wrong, but its not creating a folder and its not giving me an error code.

$year = StringRight(@Year, 2)

$name = ("henry")

DirCreate(@DesktopDir & $name & " " & @MON & @MDAY & $year & " ")

[Melba23]

RogerRabbitsClone,

AutoIt folder macros do not have a trailing \ - try this:

$year = StringRight(@Year, 2)

$name = ("henry")

DirCreate(@DesktopDir & "\" & $name & " " & @MON & @MDAY & $year & " ")

Works for me.

M23

[RogerRabbitsClone]

well i'll be dammed. thank you thank you.

[GEOSoft]

Now that you learned those 2 valuable lessons, it's time for another one

$sDesired = @DesktopDir & "\" & @UserName & @MON & @MDAY & StringRight(@Year, 2) & " "

$sFldr = @DesktopDir & StringFormat("\%s%02d%02d%02d ", @UserName,@MON, @MDAY, StringRight(@Year, 2))
MsgBox(0, "StringFormat Result", "Desired:     " & $sDesired & @CRLF & "Achieved:  " & $sFldr)

[ProgAndy]

@GEOSoft: StringFormat is useful, but really slow. So avoid to use it in long loops or try to do it outside the loop.

[GEOSoft]

@GEOSoft: StringFormat is useful, but really slow. So avoid to use it in long loops or try to do it outside the loop.

Hmmm

I don't remember putting it in a loop and it's only slow if there are a lot of iterations anyway.

Besides it was meant as a learning experience.

[ProgAndy]

Hmmm

I don't remember putting it in a loop and it's only slow if there are a lot of iterations anyway.

Besides it was meant as a learning experience.

I know. I just wanted to give some more information. In the beginning I always used StringFormat when I had more than 2 or 3 variables to concat until I realized the performance hit.

[GEOSoft]

No problem. The more - the merrier.

[RogerRabbitsClone]

Now that you learned those 2 valuable lessons, it's time for another one

$sDesired = @DesktopDir & "\" & @UserName & @MON & @MDAY & StringRight(@Year, 2) & " "

$sFldr = @DesktopDir & StringFormat("\%s%02d%02d%02d ", @UserName,@MON, @MDAY, StringRight(@Year, 2))
MsgBox(0, "StringFormat Result", "Desired:     " & $sDesired & @CRLF & "Achieved:  " & $sFldr)

forgot the dircreate

$sDesired = dircreate(@DesktopDir & "\" & @UserName & @MON & @MDAY & StringRight(@Year, 2) & " ")

but awesome! thanks guys.

this is part of my ongoing project to pull business card orders from a table in outlook and slap the info into Adobe InDesign. i wrote it when i was using CS4, and the CS5 upgrade screwed it all up, so im redoing a bunch of it.

since i have your attentions, i dont suppose anybody knows if there are Adobe functions, like _IE and _EXCEL?

[guinness]

There isn't a UDF per say but I have seen Examples floating around the Forum.

[GEOSoft]

forgot the dircreate

$sDesired = dircreate(@DesktopDir & "\" & @UserName & @MON & @MDAY & StringRight(@Year, 2) & " ")

but awesome! thanks guys.

this is part of my ongoing project to pull business card orders from a table in outlook and slap the info into Adobe InDesign. i wrote it when i was using CS4, and the CS5 upgrade screwed it all up, so im redoing a bunch of it.

since i have your attentions, i dont suppose anybody knows if there are Adobe functions, like _IE and _EXCEL?

Oh no I didn't forget. That was just to show you how the Formatted string gave you the same results as $sDesired which in the test was a text string.

It would actually be DirCreate($sFldr)

You can forget all about $sDesired and just set the right information in the StringFormat()

As a matter of fact you could even change that line to

$sFldr = StringFormat("%s\%s%02d%02d%02d ", @DesktopDir, @UserName,@MON, @MDAY, StringRight(@Year, 2))
DirCreate($sFldr)

Edited May 6, 2011 by GEOSoft

[RogerRabbitsClone]

Oh no I didn't forget. That was just to show you how the Formatted string gave you the same results as $sDesired which in the test was a text string.

It would actually be DirCreate($sFldr)

You can forget all about $sDesired and just set the right information in the StringFormat()

As a matter of fact you could even change that line to

$sFldr = StringFormat("%s\%s%02d%02d%02d ", @DesktopDir, @UserName,@MON, @MDAY, StringRight(@Year, 2))
DirCreate($sFldr)

ooooOOOOOoooooo.. iiiiiiiiiii see. thanks

@guinness, i tried searching the forums to no avail. im not too worried about it, but if you happen to find one drop me a line. right now the only way i can interact with indesign is send, winwait etc commands. uber buggy.

[Blue_Drache]

the only way i can interact with indesign is send, winwait etc commands. uber buggy.

It can be much less buggy if you use window handles, using proper WinWait() statements with timeout traps, and controlsend() instead of send().

I've had to automate AS400 emulators before, scraping text and interfacing with Excel and IE.

It's not difficult and not terribly buggy if you build proper code.

Make judicious use of the Window Spy tool built into the SciTE editor. Especially when trying to get controls.

By way of example on how I use controlsend and window handles and WinWait() traps:

Variables are labeled at the beginning of the variable's name: hwnd = window handle i = integer s = string b = binary f = float a = array

expandcollapse popup

#RequireAdmin
Opt("MustDeclareVars", 1)
Opt("WinTitleMatchMode", 4)

Func Install7z()
    Local $hwnd7zInst = Default, $iLoop = Default
    If Not FileExists(@ScriptDir & "\7-zip\7za.exe") Then
        ConsoleWrite("7-zip not detected. Installing.")
        FileInstall("C:\SciteScripts\Support\7-zip\7za920.exe", @ScriptDir & "\7-zip\", 1)
        Run(@ScriptDir & "\7-zip\7za920.exe")
        If Not WinWait("7-Zip self-extracting archive", "", 30) Then
            ConsoleWrite("Timeout on window detection for istallation of 7-zip")
            SetError(-10)
            Return 0
        EndIf
        $hwnd7zInst = WinGetHandle("7-Zip self-extracting archive")
        WinActivate($hwnd7zInst)
        ControlSend($hwnd7zInst, "", "[CLASSNN:Edit1]", @ScriptDir & "\7-zip\")
        ControlClick($hwnd7zInst, "", "[CLASSNN:Button2; TEXT:]", "primary", 1)
    EndIf
    $iLoop = 0
    While 1
        Sleep(750)
        $iLoop += 1
        If FileExists(@ScriptDir & "\7-zip\7za.exe") Then
            ConsoleWrite("7-zip detected as installed.  Exiting Loop.")
            ExitLoop
        EndIf
        If $iLoop >= 30 Then
            ConsoleWrite("7-zip not detected as installed.  Timeout. Aborting.")
            SetError(-11)
            Return 0
        EndIf
    WEnd
    $iLoop = 0
        Return 1
EndFunc   ;==>Install7z

Edited May 6, 2011 by Blue_Drache