Auto Drop ComboBox - solved

[DicatoroftheUSA]

I have a gui for most buttons and checkboxes I name with "&exemple" for keyboard navigation.

I have a combo box, that when clicked on, it drops and then the user can click on an item in the list. When the user clicks on an item it takes that text and puts into an input box. Basically it lists field headers as a helper for a sqlite database syntax.

The problem is, I can set a hotkey for the input box label, it gives it focus, but it does not drop the box down. The down arrow does not cause it to drop when it has focus either, it will just select the next item in the box.

I would like it that when a hotkey is pressed to give the combobox focus, and if the down arrow is pressed, it drops down automatically,

TIA

Edited September 6, 2011 by DicatoroftheUSA

[pieeater]

take a look at ContolCommand() And GUICtrlSetState() in the help file

Edited September 1, 2011 by pieeater

[DicatoroftheUSA]

take a look at ContolCommand() And GUICtrlSetState() in the help file

It goes without saying. I did, and it didn't help. Which should go without saying, else I would not have posted. Please don't make useless replies, it wastes time; mine, yours, and everyone else who might be looking for a similar issue. If your trying to make yourself look smart by being a sarcastic smartass, you failed.

Below is an example of my script. I need it so that when in the below example, when alt+f or alt+C is pressed the respective input box drops. In the below example, clicking on the label, it does what I want it to be able to do with the keyboard. As it is, with the keyboard, it just gives focus.

#include <GUIConstantsEx.au3>
#include <ComboConstants.au3>
$loGUI=GUICreate("EXAMPLE")
 
$loInpSelect = GUICtrlCreateInput('select  * from records where scandate>' & @YEAR & @MON & @MDAY & 0000 & ' order by scandate limit 254;', 10, 10,400,200)
$loLColumn=GUICtrlCreateLabel("&Fields", 10,215)
$loComboColumns = GUICtrlCreateCombo("", 10,240,100,20,BitOr($GUI_SS_DEFAULT_COMBO, $CBS_DROPDOWNLIST))
GUICtrlSetData($loComboColumns,"EXAMPLE1")
GUICtrlSetData($loComboColumns,"EXAMPLE2")
$lolCommand=GUICtrlCreateLabel("&Compare", 120, 215)
$loComboCommands = GUICtrlCreateCombo("", 120, 240,100,20,  BitOr($GUI_SS_DEFAULT_COMBO, $CBS_DROPDOWNLIST))
GUICtrlSetData($loComboCommands,"EXAMPLE3")
GUICtrlSetData($loComboCommands,"EXAMPLE4")
GUISetState()
WHILE 1
  SWITCH GUIGetMsg()
   Case $loComboColumns
    GUICtrlSetData($loInpSelect, GUICtrlRead($loComboColumns), "test")
   Case $loComboCommands
    GUICtrlSetData($loInpSelect, GUICtrlRead($loComboCommands), "test")
   CASE $loLColumn
    ConsoleWrite("hugh")
    ControlCommand($loGUI,"",$loComboColumns,"ShowDropDown", "")
   CASE $lolCommand
    ConsoleWrite("hugh")
    ControlCommand($loGUI,"",$loComboCommands,"ShowDropDown", "")
   Case $GUI_EVENT_CLOSE
    GUIDelete($loGUI)
    ExitLoop
   EndSwitch
WEnd

Edited September 1, 2011 by DicatoroftheUSA

[nevodj]

HotKeySet("^d","dropdown")

Func dropdown()

Guictrlsetstate($comboname, $GUI_FOCUS)

Send("{F4}")

otherwise check this post -

Edited September 1, 2011 by nevodj

[nevodj]

Send F4 will drop the combo box down

[pieeater]

#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
HotKeySet("!f", "_drop")
HotKeySet("!c", "_undrop")
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 310, 152, 361, 178)
Global $Combo1 = GUICtrlCreateCombo("Combo1", 16, 64, 145, 25)
GUICtrlSetData(-1, "i|see|this|script|works")
$Label1 = GUICtrlCreateLabel("Press Alt+f to drop the box", 16, 16, 128, 17)
$Label2 = GUICtrlCreateLabel("Press Alt+c to undrop the box", 16, 40, 143, 17)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###
 
