help with: StringRegExpReplace()

[scraps]

Hi Guys,

I have been trying to work with StringRegExpReplace() , but have had no such luck.

I am wanting to extract just the MACaddress from string.

77.10.119.232   - 255.255.254.0  - 00-15-46-5b-0t-z4   -27/09/2011 8:30:52 AM  -D-  PC0005.test.local

- after the IP there is 3 spaces then a hyphen, subnet, 2 white spaces, hypen, white space then mac address.

If someone could help me with a break down of various expressions I would use.

thanks in advance.

[PsaltyDS]

That's not a valid MAC address because it has non-hex characters in it, but if it was valid:

$sString = "77.10.119.232   - 255.255.254.0  - 00-15-46-5b-07-e4   -27/09/2011 8:30:52 AM  -D-  PC0005.test.local"
ConsoleWrite("$sString = " & $sString & @LF)
$sString = StringRegExpReplace($sString, "[[:xdigit:]]{2}-[[:xdigit:]]{2}-[[:xdigit:]]{2}-[[:xdigit:]]{2}-[[:xdigit:]]{2}-[[:xdigit:]]{2}", "FE-DC-BA-98-76-54")
ConsoleWrite("$sString = " & $sString & @LF)

[Damein]

I'm not sure if this is the BEST way to do it, but I did it like so:

Global $String = "77.10.119.232   - 255.255.254.0  - 00-15-46-5b-0t-z4   -27/09/2011 8:30:52 AM  -D-  PC0005.test.local"
 
ConsoleWrite($String & @CRLF)
 
$NewString = StringRegExp($String,'(?i)(?s)255.(.*?)- (.*?) ',3)
 
ConsoleWrite($NewString[1])

And it read it just fine.

Edited September 16, 2011 by Damein

[smashly]

Hi,

There's probably a better search pattern, but I gave it a shot.

Global $sString, $aSRE
 
$sString = "77.10.119.232   - 255.255.254.0  - 00-15-46-5b-0t-z4   -27/09/2011 8:30:52 AM  -D-  PC0005.test.local"
$aSRE = StringRegExp($sString, "(\w{2}-\w{2}-\w{2}-\w{2}-\w{2}-\w{2})", 1)
If IsArray($aSRE) Then
    MsgBox(64, "Success", "Found Mac Address: " & $aSRE[0])
Else
    MsgBox(64, "Failed", "No Mac Address found.")
EndIf

Edit: damn I'm so slow at posting..lol

Edited September 16, 2011 by smashly

[scraps]

Hi everyone,

Thanks for your help,

Both Damien and Smashly's examples resulted in a win for me ,

But so i can learn more about this function could i possibly get a break down?

StringRegExp($String,'(?i)(?s)255.(.*?)- (.*?) ',3)

- sets Case-insensitivity flag, matches anything including newline, (then im lost) think 255. is to do with the subnet mask.

tried to make sense of it in the help file but got little lost

[smashly]

Hi,

Your better off using PsaltyDS version, since mac address is hex value.

In your mock up mac address string you have 0t-z4, a mac address will not have t or z.

mac address will only contain 0 to 9 and A to F.

Hence PsaltyDS using [:xdigit:] for a search pattern is the better method.

Global $sBogusMacAddress, $sMacAddress

$sBogusMacAddress = "77.10.119.232   - 255.255.254.0  - 00-15-46-5b-0t-z4   -27/09/2011 8:30:52 AM  -D-  PC0005.test.local"
MsgBox(64, "$sBogusMacAddress", _MacAddressFromString($sBogusMacAddress))

$sMacAddress = "77.10.119.232   - 255.255.254.0  - 00-15-46-5b-0F-F4   -27/09/2011 8:30:52 AM  -D-  PC0005.test.local"
MsgBox(64, "$sMacAddress", _MacAddressFromString($sMacAddress))

Func _MacAddressFromString($sString)
    Local $aSRE
    $aSRE = StringRegExp($sString, "[[:xdigit:]]{2}-[[:xdigit:]]{2}-[[:xdigit:]]{2}-[[:xdigit:]]{2}-[[:xdigit:]]{2}-[[:xdigit:]]{2}", 1)
    If IsArray($aSRE) Then Return "Found Mac Address: " & $aSRE[0]
    Return "No Mac Address found."
EndFunc

Cheers

[scraps]

Thanks Smashly,

I do understand about Mac address being hex value, was just messing around with the values and guess i should have made the example in hex.

Thanks everyone for your help, most appreciated

[SmOke_N]

That pattern certainly looks like it could be shortened.... maybe:

$aSRE = StringRegExp($sString, "((?:[[:xdigit:]]{2}-){5}[[:xdigit:]]{2})", 1)

? Edited September 16, 2011 by SmOke_N