Trying to remove character at specific position with StringRegExp

[supersonic]

Hi!

I'm trying to remove a character at a specific position (somewhere in the string) with StringRegExp.

Here's my current "workaround":

For $i In StringRegExp(StringReplace("1234567890", 3, "X"), "[^X]", 3)
    ConsoleWrite("___" & $i & @CRLF)
Next

Is there a way to do this with StringRegExp only?

Greets,

-supersonic.

Edited August 5, 2011 by supersonic

[martin]

Hi!

I'm trying to remove a character at a specific position (somewhere in the string) with StringRegExp.

Here's my current "workaround":

For $i In StringRegExp(StringReplace("1234567890", 3, "X"), "[^X]", 3)
    ConsoleWrite("___" & $i & @CRLF)
Next

Is there a way to do this with StringRegExp only?

Greets,

-supersonic.

If you only want to remove a particular character couldn't you just use

$newstring = StringReplace("1234567890", 3, "")

[supersonic]

I would like to remove a character by position. I don't know what character it is. I know only its position and its position could change.

Furthermore the result should be returned as an array for loop processing.

My example works well - but I would like to avoid using StringReplace.

Edited August 5, 2011 by supersonic

[Malkey]

Here are a couple of ways.

Local $str = "1234567890"
Local $CharPos = 3

For $i In StringSplit(StringReplace($str, StringMid($str, $CharPos, 1), ""), "", 2)
    ConsoleWrite("___" & $i & @CRLF)
Next

ConsoleWrite(@LF)
;or
For $i In StringSplit(StringLeft($str, $CharPos - 1) & StringRight($str, StringLen($str) - $CharPos), "", 2)
    ConsoleWrite("___" & $i & @CRLF)
Next

ConsoleWrite(@LF)
;or
For $i In StringRegExp(StringLeft($str, $CharPos - 1) & StringRight($str, StringLen($str) - $CharPos), "(.)", 3)
    ConsoleWrite("___" & $i & @CRLF)
Next

Edit:: Added third method.

Edited August 5, 2011 by Malkey

[UEZ]

What about this version?

#include <Array.au3>
$string = "abcdefg1hijklm"
$rem_pos = 8
$array = StringSplit(StringLeft($string, $rem_pos - 1) & StringRight($string, StringLen($string) - $rem_pos), "", 2)
_ArrayDisplay($array)

Edit: ok, it is similar to Malkey's 3rd example.

Br,

UEZ

Edited August 5, 2011 by UEZ

[supersonic]

Thank you! - I have already thought about your examples.

I was looking for solving this with StringRegExp only to make it as short as possible.

Is there really no regular expression to point to a single character position?

[Malkey]

Another way.

Local $str = "1234567890"
Local $CharPos = 3

For $i In StringRegExp(StringRegExpReplace($str, "(.{0," & ($CharPos - 1) & "})(.?)(.*)", "\1\3"), "(.)", 3)
    ConsoleWrite("___" & $i & @CRLF)
Next

[PowerCat]

Wait, you'd like to remove a character which changes, at a position which changes?

Are there any constants in your strings?

Edited August 5, 2011 by PowerCat

[wakillon]

Another way

Local $_String = "abcdefg1hijklm", $_Pos = 8
ConsoleWrite ( "Result : " & StringMid ( $_String, 1, $_Pos-1 ) & StringMid ( $_String, $_Pos+1 ) & @Crlf )

[supersonic]

@PowerCat:

You are right!

Everything could change - The character and its position and the string length itself.

The only constant I have is the position of the character.

I hope there is a search pattern to remove character at a specific position...

[PowerCat]

That's very nebulous and unclear.

You claim both that its position "could change" and then claim that you "only know its position"

Can it change or not?? I'm confused. How do you change something which you don't know what it is, at a position which you don't know either? How do you know what to change?

You can simply use StringLeft\Right to grab what's before and after

Like if it's always the third char in a string of 10 char,

$str = "1234567890"

$str1 = StringLeft($str, "2") & StringRight($str, "7")

ConsoleWrite($str1)

Edited August 11, 2011 by PowerCat

[GEOSoft]

Is this what you are looking for?

$s_String = "This is a test string."
$s_Char = "r"
$a_SRE = StringRegExp($s_String, "(?i)^(.+?)(" & $s_Char & ")(.*)$", 3);; Everything preceeding $s_Char is in [0] $s_Char is in [1] and the balance is in [2]

If you want it to be case sensitive remove the "(?i)"

Edited August 11, 2011 by GEOSoft