Read from Registry to Array

[Bodman]

Hi All,

I am trying to read the regkey HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Run and display the result in a array. I nearly have this working as it builds a array of 2 columns and the correct length but only the last entry of the registry is displayed. Can anyone point me in the right direction please

#include <array.au3>
Global $RegTot=""

For $i = 1 to 100
    $var = RegEnumVal("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Run", $i)
    If @error <> 0 then ExitLoop
    $var1 = Regread("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Run", $var)


ConsoleWrite ($var)
ConsoleWrite ($var1)
Global $Regtot[2][$i] = [[$Var], [$Var1]]

Next

_ArrayDisplay($Regtot, "Output", -1, 1)

$RegTot = ""

[Melba23]

Bodman,

You are constantly redeclaring your array inside the loop, so it only ever contains the final values. You need to use ReDim like this:

#include <array.au3>
Global $RegTot[1][2] = [[0, 0]]

For $i = 1 To 100
    $var = RegEnumVal("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Run", $i)
    If @error <> 0 Then ExitLoop
    $var1 = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Run", $var)

    ConsoleWrite($var)
    ConsoleWrite($var1)

    ; Resize the array while keeping existing elements
    ReDim $RegTot[$i + 1][2]
    $RegTot[$i][0] = $var
    $RegTot[$i][1] = $var1

Next

_ArrayDisplay($RegTot, "Output", -1, 1)

All clear?

M23

[Bodman]

Brilliant thank you, I was going around the bend trying to work this out

I looked at ReDim, but wasnt sure how to apply it.

Thanks again

Bodman