HELP: How to Check if Tray Item exists?

[Floppy]

Global $hello
$test = TrayCreateItem("Test")
While 1

$msg = TrayGetMsg()

Select
 
  Case $msg = $test
   MsgBox(0, "", "Test")
   $hello = TrayCreateItem("Hello")
  
  Case $msg = $hello
   MsgBox(0, "", "Hello")
 
EndSelect

WEnd

How can I prevent message "Hello" from displaying?

[Melba23]

FSoft,

Although you have declared the variable $hello, you have not given it a value - so AutoIt assumes it is 0. Guess what the default return frm GUIGetMsg is when there are no messages in the queue - you got it! So the Case fires every time. Solution: give the variable an intial placehoder value that will never fire!

But you have another problem as well. You need to remove the default AutoIt tray items or you wil pause the script each time you click on the icon - then you can never click your "Test" trayitem. But if you remove them, you need to add your own "Exit" tray item - gets complicated doesn't it?

Here is a little script which shows all that in action:

; Remove the default items
Opt("TrayMenuMode", 3)

; Set a ridiculous value for this ControlID
Global $hello = 9999

$test = TrayCreateItem("Test")
$exit = TrayCreateItem("Exit") ; Add our exit item

While 1

    $msg = TrayGetMsg()

    Select

        Case $msg = $test
            MsgBox(0, "", "Test")
            $hello = TrayCreateItem("Hello")

        Case $msg = $hello
            MsgBox(0, "", "Hello")

        Case $msg = $exit ; And look for it here
            Exit

    EndSelect

WEnd

All clear?

M23

[Floppy]

LOL Thank you Melba!

Please can you give me a range of numbers that I can use to declare tray items? E.g. 99-99999

Edited November 18, 2011 by FSoft

[Melba23]

FSoft,

a range of numbers that I can use to declare tray items

You are not declaring the value of the TrayItem - that is set when you use TrayCreateItem. What the 9999 represents is a placeholder value so that the variable holds something and does not fire when TrayGetMsg returns 0.

Why do I use 9999? Well, ControlIds for normal GUI controls and TrayItems start around 3 and can go up to 65532 (or so they say!). I have never had more than 10000 controls in a GUI (in fact nowhere near that number! ) and so I felt that 9999 was pretty safe to use as it would be unlikely to match a real ControlID.

If you look at the Managing Multiple GUIs tutorial in the Wiki you will see that I use it a lot in the example scripts for exactly the same reason. And you will also see that you can use the same value for all the placeholder values for the predeclared variables - it will be replaced by the real ControlID when the control is actually created.

All clear now?

M23

[Floppy]

Ok, thank you for your great explaination Melba!