[Solved] Store Vars in Array then use them

[IanN1990]

$var = WinList()
For $i = 1 to $var[0][0]
If $var[$i][0] <> "" AND IsVisible($var[$i][1]) Then
if $var[$i][0] = "Program Manager" or $var[$i][0] = "RightScreen" or $var[$i][0] = "LeftScreen" or $var[$i][0] = "MiddleScreen" or $var[$i][0] = "TaskBar"  Then
Else
  WinSetTrans($var[$i][1], "", 0)
EndIf
    EndIf
Next

Func IsVisible($handle)
  If BitAnd( WinGetState($handle), 2 ) Then
    Return 1
  Else
    Return 0
  EndIf
EndFunc

Takes all the "Visible" (apart from Desktop, Taskbar and 3 GUIs) windows and hides them, but i want to make it look a little nicer by dimming them out

For $i = 255 to 1 Step -1
sleep(10)
WinSetTrans($Var[$i][1], '', $i)
Next

From 255, to 1 by 1 reduces the Transparency of the window.

Is there any way i can take the first function, store all that collected information into an array and then feed it into the second one to make every window dim at once rather then one at a time ?

Edited April 14, 2012 by IanN1990

[guinness]

Something like this perhaps?

Note: It will set the transparency of all visible windows to 0, so please be careful.

expandcollapse popup

_DimVisibleWindows()
Sleep(2000)
_DimVisibleWindows(1) ; Reverse the procedure.

Func _DimVisibleWindows($iReverse = 0, $sExceptions = "Program Manager;RightScreen;LeftScreen;TaskBar;SciTE")
    $sException = StringReplace($sExceptions, ";", "|")
    Local $aArray = WinList()
    Local $aReturn[$aArray[0][0] + 1][2]

    For $i = 1 To $aArray[0][0]
        If StringRegExp($aArray[$i][0], $sException) Then ; If the title of the window matches an exception then skip it.
            ContinueLoop
        EndIf
        If BitAND(WinGetState($aArray[$i][1]), 2) Then ; Check if the window is visible.
            $aReturn[0][0] += 1
            $aReturn[$aReturn[0][0]][0] = $aArray[$i][1]
            If $iReverse Then
                $aReturn[$aReturn[0][0]][1] = 0
            Else
                $aReturn[$aReturn[0][0]][1] = 255
            EndIf
        EndIf
    Next

    Local $iExit = 0
    Local $iTrans = 255
    If $iReverse Then
        $iExit = 255
        $iTrans = 0
    EndIf
    While 1
        For $i = 1 To $aReturn[0][0]
            If $iReverse Then
                $aReturn[$i][1] += 1
            Else
                $aReturn[$i][1] -= 1
            EndIf
            WinSetTrans($aReturn[$i][0], "", $aReturn[$i][1])
        Next

        If $iReverse Then
            $iTrans += 1
            If $iExit = $iTrans Then
                ExitLoop
            EndIf
        Else
            $iTrans -= 1
            If $iTrans = $iExit Then
                ExitLoop
            EndIf
        EndIf
    WEnd
EndFunc   ;==>_DimVisibleWindows

Edited January 5, 2012 by guinness

[IanN1990]

yeap and i love the big red text ^^

[guinness]

Changed the function, now includes a reversal of setting the transparency.

[IanN1990]

i liked the way u added "Scite" to the exceptions, that was a very clever idea for when writing/testing code

[guinness]

i liked the way u added "Scite" to the exceptions, that was a very clever idea for when writing/testing code

I'm not always stupid you know!

Most importantly do you understand the code? Because you had the foundation in your initial post but just had to put the rest of the pieces together.

Edited January 5, 2012 by guinness

[IanN1990]

I think i am understanding the basics of it, but it will be a while until i can use it without needing to think about it

There is 1 small things, dispite my efforts it keeps hiding taskbar even if i add it to the exceptions

Edited January 6, 2012 by IanN1990

[guinness]

I should have mentioned I did no optimisation with the code as I wrote it in 5 minutes .

1. Add the Sleep(10) above the WEnd tag.

2. Use _ArrayUnique() to delete the duplicates.

3. Play around with the exclusions part to perhaps include handles too or try with a different approach. For example the code I gave you yesterday where you can find the first handle of a PID or an array. So enumerate the processes (ProcessList()) and then find the handles of those processes, you can also exclude processes e.g. explorer.exe by looking at

If I get time I will try to optimise it, but I think it's good learning practice for you if I'm honest.

[IanN1990]

Thanks for the tips i will look into them and don't worry about optimizing it

[guinness]

OK, I think it will be a good challenge.