How do I swap "Last, First" to "First Last" name in array.

[JailDoctor]

I want to fix an array containing names in the format “Last, First” to “First Last.”

Example: Smith, John to John Smith

I played with “StringRegExp” with no results.

A little guidance will be appreciated

Edited September 2, 2011 by JailDoctor

[pieeater]

id say look at StringSplit(). here is how id do it:

For $i = 1 To UBound($array)
     $nString = StringSplit($array[$i], ", ")
     $array[$i] = $nString[1] & " " & $nString[0] ;if the syntax is wrong im sorry im at work right now and dont have the help file
Next
For $i = 1 To UBound($array)
     ConsoleWrite($array[$i] & @LF);this is just to check what the output is
Next

Edited September 2, 2011 by pieeater

[MrMitchell]

#include <Array.au3>
 
Dim $array[3] = ["Smith, John", "Doe, Jim", "Man, Bat"]
 
_ArrayDisplay($array)
 
For $i = 0 To UBound($array) - 1
    $array[$i] = StringRegExpReplace($array[$i], "(.*),(.*)", "\2 \1")
Next
 
_ArrayDisplay($array)

Except you end up with two spaces between the names depending on how the original array is, but it's easily fixable

Edit2: No more extra spaces and whatnot...

#include <Array.au3>
Dim $array[3] = ["Smith, John  ", "Doe, Jim", "Man, Bat"]
_ArrayDisplay($array)
For $i = 0 To UBound($array) - 1
$array[$i] = StringStripWS(StringRegExpReplace($array[$i], "(.*),(.*)", "\2 \1"), 1 + 2 + 4)
Next
_ArrayDisplay($array)

Edited September 2, 2011 by MrMitchell

[BrewManNH]

Here's my take on it, using 1 and 2D arrays.

#include <array.au3>
; Example for 2D array
Global $NewArray[4][2], $NewArray1[4]
Global $Array[4][2] = [["Smith", "John"],["Jones", "Mary"],["Johnson", "Peter"],["Fitch", "Abercrombie"]]
_ArrayDisplay($Array, "$Array before reformatting")
For $I = 0 To UBound($Array) - 1
     $NewArray[$I][0] = $Array[$I][1]
     $NewArray[$I][1] = $Array[$I][0]
Next
$Array = $NewArray
_ArrayDisplay($Array, "$Array after reformatting")
; Example for 1D array
Global $Array1[4] = ["Smith, John", "Jones, Mary", "Johnson, Peter", "Fitch, Abercrombie"]
_ArrayDisplay($Array1, "$Array1 before reformatting")
For $I = 0 To UBound($Array1) - 1
     $aStrings = StringSplit($Array1[$I], ",")
     $String = ""
     For $X = $aStrings[0] To 1 Step -1
          $String &= $aStrings[$X] & " "
     Next
      $NewArray1[$I] = StringTrimRight($String, 1)
Next
$Array1 = $NewArray1
_ArrayDisplay($Array1, "$Array1 after reformatting")

Edited September 2, 2011 by BrewManNH

[GEOSoft]

Here is the RegEx version

$sStr = "Smith, John"
$sStr = StringRegExpReplace($sStr, "^(.+)\b.+\b(.+)$", "$2 $1")
MsgBox(0, "Result", $sStr)

EDIT: Of course you would just swap the array element for $sStr in your loop.

Edited September 3, 2011 by GEOSoft

[JailDoctor]

Worked like a charm.

Thanks a lot guys.

It is basically what I used to do in VBA (\2 \1), I just didn't know how to put the pieces together.

[GEOSoft]

RegEx in AutoIt is pretty much the same as in the engine they use for VB. You could also use "\2 \1" but using the "$" in place of "\" is always the prefered method and that applies to any engine.