Prevent listview column resize

[Mikeman27294]

Hey guys, I have a column in a listview which is meant to be hidden but not deleted. The reason for this, is because the listview will hold values from an inisectionread and I dont want the names of the keys to appear. Is this possible?

Thanks.

[guinness]

If the values are numerical then may I suggest using _GUICtrlListView_SetItemParam() & _GUICtrlListView_GetItemParam()

[Melba23]

Mikeman27294,

To hide a column, just use _GUICtrlListView_SetColumnWidth to set the column width to 0:

#include <GuiConstantsEx.au3>
#include <GuiListView.au3>
 
GUICreate("ListView Set Column Width", 400, 300)
$hListView = GUICtrlCreateListView("Column 1|Column 2|Column 3|Column 4", 2, 2, 394, 268)
GUISetState()
 
; Change column 1 width
MsgBox(4160, "Information", "Column 1 Width: " & _GUICtrlListView_GetColumnWidth($hListView, 0))
_GUICtrlListView_SetColumnWidth($hListView, 0, 0)
MsgBox(4160, "Information", "Column 1 Width: " & _GUICtrlListView_GetColumnWidth($hListView, 0))
 
; Loop until user exits
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

To answer the question in the title, just disable the header:

#include <GuiConstantsEx.au3>
#include <GuiListView.au3>
 
$hGUI = GUICreate("ListView Set Column Width", 400, 300)
$hListView = GUICtrlCreateListView("Column 1|Column 2|Column 3|Column 4", 2, 2, 394, 268)
GUISetState()
 
; Prevent resizing of columns
ControlDisable($hGUI, "", HWnd(_GUICtrlListView_GetHeader($hListView)))
 
; Loop until user exits
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

And before you ask, just use ControlEnable to reenable it.

All clear?

M23

[Mikeman27294]

Ah thanks. I have never heard of that ControlDisable one before. I will take a look to make sure it works with my script.

[Zedna]

To answer the question in the title, just disable the header:

Nice find Melba!

[Mikeman27294]

Aah... I found that I had to disable it like this:

ControlDisable($ColumnID, "", "")

Otherwise it would disabl my entire GUI.

But it has worked. Thanks.

Edited September 11, 2011 by Mikeman27294

[Melba23]

Mikeman27294,

Your use of ControlDisable makes no sense at all - the parameters are ("GUI title", "GUI text", "Control ID") and the command works perfectly when you use them, as my example shows. And I do not see how you can disable an entire GUI with this function!

What is "$ColumnID"?

Could you post the code you ended up with?

M23

[Mikeman27294]

Yeah that didnt work for me.

$ColumnID is a variable with the Control ID of the column. I stored it in an array and it works perfectly now, whereas when I tried exactly what you said, it disabled the entire GUI, which has a dropdown box in it to allow the user to change the data.

Anyway, it is fixed now, so thanks.

[netegg]

Mikeman27294,

To hide a column, just use _GUICtrlListView_SetColumnWidth to set the column width to 0:

#include <GuiConstantsEx.au3>
#include <GuiListView.au3>

GUICreate("ListView Set Column Width", 400, 300)
$hListView = GUICtrlCreateListView("Column 1|Column 2|Column 3|Column 4", 2, 2, 394, 268)
GUISetState()

; Change column 1 width
MsgBox(4160, "Information", "Column 1 Width: " & _GUICtrlListView_GetColumnWidth($hListView, 0))
_GUICtrlListView_SetColumnWidth($hListView, 0, 0)
MsgBox(4160, "Information", "Column 1 Width: " & _GUICtrlListView_GetColumnWidth($hListView, 0))

; Loop until user exits
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

To answer the question in the title, just disable the header:

#include <GuiConstantsEx.au3>
#include <GuiListView.au3>

$hGUI = GUICreate("ListView Set Column Width", 400, 300)
$hListView = GUICtrlCreateListView("Column 1|Column 2|Column 3|Column 4", 2, 2, 394, 268)
GUISetState()

; Prevent resizing of columns
ControlDisable($hGUI, "", HWnd(_GUICtrlListView_GetHeader($hListView)))

; Loop until user exits
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

And before you ask, just use ControlEnable to reenable it.

All clear?

M23

this will disable all columns, is it possible to disable just one column (for example, the first column)?

[Melba23]

netegg,

That was fun!

Here is how you can do it:

expandcollapse popup

#include <GuiConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>
#include <HeaderConstants.au3>

$hGUI = GUICreate("ListView Fix Column Width", 400, 300)
$hListView = GUICtrlCreateListView("Column 0|Column 1|Column 2|Column 3", 2, 2, 394, 268)
GUISetState()

; Prevent resizing of a specific column (0-based)
Global $iFix_Col = 1

GUIRegisterMsg($WM_NOTIFY, "_WM_NOTIFY")

; Loop until user exits
Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

Func _WM_NOTIFY($hWnd, $iMsg, $wParam, $lParam)

    ; Get details of message
    Local $tNMHEADER = DllStructCreate($tagNMHEADER, $lParam)
    ; Look for header resize code
    $iCode = DllStructGetData($tNMHEADER, "Code")
    Switch $iCode
        Case $HDN_BEGINTRACKW
            ; Now get column being resized
            Local $iCol = DllStructGetData($tNMHEADER, "Item")
            If $iCol = $iFix_Col Then
                ; Prevent resizing
                Return True
            Else
                ; Allow resizing
                Return False
            EndIf
    EndSwitch

EndFunc

All clear?

M23

[BrewManNH]

That is a very slick method, I like it.

[Melba23]

BrewManNH,

Thanks. It took a fair bit of Googling and MSDN searching but the end result was worth it. I suppose it could be improved with the cursor not changing - but I will leave that to someone else.

M23

[Zedna]

Nice Melba!!