[Solved] For/Next or While Wend?

[Chimaera]

Ok im messing around with the windows update snippet posted by willichan

and i have this problem

$res = RunWait($tfile & " /install /match " & "KB2598845", @TempDir)
$res = RunWait($tfile & " /install /match " & "KB2468871", @TempDir)
$res = RunWait($tfile & " /install /match " & "KB2533523", @TempDir)

Btw $tfile is just the program and location

I have a number of these lines to run which are optional updates that i need doing, but instead of me doing line after line like the example

Is there a way and im assuming its either for next or while wend to make it execute them one after another?

If someone can point to the right way and ill go and work some more

Many thanks

Edited January 2, 2012 by Chimaera

[guinness]

Your favourite, Arrays!

Local $aArray[4] = [3, "KB12345", "KB67890", "KB6765"], $tfile = "Program.exe"

For $i = 1 To $aArray[0]
    RunWait($tfile & " /install /match " & $aArray[$i], @TempDir)
Next

Edited January 2, 2012 by guinness

[Mikeman27294]

I have a question about your code, Guiness. I have wondered for a while why people do this

Local $aArray[4] = [3, "KB12345", "KB67890", "KB6765"], $tfile = "Program.exe"
For $i = 1 To $aArray[0]
    RunWait($tfile & " /install /match " & $aArray[$i], @TempDir)
Next

rather than

Local $aArray[3] = ["KB12345", "KB67890", "KB6765"], $tfile = "Program.exe"
For $i = 0 To Ubound($aArray)
    RunWait($tfile & " /install /match " & $aArray[$i], @TempDir)
Next

Is the first way a better coding practise, or just preference?

Thanks.

[guinness]

I have a question about your code, Guinness. I have wondered for a while why people do this

If you're creating the Array yourself and you know the number of elements then UBound isn't really required, this (I feel) should be used when you don't know the number of elements e.g. SRE's or WMI Arrays.

[Chimaera]

Just doing some reading in the helpfile

Am i understanding this right

For $i = 1 To $aArray[0]

You are nominating an variable {which could be any letter} with a start number of 1 and the stop number is the array.

How does it know when to stop? do arrays count backwards? so 0 is always the last?

[guinness]

How does it know when to stop? do arrays count backwards? so 0 is always the last?

For...Next loops count up by plus 1 as default, so in the small snippet you posted it's the same as saying "count from to 1 to 3" (depending on what value the 0 index contains, which in this case was 3.) It will stop when $i is equal to 3 or $aArray[0], remember you start counting Arrays from the 0th position and not 1st position.

You can count backwards like this:

For $i = 30 To 0 Step -1
    ConsoleWrite($i & @LF)
Next

You are nominating a variable {which could be any letter} with a start number of 1 and the stop number is the array.

Correct, but only the number which is declared at the 0th position. (See above for where I declared 3.) Edited January 2, 2012 by guinness

[Chimaera]

hmm so

0 index = 3

1 index = 2

2 index = 1

So it starts at second and works back?

[Melba23]

Chimaera,

the stop number is the array

The stop number is the value of the array element[0] - which in many cases is a counter, but might well not be.

This is the eternal dilemma for coders - do I have a count in the [0] element. Many (if not most) arrays returned by Autoit functions have a count in element[0] - some even have a flag to determine whether this happens or not (look at StringSplit). So you must be absolutely sure which type you are dealing with - and here are two examples to show the pitfalls:

First using the count in element[0] method when it is not a count:

Global $aZeroCount[4] = [3, 1, 2, 3]

Global $aZeroData[4] = [31, 32, 33, 34]

; List the elements in ZeroCount

For $i = 1 To $aZeroCount[0]
    ConsoleWrite($aZeroCount[$i] & @CRLF)
Next

; Now try for ZeroData

For $i = 1 To $aZeroData[0]
    ConsoleWrite($aZeroData[$i] & @CRLF)
Next

; Fails as the count tries to go to 31 and there are not that many elements

And now the UBound method when there is a count:

Global $aZeroCount[4] = [3, 1, 2, 3]

Global $aZeroData[4] = [31, 32, 33, 34]

; List the elements in ZeroCount

For $i = 0 To UBound($aZeroCount) - 1
    ConsoleWrite($aZeroCount[$i] & @CRLF)
Next

; Now for ZeroData

For $i = 0 To UBound($aZeroData) - 1
    ConsoleWrite($aZeroData[$i] & @CRLF)
Next

; But the count in ZeroCount is now considered as data

That is why I said it is imperative to know which type of array you are dealing with. Personally I prefer a count in the [0] element as you so often need a counter to size the array, but that is just my preference.

I hope this helps explain clearly - ask again if not.

M23

[guinness]

How you count backwards using an Array >>

Local $aArray[4] = [3, "Data_1", "Data_2", "Data_3"]

For $i = $aArray[0] To 1 Step -1 ; We want to go to 1 and not 0 because we're not interested in displaying the total count of the Array.
    ConsoleWrite($aArray[$i] & @LF)
Next

Also have a read of this wiki entry about Arrays >> http://www.autoitscript.com/wiki/Arrays

[Chimaera]

I must have confused you guinness i wasnt worried about counting backwards im trying to work out how the array counts

So from Melba's example

0 index = 3 units in the array

1 index = data 1

2 index = data 2

3 index = data 3

so it checks the 0 index and says 3 which it hasn't got as it stands at 0 cos the loop hasn't started, so it checks 1 index which is 1 time around the loop, checks 0 index again but we have 1 not 3, so it keeps going until on the last pass it has been round 3 times and that equals the 0 index of 3 so it stops the loop

I was assuming the data in the index matters but it doesn't i don't think its the count after the loop has gone round once i think that does as it keeps comparing until the conditions are right?

That sounds about right to me...lol

Dont worry guys one day i will get this... lol

Edited January 2, 2012 by Chimaera

[Melba23]

Chimaera,

Pretty close.

The count is actually increased by the Next statement, so the loop continues until the count gets to more than the limit - as you can see here:

For $i = 1 To 4
Next
MsgBox(0, "Count", $i)

M23

[guinness]

I must have confused you guinness i wasnt worried about counting backwards im trying to work out how the array counts

You didn't confuse me, I was answering your question of "do arrays count backwards?" so I explained that a For Loop counts up by one BUT it can count backwards by changing the Step value.