Make _IsPressed() like HotKeySet?

[Donald8282]

Hello, I'm creating a way to move your mouse cursor with the arrow keys. I would like it so the keys don't let windows perform the functions they normally do. I do not want to use HotKeySet() because there is a delay in the action ending. I am using

Ex:

If _IsPressed() Then
MouseMove(x, y+1, 0)
EndIf

You get the idea. So, is there a way to make it so only my functions happen when these buttons are pressed?

Edited June 23, 2011 by Donald8282

[UEZ]

Try something like that:

#include <Misc.au3>
HotKeySet("{ESC}", "_Exit")

$dll = DllOpen("user32.dll")
$speed = 1
$acc = 1

While Sleep(10)
    $aMPos = MouseGetPos()
    If _IsPressed("25", $dll) And _IsPressed("12", $dll) Then ;alt + left
        MouseMove($aMPos[0] - $speed, $aMPos[1])
        $speed += $acc
    ElseIf _IsPressed("27", $dll) And _IsPressed("12", $dll) Then ;alt + right
        MouseMove($aMPos[0] + $speed, $aMPos[1])
        $speed += $acc
    ElseIf _IsPressed("26", $dll) And _IsPressed("12", $dll) Then ;alt + up
        MouseMove($aMPos[0], $aMPos[1] - $speed)
        $speed += $acc
    ElseIf _IsPressed("28", $dll) And _IsPressed("12", $dll) Then ;alt + down
        MouseMove($aMPos[0], $aMPos[1] + $speed)
        $speed += $acc
    Else
        $speed = 1
    EndIf
WEnd

Func _Exit()
    DllClose($dll)
    Exit
EndFunc

Br,

UEZ