Sleep error?

[erebus]

I searched the forum a bit but with no luck.. Here is my code:

Func DisplayBanners()
; Search for the JPG banners
    $search = FileFindFirstFile($path & "*." & $type)

; Check if the search was successful
    If $search = -1 Then
        MsgBox(16, $app & " " & $ver, "No " & $type & " files were found in " & $path & ". " & $app & " cannot proceed.")
        Terminate()
    EndIf

; Start displaying banners
    While 1
        $file = FileFindNextFile($search)

        If $file = "." Or $file = ".." Then ContinueLoop
        If @error Then
            FileClose($search)
            DisplayBanners()
        EndIf
    
        SplashImageOn($app & " " & $ver, $file, 160, 600, @DesktopWidth-165, @DesktopHeight-635, 3)
        
        If $fade>0 And $fade<255 Then
            WinSetTrans($app & " " & $ver, "", $fade)
            If @error Then
                MsgBox(16, $app & " " & $ver, "Transparency isn't supported by your OS. Please use the value '255' in the configurarion file. " & @LF & $app & " cannot proceed.")
                Terminate()
            EndIf
        EndIf

        Sleep($delay)
    WEnd
EndFunc

You see this "Sleep" function at the end of the code so as to allow the program delay before every SplashImageOn. The problem is that my program runs fine but after some time (more than an hour for sure) it produces the following error:

Line 0 (File "blah blah")

Sleep($delay)

Error: Recursion level has been exceeded - AutoIt will quit to prevent stack overflow.

Maybe I have missed something here, but I can't figure out what is it...

Thank you.

[jpm]

You are in the recursion game.

DisplayBanners is calling DisplayBanners.

The logic inside DisplayBanners must have a way to return. In your case there is nothing so the recursion will occurs and you will reach the recursion maximum limit which produce the error.

[erebus]

I can see your point.

However that is why I wrote this part of the code as a function, so as to call it again when I have no more files to display.

I used to have another similar problem yesterday with "invalid type handlers" which was solved by adding a FileClose($search) where it should be.

My question now (since I can't see how to solve this): Can I avoid this recursion somehow? The only thing I want is when I have no more files to read to run the function again so to start over. So probably the problem resides here:

If @error Then
            FileClose($search)
            DisplayBanners()
        EndIf

Any ideas?

[w0uter]

giant while loop of witch you start again at @error ?

[erebus]

Ok it seems that it works fine now. Just added this in my code:

While 1

DisplayBanners()

WEnd

So as to call it forever. Thanks for your answers guys, helped me a lot.

Edited June 27, 2005 by erebus

[/dev/null]

However that is why I wrote this part of the code as a function, so as to call it again when I have no more files to display.

Use this.

expandcollapse popup

while 1
    DisplayBanners("C:\pics\", "jpg")
wend

Func DisplayBanners($path, $type)

; Search for the JPG banners
    $search = FileFindFirstFile($path & "*." & $type)
; Check if the search was successful
    If $search = -1 Then
        MsgBox(16, $app & " " & $ver, "No " & $type & " files were found in " & $path & ". " & $app & " cannot proceed.")
        Terminate()
    EndIf

; Start displaying banners
    While 1
        $file = FileFindNextFile($search)

        If $file = "." Or $file = ".." Then ContinueLoop
        If @error Then
            FileClose($search)
            exitloop        
        EndIf
    
        SplashImageOn($app & " " & $ver, $file, 160, 600, @DesktopWidth-165, @DesktopHeight-635, 3)
        
        If $fade>0 And $fade<255 Then
            WinSetTrans($app & " " & $ver, "", $fade)
            If @error Then
                MsgBox(16, $app & " " & $ver, "Transparency isn't supported by your OS. Please use the value '255' in the configurarion file. " & @LF & $app & " cannot proceed.")
                Terminate()
            EndIf
        EndIf

        Sleep($delay)
    WEnd
EndFunc

Cheers

Kurt

[erebus]

Haha, exactly what I thought right now!

Thank you very much /dev/null, I really appreciate it.

[/dev/null]

Haha, exactly what I thought right now!

Thank you very much /dev/null, I really appreciate it.

<{POST_SNAPBACK}>

well, you have been faster

Cheers

Kurt