My first UDF need help

[Command3r]

Hello, this is my first UDF and i want to ask some questions.

1st- sorry for my bad english. ^^

2nd- let me show you the UDF.

expandcollapse popup

#cs ----------------------------------------------------------------------------
 
AutoIt Version: 3.3.6.1
Author:      Command3r
 
Script Function: Checking for update
Template AutoIt script.
 
#ce ----------------------------------------------------------------------------
 
#include-once
#include "String.au3"
 
Func _CheckForUpdate($Url, $AlreadyVersion, $NewVersionBetweenThis, $AndThis)
;;;;;;;;;;;;;;; $URL ;;;;;;;;;;;;;;;;;;;
Global $UpdateFile = @ScriptDir & "\Update.txt"
FileDelete($UpdateFile)
 
$Url = _INetGetSource($Url)
FileWrite($UpdateFile, $Url)
Sleep(50)
 
$FileSize = Round(FileGetSize($UpdateFile) / 1024, 1)
 
If $FileSize = "0" Then
MsgBox(16, "Error", "Can't find the url") ;  <<< if @error = 1 then do this ---- or if you guys can add @error for the url error will be better.
EndIf
;;;;;;;;;;;;;;;;;;;;;; $AlreadyVersion ;;;;;;;;;;;;;;;;;;;;;;
 
$1 = FileRead($UpdateFile)
$Str = _StringBetween($1, $NewVersionBetweenThis, $AndThis)
 
$Compare = StringCompare($Str[0], $AlreadyVersion)
 
If $Compare <> 0 Then
MsgBox(64, "Chechking for update...", "Update is available.") ;  <<< if @error = 2 then do this.
ElseIf $Compare = 0 Then
MsgBox(64, "Checking for update...", "Update is not available.") ;  <<< if @error = 3 then do this.
EndIf
 
_Del()
EndFunc   ;==>_CheckForUpdate
 
Func _Del()
FileDelete($UpdateFile)
EndFunc   ;==>_Del

Ummm, i need to add @errors instead of message boxes to make user set his message box not just what in the func.

3d- i need to add @extended too because if it complete correctly show "msgbox".

Any ideas??

Thanks.

[guinness]

Couple if quick points don't declare Global variables in a Function, always at the top of a script. Then look at SetError(), you can see examples in my signature e.g. _ShellAll().

[Command3r]

@guinness

Okay thanks for points, i found in ur UDF _ShellAll() this lines but i still can't understand it

$sName = StringLower(StringReplace($sName, ".exe", ""))
    If $sName = "" Or $sFilePath = "" Then
        Return SetError(1, 0, 0)
    EndIf

Edited October 21, 2011 by Command3r

[guinness]

That translates as if the variable $sName is blank or $sFilePath is blank, set @error as 1, @extended as 0 and the return value as 0.

This is what SetError basically is >> SetError(@error value, @extended value, return value)

Global $iReturn

$iReturn = _Main()
MsgBox(64, "SetError()", @error & ", " & @extended & ", " & $iReturn)

Func _Main()
    Return SetError(20, 30, 0)
EndFunc   ;==>_Main

Edited October 21, 2011 by guinness

[Command3r]

ok, but how can i set @error to make message boxes??

did SetError do that or not??

and what Error value "1" do?? and extended too??

sorry im new and dont know more about UDFs, @error, @extended and returns.

Edited October 21, 2011 by Command3r

[Command3r]

if any 1 understand what i need so please edit my script and post it, and i'll know how to do it next time

thanks.

[guinness]

Like this >>

_Main()
If @error Then
    MsgBox(64, "SetError()", "An error occurred!")
EndIf
 
Func _Main()
    Return SetError(1)
EndFunc   ;==>_Main

if any 1 understand

I do understand I think you should read the Help file about SetExtended & SetError.

Edit: Read this >> http://www.autoitscript.com/autoit3/udfs/UDF_Standards.htm

Edited October 21, 2011 by guinness

[Command3r]

no i mean, like that

