Highlight variable value on a MsgBox

[mabriseb]

I try to Highlight variable value in a MsgBox but there is no function to make it appear in Bold or someting like that.

Does anyone have an idea?

Thanks!

[janrenzlow]

Hi snapback,

there's definitly no possibility to format character in MsgBox. You must create your own GUI-window. Greetings Johannes

I try to Highlight variable value in a MsgBox but there is no function to make it appear in Bold or someting like that.

Does anyone have an idea?

Thanks!

<{POST_SNAPBACK}>

[jlorenz1]

Give me more information or a simplified example. MsgBox exist in other script languages too & anywhere there is no chance to format characters. Use GUI - window and different labels and set for each label other formatting character. See example GUICtrlSetFont in helpfile. Johannes

[mabriseb]

OK Thanks!

But if I already have a main GUI and I build a new one for replacing my MsgBox. How can I set the focus on the right window when users come back to the main GUI?

[GaryFrost]

Here's an example that might get you started.

expandcollapse popup

#include <GuiConstants.au3>

$main = GUICreate("MyGUI", 392, 322)

$Button_1 = GUICtrlCreateButton("MsgBox", 140, 190, 70, 30)

GUISetState()
While 1
    $msg = GUIGetMsg()
    Select
        Case $msg = $GUI_EVENT_CLOSE
            ExitLoop
        Case $msg = $Button_1
            GUISetState(@SW_DISABLE, $main)
            _MsgBox("My Message Box", "Some Text in here")
            GUISetState(@SW_ENABLE, $main)
            GUISetState(@SW_SHOW)
        Case Else
        ;;;
    EndSelect
WEnd
Exit

Func _MsgBox($s_Title, $s_Text)
    $popup = GUICreate($s_Title, 190, 160, -1, -1, $WS_DLGFRAME, $WS_EX_TOPMOST)
    
    $lbl_edit = GUICtrlCreateEdit($s_Text, 10, 10, 170, 80, BitOR($ES_READONLY, $ES_MULTILINE), $WS_EX_TRANSPARENT)
    GUICtrlSetFont(-1, 12, 700)
    GUICtrlSetColor(-1, 0xff0000)   ; Red
    $Button_2 = GUICtrlCreateButton("OK", 60, 100, 60, 20)
    GUISetState()
    While 1
        $msg2 = GUIGetMsg()
        Select
            Case $msg2 = $Button_2
                ExitLoop
            Case Else
            ;;;
        EndSelect
    WEnd
    GUIDelete($popup)
EndFunc  ;==>_MsgBox

[mabriseb]

Good!! Thank you for your help!!