How can I move a certain line(s) of text up in a txt file?

[Albertxu]

I had just solved a problem, but here comes another. I have a word list with explanation and phonetic. The pattern is like:

+wary
#adj."here is Chinese translation"
&ˈwɛəri
$3
+welter
#n."here is Chinese translation"
#vi."here is Chinese translation"
&ˈweltə
$3
+whimsy
#n."here is Chinese translation"
&ˈhwɪmzi:
$3

You can see from the pattern that the first line is the word entry, the second or third line is the Chinese translation, the last to second line is the phonetic sound, which needs to be moved to the position close to the word entry. And the last line is all the same, which is $3.

Now here comes the task, I want to change the pattern to:

+wary &ˈwɛəri
#adj."here is Chinese explanation"

+welter &ˈweltə
#n."here is Chinese explanation"
#vi."here is Chinese explanation"

+whimsy &ˈhwɪmzi:
#n."here is Chinese explanation"

I know this can be done with VBA script, but since I am learning AutoIt, I am sure we have a way to make it. Can some one here give me some ideas?

[water]

It depends on the size of the input file. But you could do something like this:

• Read the file to an array using _FileReadToArray
• Loop through the array and create the output records
• Write the output records to a new file

Number 2 could be something like:

• If record[$i] starts with "+" then record[$i+2] or record[$i+2] will start with an "&". If true combine this two records
• If record[$i] starts with "$" then write an empty record
• If record[$i] starts with "&" ignore the record (has been processed with the "+" record)

Edited May 30, 2011 by water

[bogQ]

quick example from water suggestion

#include <Array.au3>
Global $c = 0,$d = 0
Dim $array[1]
$a = '+wary'& _
@CR&'#adj."here is Chinese translation"'& _
@CR&"&'w??ri"& _
@CR&'$3'& _
@CR&'+welter'& _
@CR&'#n."here is Chinese translation"'& _
@CR&'#vi."here is Chinese translation"'& _
@CR&"&'welt?"& _
@CR&'+whimsy'& _
@CR&'#n."here is Chinese translation"'& _
@CR&"&'hw?mzi:"& _
@CR&'$3'
$b = StringSplit($a,@CR)
_ArrayDisplay($b)
;all upper lines are close or equivalent to _FileReadToArray() func


For $x = 1 To $b[0]
    If StringLeft($b[$x],1)="+" Then
        If $d > 0 Then _ArrayAdd($array,"")
        If $d = 0 Then $d += 1
        Do
            $c+=1
        Until StringLeft($b[$x+$c],1) = "&"
        _ArrayAdd($array,$b[$x]&" "&$b[$x+$c])
        $c = 0
    EndIf
    If StringLeft($b[$x],1)="#" Then _ArrayAdd($array,$b[$x])
Next
$array[0] = UBound($array)-1
_ArrayDisplay($array)
;_FileWriteFromArray() to write it to new file

[UEZ]

Try this:

$sText = FileRead("Text.txt")
$aSplit = StringSplit($sText, "$3" & @LF, 2)

Global $i, $j, $k, $s1 = "", $s2 = ""

While $i < UBound($aSplit)
    Switch StringLeft($aSplit[$i], 1)
        Case "+"
            $s1 &= StringStripCR($aSplit[$i]) & " "
            For $k = $i + 1 To UBound($aSplit) - 1
                If StringLeft($aSplit[$k], 1) = "&" Then
                    $s1 &= $aSplit[$k]
                    $i = $k
                    $s1 &= $s2 & @CRLF
                    $s2 = ""
                    ExitLoop
                EndIf
                $s2 &= $aSplit[$k]
            Next
    EndSwitch
    $i += 1
WEnd
MsgBox(0, "", $s1)

Text.txt has the content from your first code box.

Br,

UEZ

[smartee]

hi,

Here's something short and sweet if you so prefer

;Read and reorder
Local $sNewFileContents=StringRegExpReplace(FileRead("input.txt"),"(\+.+)(\r\n)(#.+\r\n+)(#.+\r\n+)*(&.+)","$1 $5$2$3$4")

;Output to UTF-8 encoded text file
Local $hOutputFile=FileOpen("output.txt",18)
FileWrite($hOutputFile,StringToBinary($sNewFileContents,4))
FileClose($hOutputFile)

-smartee

[Albertxu]

Try this:

$sText = FileRead("Text.txt")
$aSplit = StringSplit($sText, "$3" & @LF, 2)

Global $i, $j, $k, $s1 = "", $s2 = ""

While $i < UBound($aSplit)
    Switch StringLeft($aSplit[$i], 1)
        Case "+"
            $s1 &= StringStripCR($aSplit[$i]) & " "
            For $k = $i + 1 To UBound($aSplit) - 1
                If StringLeft($aSplit[$k], 1) = "&" Then
                    $s1 &= $aSplit[$k]
                    $i = $k
                    $s1 &= $s2 & @CRLF
                    $s2 = ""
                    ExitLoop
                EndIf
                $s2 &= $aSplit[$k]
            Next
    EndSwitch
    $i += 1
WEnd
MsgBox(0, "", $s1)

Text.txt has the content from your first code box.

Br,

UEZ

Hi UEZ, Your code worked just fine. Thank you very much. I combine your code with that of smartee's, and it worked greatly.

Thank you again.