Enter a ComboBox control if it has focus

[supersonic]

Hi everybody,

I'm trying to solve an apparently simple issue but I don't get it solved...

So, if the ComboBox control has focus and I press ENTER some action should start...

With the sample code below it does not work. For the Input control it works fine.

Here's the sample code:

#include <GUIConstantsEx.au3>
#include <Misc.au3>
#include <WinAPI.au3>

Local $hDLL = DllOpen("USER32.DLL")
Local $hGUI = GUICreate("", 200, 100, -1, -1)
Local $hButton = GUICtrlCreateButton("Button", 10, 10, 100, 21)
Local $hComboBox = GUICtrlCreateCombo("ComboBox", 10, 40, 100, 21)
Local $hInput = GUICtrlCreateInput("Input", 10, 62, 100, 21)

GUISetState()

While 1
Switch GUIGetMsg()
  Case $GUI_EVENT_CLOSE
   ExitLoop
  Case $hButton
   MsgBox(0, "", "Button")
EndSwitch
ConsoleWrite("___" & _WinAPI_GetFocus() & "___" & GUICtrlGetHandle($hComboBox) & @CRLF)
If _IsPressed("0D", $hDll) = True And _WinAPI_GetFocus() = GUICtrlGetHandle($hComboBox) Then ; 0D = ENTER.
  MsgBox(0, "", "ComboBox")
EndIf
ConsoleWrite("___" & _WinAPI_GetFocus() & "___" & GUICtrlGetHandle($hInput) & @CRLF)
If _IsPressed("0D", $hDll) = True And _WinAPI_GetFocus() = GUICtrlGetHandle($hInput) Then ; 0D = ENTER.
  MsgBox(0, "", "Input")
EndIf
WEnd

DllClose($hDLL)

The function "_WinAPI_GetFocus()" returns an other handle for the ComboBox control as "GUICtrlGetHandle()".

Anyone any idea?

Greets,

-supersonic.

Edited December 7, 2011 by supersonic

[JohnOne]

I'm not sure if this will work, as I'm not entirely sure it does not just give initial focus to the control, but try this after create your combo

GUICtrlSetState(-1, $GUI_DEFBUTTON)

[Melba23]

supersonic,

The combobox actually consists of 3 parts:

- 1. The combo you create

- 2. The edit box at the top

- 3. The list that drops down

So the handle you get with GUICtrlGetHandle($hComboBox) is not what _WinAPI_GetFocus sees - it sees the edit control.

The solution is to use _GUICtrlComboBox_GetComboBoxInfo to get this handle:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <Misc.au3>
#include <WinAPI.au3>
#include <GUIComboBox.au3>
#include <Constants.au3>

$tInfo = $tagCOMBOBOXINFO

Local $hDLL = DllOpen("USER32.DLL")
Local $hGUI = GUICreate("", 200, 100, -1, -1)
Local $hButton = GUICtrlCreateButton("Button", 10, 10, 100, 21)
Local $hComboBox = GUICtrlCreateCombo("ComboBox", 10, 40, 100, 21)

If _GUICtrlComboBox_GetComboBoxInfo($hComboBox, $tInfo) Then
    ConsoleWrite("Handle to the ComboBox .....: " & DllStructGetData($tInfo, "hCombo") & @CRLF)
    ConsoleWrite("Handle to the Edit Box .....: " & DllStructGetData($tInfo, "hEdit") & @CRLF)
    ConsoleWrite("Handle to the drop-down list: " & DllStructGetData($tInfo, "hList") & @CRLF)
EndIf

$hEditBox = DllStructGetData($tInfo, "hEdit")

Local $hInput = GUICtrlCreateInput("Input", 10, 62, 100, 21)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            ExitLoop
        Case $hButton
            MsgBox(0, "", "Button")
    EndSwitch

    ConsoleWrite("___" & _WinAPI_GetFocus() & "___" & $hEditBox & @CRLF)
    If _IsPressed("0D", $hDLL) = True And _WinAPI_GetFocus() = $hEditBox Then ; 0D = ENTER.
        MsgBox(0, "", "ComboBox")
    EndIf

    ConsoleWrite("___" & _WinAPI_GetFocus() & "___" & GUICtrlGetHandle($hInput) & @CRLF)
    If _IsPressed("0D", $hDLL) = True And _WinAPI_GetFocus() = GUICtrlGetHandle($hInput) Then ; 0D = ENTER.
        MsgBox(0, "", "Input")
    EndIf
WEnd

DllClose($hDLL)

All clear?

M23

[kylomas]

supersonic,

be carefull running M23's example, it loops on the consolewrite's

@M23 - can the $es_readonly style be applied to the edit component of the combobox???

kylomas

[Melba23]

kylomas,

be carefull running M23's example, it loops on the consolewrite's

It is not my example - it is supersonic's example in the first post with my added code to show the 3 handles!

can the $es_readonly style be applied to the edit component of the combobox

No - but you just need to apply the $CBS_DROPDOWNLIST to the combo when you create it to get the same effect.

I know the description in the Help file is not wonderful:

"$CBS_DROPDOWNLIST - 0x0003 - Displays a static text field that displays the current selection in the list box"

but that is what MSDN gives us to work with!

M23

[kylomas]

M23,

Thanks, apologies for the mis-attribution (cool word I just made up)...

kylomas

[supersonic]

Hi Melba,

everything clear - thank you very much for this excellent explanation!

@ kylomas: I'm aware of the "ConsoleWrite()" loop. The sample code above was just for testing purposes...

Greets,

-supersonic.