Array question.

[Mingre]

Hello AutoIt people,

I'm trying to create a function that will tell whether the two arrays $x and $y with the same index limit $no are equal---equal in the sense that an element of $x has a corresponding equal element on $y. The function will return "True" if that's the case and "False" if otherwise.

expandcollapse popup

#include-once
; . . . . .
Func _IsArrayEquivalent(ByRef $x, ByRef $y)

If Ubound($x) = Ubound($y) Then
    $no = Ubound($x)
    $count1 = 0
    For $countx = 0 to $no - 1 Step +1
        For $county = 0 to $no - 1 Step +1
            If $x[$countx] = $y[$county] Then
                $county = $no - 1
                $count1 += 1
            EndIf
        Next
    Next

    $count2 = 0
    For $county = 0 to $no - 1 Step +1
        For $countx = 0 to $no - 1 Step +1
            If $y[$county] = $x[$countx] Then
                $countx = $no - 1
                $count2 += 1
            EndIf
        Next
    Next

    If $count1 = $no And $count2 = $no Then
        Return "True"
    Else
        Return "False"
    EndIf

Else
    Return "False"
EndIf
EndFunc


; T R I A L
Dim $a[4] = ["Ba", "Ba", "Bi", "Bi"], $b[4] = ["Ba", "Bi", "Bi", "Bi"]

msgbox(0,"", _IsArrayEquivalent($a, $b))

The problem is that it is limited to those arrays whose every element occurs only once. So, the trial I did above will return "True" even though it should be false.

Help please? Thanks!

L. Go

Edited May 21, 2011 by Lilbert

[GEOSoft]

See Ubound() in the help file.

MsgBox(0, "Result", Ubound($x) = Ubound($y))

[wakillon]

Do you mean that all elements of $x have a corresponding equal element on $y ?

[Mingre]

Do you mean that all elements of $x have a corresponding equal element on $y ?

Yessir.

GEOSoft,

Thanks for mentioning Ubound()!

[wakillon]

Something like this ?

Global $a[4] = ["Ba", "Ba", "Bi", "Bi"], $b[4] = ["Ba", "Bi", "Bi", "Bi"]
ConsoleWrite ( " : " & _IsArrayEquivalent ( $a, $b ) & @Crlf )

Global $a[4] = ["Bo", "Bi", "Ba", "Bu"], $b[4] = ["Bo", "Bi", "Ba", "Bu"]
ConsoleWrite ( " : " & _IsArrayEquivalent ( $a, $b ) & @Crlf )

Func _IsArrayEquivalent ( $_Array1, $_Array2 )
    Local $_U1 = UBound ( $_Array1 ) -1, $_U2 = UBound ( $_Array2 ) -1
    If $_U2 <> $_U1 Then Return 0
    For $_I = 0 To $_U1
        ConsoleWrite ( "-->-- $_Array1[" & $_I & "] : " & $_Array1[$_I] & " -- $_Array2[" & $_I & "] : " & $_Array2[$_I] & @Crlf )
        If $_Array1[$_I] <> $_Array2[$_I] Then Return 0
    Next
    Return 1
EndFunc

[UEZ]

A small modification to wakillon's script:

#include <Array.au3>

Global $a[4] = ["Ba", "Ba", "Bi", "Bi"], $b[4] = ["Ba", "Bi", "Bi", "Bi"]
ConsoleWrite ( " : " & _IsArrayEquivalent ( $a, $b ) & @Crlf )

Global $a[4] = ["Bo", "Bi", "Ba", "Bu"], $b[4] = ["Ba", "Bi", "Bo", "Bu"]
ConsoleWrite ( " : " & _IsArrayEquivalent ( $a, $b ) & @Crlf )

Func _IsArrayEquivalent($_Array1, $_Array2)
    Local $_U1 = UBound($_Array1), $_U2 =UBound( $_Array2)
    If $_U2 <> $_U1 Then Return 0
    Local $aT1 = $_Array1, $aT2 = $_Array2
    _ArraySort($aT1)
    _ArraySort($aT2)
    For $_I = 0 To $_U1 - 1
        ConsoleWrite ( "-->-- $aT1[" & $_I & "] : " & $aT1[$_I] & " -- $aT2[" & $_I & "] : " & $aT2[$_I] & @Crlf )
        If $aT1[$_I] <> $aT2[$_I] Then Return 0
    Next
    Return 1
EndFunc

If order of the elements doesn't matter!

Au revoir,

UEZ

Edited May 21, 2011 by UEZ

[jchd]

@Lilbert,

Depending on your actual needs, you may have to refine a bit more good UEZ code.

Do you consider equality case sensitive or not?

Do you consider elements types (i.e. does "123" equal 123)?

[wakillon]

A small modification to UEZ's script

#include <Array.au3>

Global $a[4] = ["Ba", "Ba", "Bi", "Bi"], $b[4] = ["Ba", "Bi", "Bi", "Bi"]
ConsoleWrite ( "!->-- _IsArrayEquivalent : " & _IsArrayEquivalent ( $a, $b ) & @Crlf )

Global $a[4] = ["Bo", "Bi", "Ba", "Bu"], $b[4] = ["Bo", "Bi", "Ba", "BU"]
ConsoleWrite ( "!->-- _IsArrayEquivalent : " & _IsArrayEquivalent ( $a, $b ) & @Crlf )

Global $a[4] = ["Bo", "Ba", "Bu", "Bi"], $b[4] = ["Bo", "Bi", "Ba", "Bu"]
ConsoleWrite ( "!->-- _IsArrayEquivalent : " & _IsArrayEquivalent ( $a, $b ) & @Crlf )

Global $a[4] = ["Bo", "Ba", "Bu", "Bi"], $b[4] = ["Bo", "Bi", "Ba", "Bu"]
ConsoleWrite ( "!->-- _IsArrayEquivalent : " & _IsArrayEquivalent ( $a, $b, 0 ) & @Crlf )

Func _IsArrayEquivalent ( $_Array1, $_Array2, $_Order=1, $_CaseSensitive=1 )
    Local $_U1 = UBound ( $_Array1 ) -1, $_U2 = UBound ( $_Array2 ) -1
    If $_U2 <> $_U1 Then Return 0
    Local $aT1 = $_Array1, $aT2 = $_Array2
    If $_Order Then
        _ArraySort ( $aT1 )
        _ArraySort ( $aT2 )
    EndIf
    For $_I = 0 To $_U1
        ConsoleWrite ( "-->-- $_Array1[" & $_I & "] : " & $aT1[$_I] & " -- $_Array2[" & $_I & "] : " & $aT2[$_I] & @Crlf )
        If $aT1[$_I] <> $aT2[$_I] Then Return 0
        If $_CaseSensitive And Not ( $aT1[$_I] == $aT2[$_I] ) Then Return 0
    Next
    Return 1
EndFunc ;==> _IsArrayEquivalent ( )

Edit : For strings only.

Edited May 21, 2011 by wakillon

[Mingre]

Thanks guys! I'll try the script and try to digest how it works. Takes some time for me to do so.

(And LOL. I should've not posted my script. Way too embarrassing for you guys to see it!)

[martin]

Thanks guys! I'll try the script and try to digest how it works. Takes some time for me to do so.

(And LOL. I should've not posted my script. Way too embarrassing for you guys to see it!)

You should have posted it, and definitely it is nothing to be embarrassed about.