onEvent: Run function when combobox selection made

[gruntydatsun]

Hello,

I've searched for this one and can't find the answer. Any help appreciated.

I would like to run a function when a selection is made in the combobox (called $combo_Selection) in code below.

#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

$Form1 = GUICreate("Example Program", 315, 149, 192, 114)
$combo_Selection = GUICtrlCreateCombo("", 24, 24, 241, 25)
$label_RelatedInfo = GUICtrlCreateLabel("label_RelatedInfo", 24, 64, 87, 17)
GUISetState(@SW_SHOW)

Opt("GUIOnEventMode", 1)
GUISetOnEvent($GUI_EVENT_CLOSE, "Terminate")
GUICtrlSetData($combo_Selection, "Dog|Cat|Goat|Chicken","Dog")

While 1
 Sleep(1000)
WEnd

Func Terminate()
    Exit
EndFunc

[Melba23]

gruntydatsun,

A bit of a kludge, but it works:

expandcollapse popup

#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <GuiComboBox.au3>

$fCurrState = False
$fOpened = False

$Form1 = GUICreate("Example Program", 315, 149, 192, 114)
$combo_Selection = GUICtrlCreateCombo("", 24, 24, 241, 25)

$label_RelatedInfo = GUICtrlCreateLabel("label_RelatedInfo", 24, 64, 87, 17)
GUISetState(@SW_SHOW)

Opt("GUIOnEventMode", 1)
GUISetOnEvent($GUI_EVENT_CLOSE, "Terminate")

GUICtrlSetData($combo_Selection, "Dog|Cat|Goat|Chicken", "Dog")

While 1
    Sleep(10)

    $fState = _GUICtrlComboBox_GetDroppedState($combo_Selection)
    If $fState <> $fCurrState Then
        Switch $fState
            Case True
                $fOpened = True
            Case False
                If $fOpened Then
                    $fOpened = False
                    MsgBox(0, "Function", "Run it now using " & GUICtrlRead($combo_Selection))
                EndIf
        EndSwitch
        $fCurrState = $fState
    EndIf

WEnd

Func Terminate()
    Exit
EndFunc   ;==>Terminate

There should be a message from the combo somewhere we can intercept - I will look around tomorrow.

M23

Edit: Found it:

expandcollapse popup

#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <GuiComboBox.au3>

$fFlag = False

$Form1 = GUICreate("Example Program", 315, 149, 192, 114)
$combo_Selection = GUICtrlCreateCombo("", 24, 24, 241, 25)

$label_RelatedInfo = GUICtrlCreateLabel("label_RelatedInfo", 24, 64, 87, 17)
GUISetState(@SW_SHOW)

Opt("GUIOnEventMode", 1)
GUISetOnEvent($GUI_EVENT_CLOSE, "Terminate")

GUICtrlSetData($combo_Selection, "Dog|Cat|Goat|Chicken", "Dog")

GUIRegisterMsg($WM_COMMAND, "_WM_COMMAND")

While 1
    Sleep(10)

    ; Look for the flag
    If $fFlag Then
        $fFlag = False
        MsgBox(0, "Function", "Run it now using " & GUICtrlRead($combo_Selection))
    EndIf

WEnd

Func Terminate()
    Exit
EndFunc   ;==>Terminate

Func _WM_COMMAND($hWnd, $msg, $wParam, $lParam)
    ; if it is our combo and it is closed after have been opened
    If BitAND($wParam, 0x0000FFFF) = $combo_Selection And BitShift($wParam, 16) = $CBN_CLOSEUP Then
        ; Set a flag
        $fFlag = True
    EndIf
    Return $GUI_RUNDEFMSG
EndFunc

You need to use a flag becasue you do not want to run long functions from within the message handler.

All clear?

Edited May 25, 2011 by Melba23

[UEZ]

Here my version:

expandcollapse popup

#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

$Form1 = GUICreate("Example Program", 315, 149, 192, 114)
$combo_Selection = GUICtrlCreateCombo("", 24, 24, 241, 25)
GUICtrlSetOnEvent(-1, "Combo")
$label_RelatedInfo = GUICtrlCreateLabel("label_RelatedInfo", 24, 64, 87, 17)
GUISetState(@SW_SHOW)

Opt("GUIOnEventMode", 1)
GUISetOnEvent($GUI_EVENT_CLOSE, "Terminate")
GUICtrlSetData($combo_Selection, "Dog|Cat|Goat|Chicken","")

While 1
 Sleep(1000)
WEnd

Func Combo()
    Call(GUICtrlRead($combo_Selection))
EndFunc

Func Dog()
    ConsoleWrite("Running dog" & @CRLF)
EndFunc

Func Cat()
    ConsoleWrite("Running cat" & @CRLF)
EndFunc

Func Goat()
    ConsoleWrite("Running goat" & @CRLF)
EndFunc

Func Chicken()
    ConsoleWrite("Running chicken" & @CRLF)
EndFunc

Func Terminate()
    Exit
EndFunc

Br,

UEZ

[gruntydatsun]

Thanks Melba23. That was exactly what I was looking for. Implemented it my program and it works great.

Thanks for your version too UEZ. It's news to me that I can call a function by the name of a element of a combobox.

You get better support for AutoIT than you do for 99% of paid products. Thanks guys.

[Melba23]

gruntydatsun,

And here is an even more elegant way to code it - in my opinion, of course.

expandcollapse popup

#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <GuiComboBox.au3>

Opt("GUIOnEventMode", 1)

$Form1 = GUICreate("Example Program", 315, 149, 192, 114)
GUISetOnEvent($GUI_EVENT_CLOSE, "Terminate")

$combo_Selection = GUICtrlCreateCombo("", 24, 24, 241, 25)
GUICtrlSetData($combo_Selection, "Dog|Cat|Goat|Chicken", "Dog")

$label_RelatedInfo = GUICtrlCreateLabel("label_RelatedInfo", 24, 64, 87, 17)

; Create a dummy control to run the function
$hDummy = GUICtrlCreateDummy()
GUICtrlSetOnEvent(-1, "Do_It")

GUISetState(@SW_SHOW)

GUIRegisterMsg($WM_COMMAND, "_WM_COMMAND")

While 1
    Sleep(10)
WEnd

Func Do_It()
    MsgBox(0, "Function", "Run it now using " & GUICtrlRead($combo_Selection))
EndFunc

Func Terminate()
    Exit
EndFunc   ;==>Terminate

Func _WM_COMMAND($hWnd, $msg, $wParam, $lParam)
    ; if it is our combo and it is closed after have been opened
    If BitAND($wParam, 0x0000FFFF) = $combo_Selection And BitShift($wParam, 16) = $CBN_CLOSEUP Then
        ; Fire the dummy
        GUICtrlSendToDummy($hDummy)
    EndIf
    Return $GUI_RUNDEFMSG
EndFunc

M23