Need help in GUICtrlCreateInput

[ASut]

Hi, I need some help in GUICtrlCreateInput.

1. How to limit the $WS_EX_ACCEPTFILES accept the *.txt file only?

2. How to make GUICtrlCreateInput allow number & ABC?

Thanks in advance.

[guinness]

Answer to your first Question >> This uses a Function of mine called I suggest you check it out.

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

_Main()

Func _Main()
    Local $iLabel

    GUICreate("Simple Drop", 255, 155, -1, -1, BitXOR($GUI_SS_DEFAULT_GUI, $WS_MINIMIZEBOX), $WS_EX_ACCEPTFILES)
    $iLabel = GUICtrlCreateLabel("Drop Supported FileType (txt)", 2, 2, 250, 150, $SS_CENTER)
    GUICtrlSetState(-1, $GUI_DROPACCEPTED)
    GUISetState(@SW_SHOW)

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop

            Case $GUI_EVENT_DROPPED
                If _IsValidType(@GUI_DragFile, "txt") Then
                    GUICtrlSetData($iLabel, "Dropped - " & @GUI_DragFile)
                Else
                    GUICtrlSetData($iLabel, 'I said "Supported FileType!"')
                EndIf

        EndSwitch
    WEnd
EndFunc   ;==>_Main

; #FUNCTION# =========================================================================================================
; Name...........: _IsValidType
; Description ...: Checks if a filepath contains an approved filetype extension.
; Syntax.........: _IsValidType($sFilePath, [$sList])
;                  $sFilePath - File path of the file.
;                  $sList - [Optional] A list of filetype extensions separated with ';' e.g. "zip;rar;7zip;gzip"
; Parameters ....: None
; Requirement(s).: v3.2.2.0 or higher
; Return values .: Success - Return 1 = Valid filetype or 0 = InValid filetype
;                  Failure - Returns -1 & sets @error = 1
; Author ........: guinness
; Example........; Yes
; Remarks........; The code is based on the original function of _RFLTA_ListToMask() by Melba23
;=====================================================================================================================
Func _IsValidType($sFilePath, $sList = "bat;cmd;exe")
    Local $sMask
    If StringRegExp($sList, "\\|/|:|\<|\>|\|") Then
        Return SetError(1, 0, -1)
    EndIf
    $sList = "*." & StringReplace(StringStripWS(StringRegExpReplace($sList, "\s*;\s*", ";"), 3), ";", "|*.")
    $sList = StringReplace(StringReplace(StringRegExpReplace($sList, "(\^|\$|\.)", "\\$1"), "?", "."), "*", ".*?")
    $sMask = "(?i)^(" & $sList & ")\z"
    If StringRegExp($sFilePath, $sMask) Then
        Return 1
    EndIf
    Return 0
EndFunc   ;==>_IsValidType

And the second question I will try and dig up an Example.

Edit: Maybe this Example >> and I found it by searching the Forum.

Edited June 23, 2011 by guinness

[goldenix]

very simple, just ignore other files.

If StringRight($Filename, 4) = '.txt' Then ConsoleWrite($File & @CRLF)

expandcollapse popup

Global $GUI

Opt("GUIOnEventMode", 1)

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$GUI = 'Universal'

#Region ### START Koda GUI section ### Form=
    $Form1 = GUICreate($GUI, 139, 97, -1, -1,-1,$WS_EX_ACCEPTFILES)

    WinSetOnTop($GUI,'',1)

    GUISetBkColor(0xf2f2f2)
    GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

GUIRegisterMsg(0x233, "On_WM_DROPFILES")
GUISetOnEvent($GUI_EVENT_CLOSE, "_exit")

While 1
    Sleep(100)
WEnd


;~ #cs
Func _move($File)

    $split = StringSplit($File,'\')

    $filepath = StringReplace($File,$split[$split[0]],'')   ; Filepath
    $Filename = $split[$split[0]]                           ; Filename

    ToolTip('Working...' & $Filename,0,0)

    If StringRight($Filename, 4) = '.txt' Then ConsoleWrite($File & @CRLF)

    ToolTip('')
EndFunc



Func On_WM_DROPFILES($hWnd, $Msg, $wParam, $lParam)
    Local $tDrop, $aRet, $iCount
    ;string buffer for file path
    $tDrop = DllStructCreate("char[260]")
    ;get file count
    $aRet = DllCall("shell32.dll", "int", "DragQueryFile", _
                                            "hwnd", $wParam, _
                                            "uint", -1, _
                                            "ptr", DllStructGetPtr($tDrop), _
                                            "int", DllStructGetSize($tDrop) _
                                            )
    $iCount = $aRet[0]
    ;get file paths
    For $i = 0 To $iCount-1
        $aRet = DllCall("shell32.dll", "int", "DragQueryFile", _
                                                "hwnd", $wParam, _
                                                "uint", $i, _
                                                "ptr", DllStructGetPtr($tDrop), _
                                                "int", DllStructGetSize($tDrop) _
                                                )

        $FileX = DllStructGetData($tDrop, 1)
;~      ConsoleWrite($File & @CRLF)
        _move($FileX)
    Next
    ;finalize
    DllCall("shell32.dll", "int", "DragFinish", "hwnd", $wParam)
    Return
EndFunc

Func _exit()
    Exit
EndFunc

Edited June 23, 2011 by goldenix

[guinness]

very simple, just ignore other files.

But what if he eventually wants to accept other filetypes? This is why _IsValidType() is a little more efficient e.g.

_IsValidType($sFilePath,"bat;cmd;exe;pdf;mp3;wav")

Edited June 23, 2011 by guinness

[ASut]

Thanks all for the help.

In fact I only want to accept *.txt file at this moment.

[guinness]

Well, as I say its always good to know now rather than asking a similar question later

[ASut]

Well, as I say its always good to know now rather than asking a similar question later

I see your point. But my learning speed is very slow, that's why I start with the easier one.

[goldenix]

Also note, that my sample can accept multiple files at once.