Auto-fill drop down

[nevodj]

Hello,

i've searched the forum but i can't find anything on how to make a combo box autofill as you type.

example, in the drop down list of customers there could be a company name ABC Engineering.

as you type ABC it would put the closest match in.

you can do it by clicking on the dropdown or pushing the F4 key but i wondered if it could happen automatically.

thanks!

[ahmet]

Maybe by czardas can help.

[Melba23]

nevodj,

You do it like this:

#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiComboBox.au3>

Dim $sString = "Hello|world|AutoIt|rules|and|more|some|data"

$hGUI = GUICreate("Search in combo demo", 300, 200)

$hCombo = GUICtrlCreateCombo("", 70, 75, 170, 20)
GUICtrlSetData(-1, $sString, "Hello")

GUIRegisterMsg($WM_COMMAND, "WM_COMMAND")

GUISetState()

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

Func WM_COMMAND($hWnd, $Msg, $wParam, $lParam)
    Local $iIDFrom = BitAND($wParam, 0x0000FFFF)
    Local $iCode = BitShift($wParam, 16)
    
    Switch $iIDFrom
        Case $hCombo
            Switch $iCode
                Case $CBN_EDITCHANGE
                    _GUICtrlComboBox_AutoComplete($hCombo)
            EndSwitch
    EndSwitch
    
    Return $GUI_RUNDEFMSG
EndFunc   ;==>WM_COMMAND

I hope that helps.

M23

[nevodj]

Awesome, thanks very much!