Monitoring for a custom message in OnEvent mode?

[shastaman2]

I'm having trouble trying to monitor for a custom message in OnEvent Mode.

I have a loop which is checking for the existence of an app window every 60 seconds to make sure it does not close. While the app is running, if a certain condition occurs in the app, the app will send a custom message to my GUI which tells me to error out of my script.

I created a version in MessageLoop mode but don't want to have to have the tight loop checking for messages, so I want to use OnEvent mode.

Questions:

1. To use OnEvent mode, I don't understand how to set GUISetOnEvent to look for my message.

2. I don't understand how to set the function specified in GUISetOnEvent to have all 4 parameters so I can check the info in the message itself.

Here's how I did it in MessageLoop Mode:

#include <GUIConstantsEx.au3>

#include <WindowsConstants.au3>

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;

;; Register for a Message

;;

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

Local $lpString = "My_MSG"

Local $RT = DllCall("User32.dll","int","RegisterWindowMessageW","WSTR",$lpString)

if @error Or $RT[0] = 0 Then

SetError(1,0,0)

Exit 1

EndIf

Local $MSG_ID = $RT[0]

Local $MSG_NAME = $RT[1]

MsgBox (0, "Receiver", "Registered message: " & $MSG_NAME & " (" & $MSG_ID & ")" & @CRLF)

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;

;; Create a blank GUI

;;

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

$GuiHwnd = GUICreate("Receiver", 200, 80)

;~ GUISetState(@SW_SHOW)

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;

;; Register the GUI to do something when MSG_ID is received

;;

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

GUIRegisterMsg($MSG_ID, "ReceivedProc")

;; GUI loop

While 1

If Not (WinWait("My App","",2)) Then

ThrowError("App window not found")

Endif

$GUIMsg = GUIGetMsg()

Switch $GUIMsg

Case $GUI_EVENT_CLOSE

Exit

EndSwitch

WEnd

Exit 0

;; Function to call when the message is received

Func ReceivedProc ($hWnd,$Msg,$wParam,$lParam)

MsgBox (0, "Receiver", "Closed GUI")

Exit

EndFunc

Func ThrowError ($msg)

MsgBox (0, "Failed", $msg)

Exit

EndFunc

To switch to OnEvent mode, I tried changing the GUI part to this:

Opt("GUIOnEventMode", 1) ; Change to OnEvent mode

$mainwindow = GUICreate("Receiver", 200, 100)

GUISetOnEvent($MSG_NAME, "ReceivedProc")

and removed the calls to GUIRegisterMsg and GUIGetMsg, however, it just failed with an long negative number error.

Many thanks for any assistance.

[BrewManNH]

You're confusing Windows messages and OnEvent messages. First off, any windows message is going to kill your script, if you move it, click on the title bar etc., but as you have the GUISetState line commented out, that probably won't be a problem. You shouldn't need the GUISetOnEvent line if you are using a GUIRegisterMsg line, as one will take over for the other for receiving the messages.

[shastaman2]

Voila. Many thanks BrewMan.

I thought that GUISetOnEvent was specific and required for using OnEvent mode and GUIRegisterMsg was specific and required for MessageLoop mode. No examples mixed the two.

First future users, here's the solution I'm using:

#include <GUIConstantsEx.au3>

#include <WindowsConstants.au3>

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;

;; Register for a Message

;;

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

Local $lpString = "My_MSG"

Local $RT = DllCall("User32.dll","int","RegisterWindowMessageW","WSTR",$lpString)

if @error Or $RT[0] = 0 Then

SetError(1,0,0)

Exit 1

EndIf

Local $MSG_ID = $RT[0]

Local $MSG_NAME = $RT[1]

MsgBox (0, "Receiver", "Registered message: " & $MSG_NAME & " (" & $MSG_ID & ")" & @CRLF)

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;

;; Create a blank GUI which is hidden (I'm only making it to receive messages)

;;

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

Opt("GUIOnEventMode", 1) ; Change to OnEvent mode

$mainwindow = GUICreate("Receiver", 200, 100)

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;;

;; Register the GUI to do something when MSG_ID is received

;;

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

GUIRegisterMsg($MSG_ID, "ReceivedProc")

;; GUI loop

While 1

If Not (WinWait("My App","",2)) Then

ThrowError("App window not found")

Endif

WEnd

Exit 0

;; Function to call when the message is received

Func ReceivedProc ($hWnd,$Msg,$wParam,$lParam)

MsgBox (0, "Receiver", "Closed GUI")

Exit

EndFunc

Func ThrowError ($msg)

MsgBox (0, "Failed", $msg)

Exit

EndFunc

[Melba23]

shastaman2

I thought that GUISetOnEvent was specific and required for using OnEvent mode and GUIRegisterMsg was specific and required for MessageLoop mode

It is GUIGetMsg that is required in MessageLoop mode to poll the message queue for events. GUIRegisterMsg can be used in either mode to detect Windows messages.

M23