how to read guictrlcreatemenuitem

[dirty]

$FileMenu = GUICtrlCreateMenu ("&File")

$Open = GUICtrlCreateMenuItem ("Open",$FileMenu)

If there are more then 1 menu item, how to read one that was selected ? or how to use it as:

because each file opened is stored into this menu and by selecting one opened file or another from the drop down created by each entered item, nothing happens caz i dont know how to read it.

[Melba23]

dirty,

Another canine-ingested Help file, I assume.

GUICtrlRead ( controlID [, advanced] )

In 'advanced' mode the return value contains additional data of the control

Menu, MenuItem - The text of the control

M23

[dirty]

Thanks i now learned how to use advanced parametes for guictrlread. thanks to u.

$FileMenu = GUICtrlCreateMenu ("&File")

$Recent = GUICtrlCreateMenu ("Recent Files", $FileMenu)

GUICtrlCreateMenuItem ("",$FileMenu)

GUICtrlCreateMenuItem has no variable assigned to it and is being created by openfiledialog, so how do i read it if it has no variable and there are many of them since i opened many files ?

Edited September 21, 2011 by dirty

[Melba23]

dirty,

You can do it like this:

expandcollapse popup

#include <GUIConstantsEx.au3>

; Create an array to hold the ControlIDs of the MenuItems
Global $aMenuItem[3]

$hGUI = GUICreate("Test", 500, 500)

; Create the menu
$mMenu = GUICtrlCreateMenu("File")
For $i = 0 To 2
    $aMenuItem[$i] = GUICtrlCreateMenuItem("Item " & $i, $mMenu)
Next

; Clicking this adds an item to the menu
$hButton = GUICtrlCreateButton("Add Menu Item", 10, 10, 80, 30)

GUISetState()

While 1

    $iMsg = GUIGetMsg()
    Switch $iMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $hButton
            ; Resize the array
            $iCount = UBound($aMenuItem)
            ReDim $aMenuItem[$iCount + 1]
            ; And add the new item ControlID
            $aMenuItem[$iCount] = GUICtrlCreateMenuItem("Item " & $iCount, $mMenu)
        Case Else
            ; Run through the array to see if we have a match
            For $i = 0 To UBound($aMenuItem) - 1
                If $iMsg = $aMenuItem[$i] Then
                    ; We do, so read the text of the menu item
                    $sText = GUICtrlRead($iMsg, 1)
                    ; And display it
                    ConsoleWrite($sText & @CRLF)
                    ; No point in looking any further
                    ExitLoop
                EndIf
            Next
    EndSwitch

WEnd

As you can see, when you add an item to the menu you also add the ControlID to the array.

All clear?

M23

[dirty]

am lost.

Can you open my whole script and see how i can fix it to get this working ? your example does make enough since to me.

My other post with another issue with my script included is here

thanks for quick reply and a very detailed example

look into line 326 is where i try to read the value off if created menuitem in line 214

Edited September 21, 2011 by dirty

[Melba23]

dirty,

Here is an untested version of your script using code similar to the example I posted above - look for the <<<<<<<<<<<< lines to see where I have changed it:

This updowngraded editor is screwing up the AutoIt tags yet again so I have had to attach it as a file.

There are no syntax errors, but as I do not have any of your data I cannot really test it fully. Let me know when you have downloaded it and if it works.

M23

P.S. You might want to look at using a Switch structure rather than all those If $GUIGETMSG...EndIf statements. And why are you using Assign to set values to variables - what is wrong with a simple = operator?

[dirty]

It does thanks.

Ways you created this to work are very confusing to me, but am sure i will understand it later.

For now ill just use it.

[Melba23]

dirty,

If you do run into difficulties understanding what I did and why, please ask so I can explain.

M23