Jump to content

countdown button


silver217
 Share

Recommended Posts

I like to have a countdown button on my GUI.

there is a number in the button that goes down from 30 to 1 and

in the rest of the program I need to know if it timed out or was pressed.

No need to have the countdownvalue.

After timeout or when pressed, the GUI can close and the program continues.

Any help is apprciated, I will send a postcard from the Netherlends.

Link to comment
Share on other sites

  • Moderators

silver217,

You could do it like this:

#include <GUIConstantsEx.au3>

; You will need to reset this to 30
$iCount = 5

$hGUI = GUICreate("Test", 500, 500)

$hButton = GUICtrlCreateButton($iCount, 10, 10, 80, 30)

GUISetState()

; Get a timestamp
$iBegin = TimerInit()

While 1

    ; If it is over a second since the timestamp
    If TimerDiff($iBegin) > 1000 Then
        ; Reduce the count
        $iCount -= 1
        ; Are we timed out?
        If $iCount = -1 Then
            ; Exit the loop
            ExitLoop
        Else
            ; Change the button text
            GUICtrlSetData($hButton, $iCount)
        EndIf
        ; reset teh timestamp for the next second
        $iBegin = TimerInit()
    EndIf

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $hButton
            ; Exit the loop if the button was pressed
            ExitLoop
    EndSwitch

WEnd

; Now see the value of count
If $iCount = -1 Then
    MsgBox(0, "Countdown", "Timed out")
Else
    MsgBox(0, "Countdown", "Button pressed")
EndIf

Please ask if anything is unclear. :D

M23

Public_Domain.png.2d871819fcb9957cf44f4514551a2935.png Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind

Open spoiler to see my UDFs:

Spoiler

ArrayMultiColSort ---- Sort arrays on multiple columns
ChooseFileFolder ---- Single and multiple selections from specified path treeview listing
Date_Time_Convert -- Easily convert date/time formats, including the language used
ExtMsgBox --------- A highly customisable replacement for MsgBox
GUIExtender -------- Extend and retract multiple sections within a GUI
GUIFrame ---------- Subdivide GUIs into many adjustable frames
GUIListViewEx ------- Insert, delete, move, drag, sort, edit and colour ListView items
GUITreeViewEx ------ Check/clear parent and child checkboxes in a TreeView
Marquee ----------- Scrolling tickertape GUIs
NoFocusLines ------- Remove the dotted focus lines from buttons, sliders, radios and checkboxes
Notify ------------- Small notifications on the edge of the display
Scrollbars ----------Automatically sized scrollbars with a single command
StringSize ---------- Automatically size controls to fit text
Toast -------------- Small GUIs which pop out of the notification area

 

Link to comment
Share on other sites

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now
 Share

  • Recently Browsing   0 members

    • No registered users viewing this page.
×
×
  • Create New...