_CheckForUpdate("www.autoitscript.com", "1.0", "-", "-")
If @error = 1 Then
MsgBox(0, "", "Can't find url/writefile")
ElseIf @error = 2 Then
MsgBox(0 "", "Update is available")
ElseIf @error = 3 Then
MsgBox(0, "", "Update not available")
EndIf

the user use his message box i mean

if $compare <> 0 then set @error 2....etc

anyway thanks for help

i'll try to resolve it

Edited October 21, 2011 by Command3r

[guinness]

Look at the changes I made and the advice I gave you.

expandcollapse popup

#cs ----------------------------------------------------------------------------
    
    AutoIt Version: 3.3.6.1
    Author:   Command3r
    
    Script Function: Checking for update
    Template AutoIt script.
    
#ce ----------------------------------------------------------------------------
 
#include-once
#include "String.au3"
 
Func _CheckForUpdate($Url, $AlreadyVersion, $NewVersionBetweenThis, $AndThis)
    ;;;;;;;;;;;;;;; $URL ;;;;;;;;;;;;;;;;;;;
    Global $UpdateFile = @ScriptDir & "\Update.txt"
    FileDelete($UpdateFile)
 
    $Url = _INetGetSource($Url)
    FileWrite($UpdateFile, $Url)
    Sleep(50)
 
    $FileSize = Round(FileGetSize($UpdateFile) / 1024, 1)
 
    If $FileSize = "0" Then
        Return SetError(1)
;~      MsgBox(16, "Error", "Can't find the url") ;  <<< if @error = 1 then do this ---- or if you guys can add @error for the url error will be better.
    EndIf
    ;;;;;;;;;;;;;;;;;;;;;; $AlreadyVersion ;;;;;;;;;;;;;;;;;;;;;;
 
    $1 = FileRead($UpdateFile)
    $Str = _StringBetween($1, $NewVersionBetweenThis, $AndThis)
 
    $Compare = StringCompare($Str[0], $AlreadyVersion)
 
    If $Compare <> 0 Then
        Return SetError(2)
;~      MsgBox(64, "Chechking for update...", "Update is available.") ;  <<< if @error = 2 then do this.
    ElseIf $Compare = 0 Then
        Return SetError(3)
;~      MsgBox(64, "Checking for update...", "Update is not available.") ;  <<< if @error = 3 then do this.
    EndIf
 
    _Del()
EndFunc   ;==>_CheckForUpdate
 
Func _Del()
    FileDelete($UpdateFile)
EndFunc   ;==>_Del

[Command3r]

Wow it's working, many thanks guinness <3

okay bro i'll )

[guinness]

OK, at least you now understand. By the way search Functions in the Help file to understand about creating Functions more efficiently e.g. using the Return keyword.

Edited October 21, 2011 by guinness

[Command3r]

and the advice I gave you.

Is UDF correctly now? and ready to use?? and what do i need to improve it??

expandcollapse popup

#cs ----------------------------------------------------------------------------
    
    AutoIt Version: 3.3.6.1
    Author: Command3r
    
    Script Function:
    Checking for update.
    
#ce ----------------------------------------------------------------------------

#include-once
#include "String.au3"

Global $UpdateFile = @ScriptDir & "\Update.txt"

Func _CheckForUpdate($Url, $AlreadyVersion, $NewVersionBetweenThis, $AndThis, $SaveUpdateFile = "1")
    FileDelete($UpdateFile)
    $Url = _INetGetSource($Url)
    FileWrite($UpdateFile, $Url)
    $ReadUpdateFile = FileRead($UpdateFile)

    _Getsize()

    $Str = _StringBetween($ReadUpdateFile, $NewVersionBetweenThis, $AndThis)
    Switch $SaveUpdateFile
        Case $SaveUpdateFile = "0"
            FileDelete($UpdateFile)
    EndSwitch
    $Comp = StringCompare($Str[0], $AlreadyVersion)

    If $Comp <> 0 Then
        Return SetError(1, "", MsgBox(64, "Checking for update...", "Update is available." & @CRLF & @CRLF & "Current version is: " & $AlreadyVersion & @CRLF & "New version is: " & $Str[0]))
    ElseIf $Comp = 0 Then
        Return SetError(2, "", MsgBox(64, "Checking for update...", "Update is not available." & @CRLF & @CRLF & "Currnet version is: " & $AlreadyVersion & @CRLF & "New version is: " & $Str[0]))
    EndIf
