Run Script if Computer is a member of group in AD

[ReitzelTechnology]

I have a script to install Macromedia Studio on our machines and I have a group in Active Directory called "Studio8_Stations". I would like to be able for the script to check to see if it is a member of that group before it runs the installer script.

[UEZ]

Try this:

#include "AD.au3"

Global $aMembers[1], $computer = "Computer10", $group = "Studio8_Stations", $found = False, $i

; Open Connection to the Active Directory
_AD_Open()
If @error Then Exit MsgBox(16, "Active Directory Example Skript", "Function _AD_Open encountered a problem. @error = " & @error & ", @extended = " & @extended)


; Get a sorted list of members for the first group the currently logged on user is a member of
$aMembers = _AD_GetGroupMembers($group)

If @error > 0 Then
    MsgBox(64, "Active Directory Functions - Example 1", "The group '" & $group & "' has no members")
Else
    For $i = 1 To $aMembers[0]
        If StringInStr($aMembers[$i], "CN=" & $computer & ",") Then
            MsgBox(64, "Information", $computer & " is a member of " & $group)
            $found = True
            ExitLoop
        EndIf
    Next
    If Not $found Then MsgBox(16, "Information", $computer & " is NOT a member of " & $group)
EndIf


; Close Connection to the Active Directory
_AD_Close()

You need made by water!

Br,

UEZ

Edited December 21, 2011 by UEZ

[water]

Or even easier and faster:

#include <AD.au3>
Global $iResult, $sGroup = "Studio8_Stations"
; Open Connection to the Active Directory
_AD_Open()
If @error Then Exit MsgBox(16, "Active Directory", "Function _AD_Open encountered a problem. @error = " & @error & ", @extended = " & @extended)
; Check if the computer is an immediate member of the group
If _AD_IsMemberOf($sGroup, @ComputerName & "$") = 1 Then
    ; Computer is member of the group - do whatever you need to do
EndIf
; Close Connection to the Active Directory
_AD_Close()

Edited December 22, 2011 by water

[rudi]

Hi.

"Run Script if Computer is a member of group in AD" was the question?

So it's (maybe)

If _AD_IsMemberOf($sGroup, @computername) = 1

This is a question, as I'm not sure, *IF* the AD computer account name will always match the local @computername...

Regards, Rudi.

Edited December 22, 2011 by rudi

[water]

If you pass the computername as SamAccountName you have to append a dollar sign e.g. @ComputerName & "$"

[kzooman]

Water - Are you sure this is working? I can never get your script in Post 21 to find the computer in the group even though I know it is. Thanks for any help you can provide.

[water]

Yes, I am.

I just checked it again and it works.

Can you post the code you use?