"GUICtrlGetHandle" function

[atzoref]

Hi,

Returns the handle for a control and some special (item) handles (Menu, ContextMenu, TreeViewItem).

What is the meaning of the "Handle" here?

Thanks

[jaberwacky]

Returns the identifier that Windows uses to keep track of the control is my best understanding.

[Melba23]

atzoref,

A "handle" is the unique number allocated by Windows to everthing it creates. It is different from the "ControlID" returned by controls created by Autoit's native functions, although many UDF functions do return handles.

Here is a script to show you:

#include <GUIConstantsEx.au3>
#include <GUIButton.au3>


$hGUI = GUICreate("Test", 500, 500)

$hButton_1 = GUICtrlCreateButton("Test 1", 10, 10, 80, 30)

$hButton_2 = _GUICtrlButton_Create($hGUI, "Test 2", 10, 100, 80, 30)

GUISetState()

MsgBox(0, "Results", "GUI handle = " & $hGUI & @CRLF & @CRLF & "Test 1 ControlID = " & $hButton_1  & @CRLF & @CRLF & "Test 2 handle = " & $hButton_2)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

You can usually deal with AutoIt controls using the ControID - handles tend to be needed for DllCalls and the like.

Please ask if you have any more questions - although I am preparing a big lunch at the moment and it might be a while before I get back to you.

M23

[atzoref]

Thanks for your best helpful answer.

It's OK for now.

[atzoref]

A little question I still don't understand

Why do I prefer to deal with those handles above controlID? There is an advantage by using it?

[guinness]

Why do I prefer to deal with those handles above controlID? There is an advantage by using it?

I personally wouldn't think like that, you should be thinking more on the lines of 'What suits my requirements.' For example if you just need a button then GUICtrlCreateButton which be an obvious choice rather than _GUICtrlButton_Create, as you would then have to start using WM_ Messages (see Helpfile) to monitor when the button is selected whereas using the simple GUIGetMsg would alleviate all of this.

ControlIDs are used with native AutoIt controls for example GUICtrlSetData or monitoring when an event happens with GUIGetMsg. Whereas handles you tend to use with the UDF functions (as Melba23 mentioned) because these work directly with Windows which uses handles.

Example to find the ControlID of a handle, but only if the control was created by using a native function.

#include <GUIConstantsEx.au3>
#include <WinAPI.au3>

Example()

Func Example()
    GUICreate("Test", 500, 500)
    Local $iButton_1 = GUICtrlCreateButton("Test 1", 10, 10, 80, 30) ; Create a button and store the ID to a variable.
    Local $hButton_1 = GUICtrlGetHandle($iButton_1) ; Find the handle.

    GUISetState()

    MsgBox(4096, "", "The ControlID is: " & $iButton_1 & @CRLF & _
            "The hWnd (handle) is: " & $hButton_1 & @CRLF & _
            "The ControlID using the hWnd (handle) value is: " & _WinAPI_GetDlgCtrlID($hButton_1))

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE, $iButton_1
                Exit
        EndSwitch
    WEnd
EndFunc   ;==>Example