how to use autoit to popup a menu?

[ogrish]

Hi,

I want to use AutoIt to do the following work. When pressing a predefined key, a menu pops up. Then I click one of the menu item, the correspond code executes. How to do this kind of thing? I can just use AutoIt to do jobs without GUI. Thanks.

[Xandy]

#include <Misc.au3>;include for _ispressed function
;#include <guiConstantsex.au3>;include for $gui_event_close value
$done= 0
;$guihandle= GUICreate("Hello world!, wtf am I supposed to do?¿", 420, 200);make a gui window
;$buttonmax= 5
;dim $button[$buttonmax]
;for $i= 0 to $buttonmax-1
;   $button[$i]= GUICtrlCreateButton("button "&$i, 10, 10+$i*22, 60, 20)
;next
;GUISetState();this code with empty set shows the gui window
while $done= 0;main loop
    ;$msg= GUIGetMsg();get messages from user interaction with gui
    if _IsPressed("0d") then 
        for $i= 500 to 2000
            beep($i, 1)
        next
    endif
    if _IsPressed("1b") then $done= 1
    ;if $msg= $gui_event_close then $done= 1;if the user clicks the X button at the top right of the gui window
wend

press ENTER for beep sound function

press ESC for a function to terminate the program

Not sure what you want do at be able.

Edited July 3, 2011 by songersoft

[monoscout999]

Search for Melba23 Toast in the example section. Forget it, look at this, maybe is useful

[Melba23]

ogrish,

Not sure my Toast UDF will help you too much - but this might:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

; Set a HotKey to call the menu GUI - here it is Ctrl-Shft-A
HotKeySet("^+a", "_Visible")

; Set a HotKey to exit
HotKeySet("{ESC}", "On_Exit")

Global $aItems[6][3] = [ _ ; Set the 6 to be one more than the number of items you want
    [5, 0, 0], _ ; Set the 5 to be the number of items
    ["Item 1", "What you want to do 1", 0], _ ; Just add the items here - [Button title, what you want to do, 0]
    ["Item 2", "What you want to do 2", 0], _
    ["Item 3", "What you want to do 3", 0], _
    ["Item 4", "What you want to do 4", 0], _
    ["Item 5", "What you want to do 5", 0]]

; Cretae the GUI
$hGUI = GUICreate("My PopUp Menu", 200, 20 * $aItems[0][0], -1, -1, BitOR($WS_POPUP, $WS_BORDER)) ; Change the -1, -1 to the coordinates you want
; Create the buttons
For $i = 1 To $aItems[0][0]
    $aItems[$i][2] = GUICtrlCreateButton($aItems[$i][0], 0, (20 * $i) - 20, 200, 20)
Next
; Hide the GUI until the Hotkey makes it visible
GUISetState(@SW_HIDE)

While 1

    $iMsg = GUIGetMsg()
    Switch $iMsg
        ; Look for the buttons
        Case $aItems[1][2] To $aItems[$aItems[0][0]][2]
            ; Hide the GUI again once a button is pressed
            GUISetState(@SW_HIDE)
            ; Get the index of the button pressed
            $iIndex = $iMsg - $aItems[1][2] + 1
            ; Display the action - you could use Run here to start an app
            MsgBox(0, "Action", $aItems[$iIndex][1])
    EndSwitch
WEnd

Func _Visible()
    ; When the HotKey is pressed make the GUI visible
    GUISetState(@SW_SHOW)
EndFunc

Func On_Exit()
    Exit
EndFunc

Please ask if you have any questions.

M23

[ProgAndy]

If you want a context-menu like interface, you can use this code:

#include<WindowsConstants.au3>
#include<GUIMenu.au3>
HotKeySet("{F10}", "_Show")
$hGUI = GUICreate("", 1, 1, -5, -5, $WS_POPUP, $WS_EX_TOOLWINDOW)
$ctlMenu = GUICtrlCreateContextMenu()
$ctlMenuAlert = GUICtrlCreateMenuItem("Alert", $ctlMenu)
$ctlMenuClose = GUICtrlCreateMenuItem("Exit", $ctlMenu)
While 1
    Switch GUIGetMsg()
        Case $ctlMenuAlert
            MsgBox(0, '', "Message")
        Case $ctlMenuClose
            Exit
    EndSwitch
WEnd

Func _Show()
    GUISetState(@SW_SHOW, $hGUI)
    _GUICtrlMenu_TrackPopupMenu(GUICtrlGetHandle($ctlMenu), $hGUI, -1, -1, 1, 1, 1)
    GUISetState(@SW_HIDE, $hGUI)
EndFunc

[ogrish]

Thanks everyone! With you guy's help I solved this problem! Thanks!