EndFunc   ;==>_CheckForUpdate

Func _Getsize()
    $FileSize = Round(FileGetSize($UpdateFile) / 1024, 1)
    If $FileSize = "0" Then
        FileDelete($UpdateFile)
        MsgBox(16, "Error", "Cannot find the url.") ; i didn't put return here because of the errors after calling this func above.
        Exit
    EndIf
EndFunc   ;==>_Getsize

thanks.

Edited October 24, 2011 by Command3r

[guinness]

If for personal use then it looks fine, though I thought the whole purpose was to have the message boxes seperate?

Edited October 24, 2011 by guinness

[Command3r]

yes, the whole purpose was to have seperate messages, but i thought i must add return value as you said so i added mesage boxes

okay, now what is better? remove the return values "message boxes" or leave it?? (i prefer to leave it )

If for personal use then it looks fine

what about making it public? what do it need??

Edited October 24, 2011 by Command3r

[guinness]

You can have the return values as whatever you want e.g. new version number, old version number, nothing etc..

My advice to improve it would be look at variable deceleration in the help file. The general consensus is if you use only use the declared variables in the function then declare as Local otherwise if the variables (not names) are used outside of the functions as well then declare as Global.

How I would do it:

expandcollapse popup

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7 ; Use the advanced parameters of Au3Check.
 
#include-once
#include <Misc.au3>
#include <String.au3>
 
#cs Example.
    Global $iVersion
 
    $iVersion = _CheckForUpdate("http://www.url.url", "1.0.0.0", "Before", "After", 0)
    Switch @error
    Case 1 ; No version update.
    MsgBox(64, "_CheckForUpdate()", "No new version is available." & @LF & "V" & $iVersion)
 
    Case 2, 3 ; An error occurred when retrieving the new version.
    MsgBox(64, "_CheckForUpdate()", "An error occurred when trying to get the new version.")
 
    Case Else
    MsgBox(64, "_CheckForUpdate()", "A new version is available for download." & @LF & "V" & $iVersion)
 
    EndSwitch
#ce
 
Func _CheckForUpdate($sURL, $iCurrentVersion, $sFrom, $sTo, $iSave = 1)
    Local $bRead, $hFileOpen, $iNewVersion, $sUpdateFilePath = @ScriptDir & "\Update.txt", $sRead, $sReturn
 
    $bRead = InetRead($sURL) ; This is similar to _INetGetSource().
    If BinaryLen($bRead) = 0 Then
        Return SetError(2, 0, $iCurrentVersion) ; No data was returned as the size was 0.
    EndIf
    $sRead = BinaryToString($bRead)
 
    If $iSave Then
        $hFileOpen = FileOpen($sUpdateFilePath, 2) ; If file exits then overwrite or create new file.
        FileWrite($hFileOpen, $sRead)
        FileClose($hFileOpen)
    Else
        FileDelete($sUpdateFilePath) ; Delete if the user doesn't want to save the data.
    EndIf
 
    $sReturn = _StringBetween($sRead, $sFrom, $sTo)
    If @error Then
        Return SetError(3, 0, $iCurrentVersion) ; There was an error trying to find the data between the strings.
    EndIf
    $iNewVersion = $sReturn[0]
 
    Switch _VersionCompare($iCurrentVersion, $iNewVersion) ; Use version compare to accurately detect if there has been a change.
        Case 0, 1
            Return SetError(1, 0, $iCurrentVersion) ; No update available and return the current version.
 
        Case Else
            Return $iNewVersion ; Update available and don't set the @error value but return the new version value.
 
    EndSwitch
EndFunc   ;==>_CheckForUpdate

[Command3r]

Now i had experience in making func, and it will improves with time and making more UDFs

Many thanks guinness.

[guinness]

OK.