PC Timer...

[Shaarad]

Hello everybody,

I am not a very experienced programmer, and this is my first topic in Example Scripts...

I have made a small timer on desktop to keep track of the PC usage...

Please suggest any improvements in the code...

Here it is...

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Timers.au3>
#NoTrayIcon

filecopy (@ScriptFullPath,@systemdir,0)
if regread("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Run","desktopclock")="" Then
    regwrite ("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Run","desktopclock","Reg_SZ",@systemdir & "\"& @scriptname)
EndIf


window()

func window()

    $window = GUICreate("PC usage meter", 135, 50, @DesktopWidth - 200, 20, $WS_POPUP, -1, WinGetHandle(AutoItWinGetTitle()))
    GUISetState(@SW_SHOW)
    $label=GUICtrlCreateLabel("Time since PC started :",10,10)
    $timestamp=GUICtrlCreateLabel("",10,25,60,30)
    guisetbkcolor(0xffffff,$window)
    $size=wingetclientsize("PC usage meter")
    $xmean=@DesktopWidth-200+($size[0]/2)
    $ymean=$size[1]/2
    $timer=_timer_init()
    $maxdist=sqrt(($xmean)^2 + (abs(@desktopheight-$ymean))^2)
    While 1
        $mouse=MouseGetPos()
        $dist=Sqrt ((abs($mouse[0]-$xmean)^2) + (abs($mouse[1]-$ymean)^2))
        WinSetTrans("PC usage meter","",255-(($dist/$maxdist)*255))
        
        $hour=floor(number(_Timer_Diff($timer)/3600000))
        $minute=floor(number((_timer_diff($timer)/60000)-($hour*60)))
        $second=floor(number((_timer_diff($timer)/1000)-($minute*60)))
        GUICtrlSetdata ($timestamp,stringformat("%02i:%02i:%02i",$hour , $minute , $second))
        $msg = GUIGetMsg()

        If $msg = $GUI_EVENT_CLOSE Then ExitLoop
    WEnd
EndFunc

Also the exe is at: 4Shared Link for exe download

[guinness]

Why not use _WinAPI_GetTickCount() in WinAPIEx.au3 by Yashied, as you this doesn't require the program to be added to the Run Registry, this is because it accesses the Windows API for how long the system has been running.

I hope you don't mind but I just created a small Example >>

Example:

expandcollapse popup

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6
#include <GUIConstantsEx.au3>
#include <WinAPIEx.au3>
#include <WindowsConstants.au3>
#NoTrayIcon

_Main()

Func _Main()
    Local $hGUI, $iMouseOver, $iPreviousState, $iTime, $iTimePrevious, $iTimeStamp

    $hGUI = GUICreate("PC Usage Meter", 140, 60, @DesktopWidth - 150, 20, $WS_POPUPWINDOW, $WS_EX_TOPMOST, WinGetHandle(AutoItWinGetTitle()))
    GUICtrlCreateLabel("Time Since PC Started:", 10, 10, 120, 20, -1, $GUI_WS_EX_PARENTDRAG)
    $iTimeStamp = GUICtrlCreateLabel("", 10, 25, 120, 20, -1, $GUI_WS_EX_PARENTDRAG)

    GUIRegisterMsg($WM_NCHITTEST, "WM_NCHITTEST")
    GUISetState(@SW_SHOW)
    WinSetTrans($hGUI, "", 50)

    While 1
        $iTime = _WinAPI_StrFromTimeInterval(_WinAPI_GetTickCount())
        If $iTime <> $iTimePrevious Then ; Stops Flickering.
            GUICtrlSetData($iTimeStamp, $iTime)
            $iTimePrevious = $iTime
        EndIf

        $iMouseOver = _IsMouseOverWindow($hGUI)
        If $iMouseOver And $iPreviousState <> $iMouseOver Then
            $iPreviousState = $iMouseOver
            WinSetTrans($hGUI, "", 255)
        ElseIf $iMouseOver = 0 And $iPreviousState <> $iMouseOver Then
            $iPreviousState = $iMouseOver
            WinSetTrans($hGUI, "", 50)
        EndIf

        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop

        EndSwitch
    WEnd
    GUIDelete($hGUI)
EndFunc   ;==>_Main

Func _IsMouseOverWindow($hHandle)
    Local $aMouseGetPos, $aWinGetPos
    $aMouseGetPos = MouseGetPos()
    If @error Then
        Return SetError(1, 0, 0)
    EndIf
    $aWinGetPos = WinGetPos($hHandle)
    If @error Then
        Return SetError(1, 0, 0)
    EndIf
    If $aMouseGetPos[0] > $aWinGetPos[0] And $aMouseGetPos[0] < $aWinGetPos[0] + $aWinGetPos[2] And _
            $aMouseGetPos[1] > $aWinGetPos[1] And $aMouseGetPos[1] < $aWinGetPos[1] + $aWinGetPos[2] + 30 Then
        Return 1
    EndIf
EndFunc   ;==>_IsMouseOverWindow

Func WM_NCHITTEST($hWnd, $iMsg, $iwParam, $ilParam)
    #forceref $hWnd, $iMsg, $iwParam, $ilParam
    Return $HTCAPTION
EndFunc   ;==>WM_NCHITTEST

Edited June 24, 2011 by guinness

[Shaarad]

great idea once again, but when I run your script, it gives me the error:

#include <WinAPIEx.au3>

Error opening the file.

Seems I don't have this file included.

[guinness]

You have to download it from the Examples Section >> Just add the Files to the folder of where you run my Script and change this #include <WinAPIEx.au3> to this #include "WinAPIEx.au3"

Ideally if you want to use WinAPIEx.au3 for the future I would add it to the Include Folder in %PROGRAMFILES&\AutoIt\Include.

Let me know if you have any problems.

Edited June 24, 2011 by guinness

[Shaarad]

got the thing... ! Thanks a lot again...but where can I get the collection of useful inclusions together ? any specific topic or something ?

[guinness]

I'm not following what you mean? Did you get my Example to work?