While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd
 
Func _drop()
    ControlCommand("Form1", "", $Combo1, "ShowDropDown", "")
EndFunc
 
Func _undrop()
    ControlCommand("Form1", "", $Combo1, "HideDropDown", "")
EndFunc

#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <Misc.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 310, 152, 361, 178)
$Combo1 = GUICtrlCreateCombo("Combo1", 16, 64, 145, 25)
GUICtrlSetData(-1, "i|see|this|script|works")
$Label1 = GUICtrlCreateLabel("Press Alt+f to drop the box", 16, 16, 128, 17)
$Label2 = GUICtrlCreateLabel("Press Alt+c to undrop the box", 16, 40, 143, 17)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###
 
While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
    If _IsPressed(12) And _IsPressed(46) Then
        ControlCommand("Form1", "", $Combo1, "ShowDropDown", "")
    ElseIf _IsPressed(12) And _IsPressed(43) Then
        ControlCommand("Form1", "", $Combo1, "HideDropDown", "")
    EndIf
WEnd

Examples of how to use them, both ways i believe you will find work

Edited September 1, 2011 by pieeater

[DicatoroftheUSA]

Thanks guys, what I ended up doing is below. I really like to minimize global declares, registers, and process usage, as my scripts tend to get massive. I need them to be easy enouph to read, with clearcut cause>effect chains, that neophyte coworkers can manipulate it when needed, and can eventually be turned into #includes without worry.

The problem with below, is the mouse no longer works on the combobox as expected for an end user, but that is a better problem than not having keyboard control. And worse, it forces them to select something. I know I can write a process hungry escape pattern, but I want it to be lean. I would appreciate any further tips.

expandcollapse popup

#include <GUIConstantsEx.au3>
#Include <Misc.au3>
#include <ComboConstants.au3>
$loGUI = GUICreate("EXAMPLE")
 
_gui()
func _gui()
$loInpSelect = GUICtrlCreateInput('select  * from records where scandate>' & @YEAR & @MON & @MDAY & 0000 & ' order by scandate limit 254;', 10, 10, 400, 200)
$loLColumn = GUICtrlCreateLabel("&Fields", 10, 215)
$loComboColumns = GUICtrlCreateCombo("", 10, 240, 100, 20, BitOR($GUI_SS_DEFAULT_COMBO, $CBS_DROPDOWNLIST))
GUICtrlSetData($loComboColumns, "EXAMPLE1")
GUICtrlSetData($loComboColumns, "EXAMPLE2")
$lolCommand = GUICtrlCreateLabel("&Compare", 120, 215)
$loComboCommands = GUICtrlCreateCombo("", 120, 240, 100, 20, BitOR($GUI_SS_DEFAULT_COMBO, $CBS_DROPDOWNLIST))
GUICtrlSetData($loComboCommands, "EXAMPLE3")
GUICtrlSetData($loComboCommands, "EXAMPLE4")
GUISetState()
$loDll = DllOpen("user32.dll")
While 1
Switch GUIGetMsg()
  Case $GUI_EVENT_CLOSE
   GUIDelete($loGUI)
   ExitLoop
EndSwitch
_UnMouseCombo($loGui,$loComboColumns,$loInpSelect,$loDll )
_UnMouseCombo($loGui,$loComboCommands,$loInpSelect,$loDll )
 
WEnd
DllClose($loDll)
EndFunc
Func _UnMouseCombo($loGui,$loCombo,$loRefocus,$loDll )
WHILE 1
$X=0
If ControlGetHandle($loGUI, "", ControlGetFocus($loGUI)) = GUICtrlGetHandle($loCombo) AND $X=0 Then
  ControlCommand($loGUI,"",$loCombo,"ShowDropDown", "")
  $X=1
  If _IsPressed('0D', $loDll) Or _IsPressed('20', $loDll) Then
   ControlFocus($loGui,"",$loRefocus)
   GUICtrlSetData($loRefocus, GUICtrlRead($loRefocus)&" "&  GUICtrlRead($loCombo)&" ")
   RETURN (1)
  EndIf
