regexp to detect HEX

[bobbby]

I have created a string to hex and hex to string converter. But how do I detect if it's hex and not a string?

I tested with this but it fails for me sometimes. If i use a normal string.

expandcollapse popup

#include <string.au3>

$var = string2hex("this is a simple test")
$num = stringsplit($var,chr(32))
if isarray($num) and $num[0] > 0 then _run()

func _run()
    for $i = 1 to $num[0]
        if stringregexp($num[$i],'[A-F0-9]{2}') == 1 Then
        else
            $i = $num[0]
            consolewrite("No Hex"&@crlf)
        EndIf
    Next
    consolewrite("No errors was found"&@crlf)
EndFunc

func hex2string($hex)
    local $str = stringsplit($hex,chr(32))
    local $a
    if isarray($str) then
        if $str[0] > 0 then
            for $i = 1 to $str[0]
                $a = $a & _hextostring($str[$i])
            Next
            return $a
        Else
            return 0
        EndIf
    Else
        return 0
    EndIf
EndFunc


func string2hex($string)
    local $b
    for $i = 1 to stringlen($string)
        if $i == 1 Then
            $b = $b & _StringToHex(stringmid($string,$i,1))
        else
            $b = $b &" "&_StringToHex(stringmid($string,$i,1))
        EndIf
    Next
    return $b
EndFunc

Edited June 9, 2011 by bobbby

[BrewManNH]

I'm no regex expert, but deciding if a string is Hex by seeing if it contains A-F isn't going to work. There are plenty of Hex numbers that don't contain any of those characters. Take for instance "16" is that 22 in Hex, or 16 in base 10?

[jchd]

The best you can do is determine is a string _may_ be hex (possibly adding the criterion that its length should be even) or not.

Now, all this should use existing internal functions:

Local $str = 'abcde'

$hStr = Hex(StringToBinary(($str)))
ConsoleWrite($hStr & @LF)

$string = String(BinaryToString('0x' & $hStr))
ConsoleWrite($string & @LF)

ConsoleWrite("$hStr   is a possible hex string is " & (StringIsXDigit($hStr) = 1) & @LF)
ConsoleWrite("$string is a possible hex string is " & (StringIsXDigit($string) = 1) & @LF)

Local $test = 'grz hpo g42 jr574 h'
ConsoleWrite("$test   is a possible hex string is " & (StringIsXDigit($test) = 1) & @LF)

[GEOSoft]

Based on the suggestion (about checking to see if the length is an even number) from jchd and using RegEx this should put you on the right track but still may not be 100% accurate in all cases. Please remember that RegEx may in fact be slower than using the functions as given by jchd so avoid SREs if speed is important.

$sStr = StringRegExpReplace($sStr, "^0x([[:xdigit:]]+)$", "$1")
If (NOT Mod(StringLen($sStr), 2)) AND StringRegExp($sStr, "^[[:xdigit:]]+$") Then
    ConsoleWrite("Chances are good that the value is Hex" & @CRLF)
EndIf

Of course I just did a fast test of this and didn't try to implement it into your code.