else
  SetError(2)
  ControlCommand($loGUI,"",$loCombo,"HIDEDropDown", "")
  Return (-1)
  ExitLoop
EndIf
WEnd
EndFunc

Edited September 2, 2011 by DicatoroftheUSA

[nevodj]

the easiest way is for the user to press F4 to drop / minimize the combobox... it's a standard windows function... why complicate your script by replicating it.

[DicatoroftheUSA]

the easiest way is for the user to press F4 to drop / minimize the combobox... it's a standard windows function... why complicate your script by replicating it.

To answer your retorical question in short; it is because the drop down combo object is doesn't work as I need it to. If the solution was so simple, I wouldn't have posted. If I am not making it clear on what I am trying to accomplish, let me know how to clarify. If you are being snarky, shame on you for wasting everyones time.

What happens when they press f4, and then use the arrow keys, every time the arrow key is pressed it registers with guigetmsg() and performs the function, namely reading the value and appending it to an input box. I only want that after their selection is highlighted and press enter, or click on it. If you run the first example script, you will note this behavoir.

For some reason if I try to modify that behavior by making so that under guigetmsg=combo, if I use _ispressed is mouse click or keyboard. It doesn't run the function. Also if I just check for the enter or click event, and then check for focus, it would cause problems, as it is possible for the user to click another portion of the gui while the combobox still has focus.

I could use hotkey set, but as I stated before, I hate using global values and functions, as I intend this to be modular and used under different applications, and I would rather use a method that won't eventually cause conflicts. And ultamately I bet it is unnescessary, because I am familiar with other native windows apps that behave in the way I am trying accomplish here.

If a solution doesn't come up soon, I think I will just have to make a popup child gui. It is much uglier in script and in UI, but I am short on ideas.

Edited September 6, 2011 by DicatoroftheUSA

[BrewManNH]

Create a button that is used to activate the Combobox selection instead. This way you can scroll up and down the list as much as you want, but until you press the button, nothing gets activated. I took your script and added a button to the GUI and a message box to demonstrate one way to do it.

Func _gui()
    $loInpSelect = GUICtrlCreateInput('select  * from records where scandate>' & @YEAR & @MON & @MDAY & 0000 & ' order by scandate limit 254;', 10, 10, 400, 200)
    $loLColumn = GUICtrlCreateLabel("&Fields", 10, 215)
    $loComboColumns = GUICtrlCreateCombo("", 10, 240, 100, 20, BitOR($GUI_SS_DEFAULT_COMBO, $CBS_DROPDOWNLIST))
    GUICtrlSetData($loComboColumns, "EXAMPLE1")
    GUICtrlSetData($loComboColumns, "EXAMPLE2")
    $lolCommand = GUICtrlCreateLabel("&Compare", 120, 215)
    $loComboCommands = GUICtrlCreateCombo("", 120, 240, 100, 20, BitOR($GUI_SS_DEFAULT_COMBO, $CBS_DROPDOWNLIST))
    GUICtrlSetData($loComboCommands, "EXAMPLE3")
    GUICtrlSetData($loComboCommands, "EXAMPLE4")
    $Button1 = GUICtrlCreateButton("GO", 20, 300)
    GUISetState()
    $loDll = DllOpen("user32.dll")
    While 1
         Switch GUIGetMsg()
             Case $GUI_EVENT_CLOSE
                  GUIDelete($loGUI)
                  Exit
             Case $Button1
                  MsgBox(0, "", "ComboBox1 reads: " & GUICtrlRead($loComboColumns) & @CRLF & "ComboBox2 reads: " & GUICtrlRead($loComboCommands))
        EndSwitch
;~   _UnMouseCombo($loGUI, $loComboColumns, $loInpSelect, $loDll)
;~   _UnMouseCombo($loGUI, $loComboCommands, $loInpSelect, $loDll)
      WEnd
       DllClose($loDll)
EndFunc   ;==>_gui

[DicatoroftheUSA]

@BrewManNH -Thanks, I thought of that, but for this application, it is not intuitive enouph. In nature this application going to be unavoidably too complex for its users, any multistep buttons, even clicking an extra couple buttons (ie tab+enter) will slow them down too much and cause their heads to explode.

I think I will settle with the script below, and teach them f4. Marking as solved.

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <ComboConstants.au3>
#include <Misc.au3>
 
Local $loComboSelection
$loGUI = GUICreate("EXAMPLE")
$loDLL = DllOpen("user32.dll")
$loInpSelect = GUICtrlCreateInput('select  * from records where scandate>' & @YEAR & @MON & @MDAY & 0000 & ' order by scandate limit 254;', 10, 10, 400, 200)
$loLColumn = GUICtrlCreateLabel("&Fields", 10, 215)
$loComboColumns = GUICtrlCreateCombo(" ", 10, 240, 100, 20, BitOR($GUI_SS_DEFAULT_COMBO, $CBS_DROPDOWNLIST))
GUICtrlSetData($loComboColumns, "EXAMPLE1")
GUICtrlSetData($loComboColumns, "EXAMPLE2")
$lolCommand = GUICtrlCreateLabel("&Compare", 120, 215)
$loComboCommands = GUICtrlCreateCombo(" ", 120, 240, 100, 20, BitOR($GUI_SS_DEFAULT_COMBO, $CBS_DROPDOWNLIST))
GUICtrlSetData($loComboCommands, "EXAMPLE3")
GUICtrlSetData($loComboCommands, "EXAMPLE4")
GUISetState()
 
While 1
Switch GUIGetMsg()
  Case $loComboColumns
;~  GUICtrlSetData($loInpSelect, GUICtrlRead($loComboColumns), "test")
   $loComboSelection = GUICtrlRead($loComboColumns)
   GUICtrlSetData($loComboCommands, " ")
  Case $loComboCommands
;~  GUICtrlSetData($loInpSelect, GUICtrlRead($loComboCommands), "test")
   $loComboSelection = GUICtrlRead($loComboCommands)
   GUICtrlSetData($loComboColumns, " ")
  Case $loLColumn
   ControlCommand($loGUI, "", $loComboColumns, "ShowDropDown", "")
  Case $lolCommand
   ControlCommand($loGUI, "", $loComboCommands, "ShowDropDown", "")
  Case $GUI_EVENT_CLOSE
   GUIDelete($loGUI)
   ExitLoop
EndSwitch
If WinActive($loGUI) Then
  _HandleBox($loGUI, $loComboColumns, $loInpSelect, $loDLL)
  _HandleBox($loGUI, $loComboCommands, $loInpSelect, $loDLL)
EndIf
WEnd
Sleep(100)
Func _HandleBox($loGUI, $loComboBox, $loInputBox, $loDLL)
Local $lsRead
If _GuiCtrlGetFocus($loGUI) = $loComboBox Then
If _IsPressed('01', $loDLL) Or _IsPressed('0D', $loDLL) Then
   $lhGui = GUICtrlGetHandle($loGUI)
   If GUICtrlRead($loComboBox) <> "" Then
    $lsRead = GUICtrlRead($loComboBox)
    GUICtrlSetData($loComboBox, " ")
    While _IsPressed('01', $loDLL) Or _IsPressed('0D', $loDLL)
     Sleep(1)
    WEnd
    GUICtrlSetData($loInpSelect, $lsRead, "test")
   EndIf
  EndIf
EndIf
EndFunc   ;==>_HandleBox
 
Func _GuiCtrlGetFocus($GuiRef)
Local $hwnd = ControlGetHandle($GuiRef, "", ControlGetFocus($GuiRef))
Local $result = DllCall("user32.dll", "int", "GetDlgCtrlID", "hwnd", $hwnd)
Return $result[0]
EndFunc   ;==>_GuiCtrlGetFocus

Edited September 6, 2011 by DicatoroftheUSA