[SOLVED] Inserted ListView Item not deleting

[czardas]

When I use _GUICtrlListView_InsertItem() I don't seem to be able to delete the inserted item. Does anyone know if I'm doing something wrong, or is this the intended behaviour. I could write another function to insert a row into my ListView control, but I would like to know why this method is not working.

It's the empty 3rd row that should have been deleted.

expandcollapse popup

#include <GUIConstants.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>

_Run()

Func _SetData($hListView)
    For $i = 0 To 3
        GUICtrlCreateListViewItem( _
        $i + 1 &"|"& _
        "Item " & $i &"|"& _
        "C_" & $i+Random(100,700, 1) &"|"& _
        "D_" & $i+Random(100,700, 1) &"|"& _
        "M_" & $i+Random(100,700, 1) , $hListView)
    Next
    _GUICtrlListView_InsertItem($hListView, "", 2) ; Item to be deleted
EndFunc

Func _Run()
    Local $bStyle = BitOR($GUI_SS_DEFAULT_GUI, $WS_MAXIMIZEBOX)
    Local $hDataBuzz = GUICreate(" AU3 Databuzz", 300,200, Default, Default, $bStyle)

    Local $sHeadings = "Index"
    For $i = 1 To 4
        $sHeadings &= "| "
    Next

    $hListView = GUICtrlCreateListView($sHeadings, 0, 0, 300, 200, _
    BitOR($LVS_REPORT,$LVS_SHOWSELALWAYS))
    _GUICtrlListView_SetExtendedListViewStyle($hListView, _
    BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_GRIDLINES))
    _GUICtrlListView_HideColumn($hListView, 0)

    _SetData($hListView)
    ; _GUICtrlListView_DeleteItem($hListView, 1) ; This works, but =>
    _GUICtrlListView_DeleteItem($hListView, 2) ; This isn't working!

    GUISetState(@SW_SHOW)

    ;================================================================================
    While 1
        $msg = GUIGetMsg()
        If $msg = $GUI_EVENT_CLOSE Then ExitLoop
    WEnd
    ;===============================================================================
EndFunc

Edited January 12, 2012 by czardas

[Melba23]

czardas,

Mixing native and UDF creation and item functions in ListViews is always fraught with danger - best to stick with one or the other.

Here is the script adapted to use the UDF functions - I also moved the GUISetState and added a Sleep so you can see it working:

expandcollapse popup

#include <GUIConstants.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>

_Run()

Func _SetData($hListView)
    For $i = 0 To 3
        $iIndex = _GUICtrlListView_AddItem($hListView, $i + 1)
        _GUICtrlListView_AddSubItem($hListView, $iIndex, "Item " & $i, 1)
        _GUICtrlListView_AddSubItem($hListView, $iIndex, "C_" & $i+Random(100,700, 1), 2)
        _GUICtrlListView_AddSubItem($hListView, $iIndex, "D_" & $i+Random(100,700, 1), 3)
        _GUICtrlListView_AddSubItem($hListView, $iIndex, "M_" & $i+Random(100,700, 1), 4)
    Next
    _GUICtrlListView_InsertItem($hListView, "", 2) ; Item to be deleted
EndFunc

Func _Run()
    Local $bStyle = BitOR($GUI_SS_DEFAULT_GUI, $WS_MAXIMIZEBOX)
    Local $hDataBuzz = GUICreate(" AU3 Databuzz", 300,200, Default, Default, $bStyle)

    Local $sHeadings = "Index"
    For $i = 1 To 4
        $sHeadings &= "| "
    Next

    $hListView = _GUICtrlListView_Create($hDataBuzz, $sHeadings, 0, 0, 300, 200, _
    BitOR($LVS_REPORT,$LVS_SHOWSELALWAYS))
    _GUICtrlListView_SetExtendedListViewStyle($hListView, _
    BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_GRIDLINES))
    _GUICtrlListView_HideColumn($hListView, 0)

    GUISetState(@SW_SHOW)

    _SetData($hListView)

    Sleep(1000)

    ;_GUICtrlListView_DeleteItem($hListView, 1) ; This works, but =>
    _GUICtrlListView_DeleteItem($hListView, 2) ; This isn't working!



    ;================================================================================
    While 1
        $msg = GUIGetMsg()
        If $msg = $GUI_EVENT_CLOSE Then ExitLoop
    WEnd
    ;===============================================================================
EndFunc

M23

[czardas]

Thanks. I can see that this is going to be tricky. I may be have to change much more of my code than I had hoped, or I may have to compromise for the time being. I also experienced the same problem with deleting items after using _GUICtrlListView_AddArray so I wrote another function to add the array. I currently need to contemplate time constraints. The phone rings as I speak.

[czardas]

Actually, after a quick analysis, it doesn't look all that bad. I think I'll be able to make the changes needed quite quickly. Whether everything will still work afterwards is unknown, but your explanation gives me a clearer picture. Thanks again.

[czardas]

I have been thinking about this for most of a sleepless night. I haven't been brave enough to attempt the changes yet since there appear to be significant differences between the two different ways of creating a ListView control; and I have the feeling that no matter which root I take, I will need to make a lot of adjustments. Until I try I won't really know the outcome.

My concern is as follows: all the help file examples for the conflicting UDF functions mentioned above use GUICtrlCreateListView, which is a native function. If this is a risky affair, then many of the ListView help file functions would appear to need rewriting. I will be trying the changes with some trepidation withiin the next 48 hours, but I feel I ought to mention my concerns about these help file examples and the accompanying documentation.

Edited January 10, 2012 by czardas

[Melba23]

czardas,

The Help file examples work because they do not mix the creation functions. The _GUICtrlListView_DeleteItem Example1 uses the native functions to create the ListView AND add the items - Example_UDF_Created uses the UDF functions to create the ListView AND add the items.

In your script above, you were mixing native and UDF functions to add items:

Func _SetData($hListView)
    For $i = 0 To 3
        GUICtrlCreateListViewItem( _  ; <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
        $i + 1 &"|"& _
        "Item " & $i &"|"& _
        "C_" & $i+Random(100,700, 1) &"|"& _
        "D_" & $i+Random(100,700, 1) &"|"& _
        "M_" & $i+Random(100,700, 1) , $hListView)
    Next
    _GUICtrlListView_InsertItem($hListView, "", 2) ; Item to be deleted ; <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
EndFunc

It is this which caused your problem.

ListView are complex beasts and although the UDF functions normally work on native created ListViews, mixing the creation functions is a sure-fire way of getting them to fail. If you need to use _GUICtrlListView_InsertItem to interleave items into your existing ListView then I believe you will have to change the whole script to use the UDF functions.

Sorry not to be more optimistic. I can only imagine that there is something that AutoIt native functions do the ListView which makes it incompatible with the UDF functions - and as it is probably buried deep in the core code we are unlikely to see any changes.

M23

[czardas]

If you need to use _GUICtrlListView_InsertItem to interleave items into your existing ListView then I believe you will have to change the whole script to use the UDF functions.

Although I know a fix for the code which I have at present, I was concerned that all future functions which I intend to write might run into the same problem. It looks like I will have to change everything to use UDF functions. I just did a complete overhaul to functions which enable and disable menu items, and I'm finding Undo / Redo buffers quite a challenge. Sometimes it seems that each new thing you add involves a complete rewrite, as if I'm constantly barking up the wrong tree.

Now I understand this more clearly. The UDF ListView behaves differently. For example grid lines do not appear to extend to fill empty the space. You can see this difference if you maximize the two versions above. I need to know what else might be different, and perhaps mess around with GUI and control backgrouds etc. We're lucky that there are experienced coders around, like you, to explain this stuff. Much appreciated.

Edited January 10, 2012 by czardas

[BrewManNH]

The Listview UDF functions don't work well with control IDs when referring to the Listview itself. You should always use the function GUICtrlGetHandle to get the handle of the ListView when using the UDF functions. They will accept the control ID of the listview in the functions, but odd things happen when you do it that way. If you make sure that all your function calls to _GUICtrlListview_xxx use the handle, it will be much easier to work with them.

[czardas]

Thanks BrewManNH, Ill bear that in mind.

I tried to implement _GUICtrlListView_InsertItem() but it was no surpise to me that it failed. Sometimes you just have to keep climbing whichever rock you are climbing. This is one of those occasions where turning back is not an option.. I have found a solution which allows me to insert multiple items using GUICtrlCreateListViewItem() , although it's a little bit complicated since GUICtrlCreateListViewItem() only appends items at the end of the control. The code is messy and it would take too long to write a reproducer, so instead of that, I have written a simulation of this method using _ArrayDisplay() to represent the ListView control. While the method may not be ideal, it could have practical application elsewhere.

Simulation

Imagine that after deleting multiple selected items from a ListView control, the user decides to undo their previous action. This requires inserting multiple rows back into their original positions. A number of possibilities exist, but this method adds them to the end of the ListView first, and repositions them later. To do this, the original Index numbers need to be put back the way they were before deleting the rows. Positioning is then just a question of sorting on an index column. As it happens my original script has a hidden index column.

Reconstruction

expandcollapse popup

#include <Array.au3>

Dim $aListView[4][2] = [[1,"Item 2"],[2,"Item 3"],[3,"Item 6"],[4,"Item 7"]] ; Snapshot after deleting Item 1, Item 4 and Item 5
Dim $aAction2Undo[4][2] = [[3,""],[4,"Item 5"],[3,"Item 4"],[0,"Item 1"]] ; Undo Buffer

_ArrayDisplay($aListView, "After Deleting Rows",-1,0,"","","Row|Index|Data") ; Simulate ListView Control

_UndoDelete($aListView, $aAction2Undo)

_ArrayDisplay($aListView, "After Undo Delete",-1,0,"","","Row|Index|Data") ; Simulate ListView Control

Func _UndoDelete(ByRef $aListView, $aAction2Undo)
    Local $iCount = $aAction2Undo[0][0], $iRows = UBound($aListView), $iOccurence = 3 ; $iOccurence is stored elsewhere

    ; Reconstruct original indeces (Code needs to be streamlined)
    $j = 0
    For $i = 1 To $iOccurence
        For $j = $j To $iRows -1
            If $aListView[$j][0] = $aAction2Undo[$iCount][0] +1 Then
                For $k = $j To $iRows -1
                    $aListView[$k][0] += 1
                Next
                $iCount -= 1
                ExitLoop
            EndIf
        Next
    Next

    For $i = $aAction2Undo[0][0] To $aAction2Undo[0][0] - $iOccurence +1 Step -1 ; From the original script
        ; Redo Buffer code omitted for this simulation

        ; Simulate GUICtrlCreateListViewItem
        ReDim $aListView[UBound($aListView) +1][2] ; Append Rows
        $aListView[UBound($aListView) -1][0] = $aAction2Undo[$i][0] +1
        $aListView[UBound($aListView) -1][1] = $aAction2Undo[$i][1]
    Next

    _ArraySort($aListView) ; Simulate _GUICtrlListView_SimpleSort

    ; Clear Undo Buffer code omitted for this simulation
EndFunc

The code I have written for the real ListView control is heavily embedded code and it struck me that using array functions would make it easier to demonstrate how I solved this problem. Since I no longer need to use _GUICtrlListView_InsertItem() everything is working again.

Finally, it appears that however ListView Control Items are created must be consistant throughout the script. Which is what Melba told me earlier. Now to write the Redo function.

Edited January 12, 2012 by czardas

[czardas]

The Listview UDF functions don't work well with control IDs when referring to the Listview itself. You should always use the function GUICtrlGetHandle to get the handle of the ListView when using the UDF functions. They will accept the control ID of the listview in the functions, but odd things happen when you do it that way. If you make sure that all your function calls to _GUICtrlListview_xxx use the handle, it will be much easier to work with them.

I was just wondering if this only affects ListView controls created using _GUICtrlListView_Create() , since I have never had a problem with my ListView which is created using GUICtrlCreateListView() .

[BrewManNH]

Actually, it (meaning the ListView UDF functions) has more of a problem with Listviews created with GUICtrlCreateListview because the value returned is a control ID and not a handle. If you're using the UDF functions, then you need to reference the handle of the LV, if you're using the native functions, you need the controlID.

[czardas]

If you say this is the case then I won't dispute it. Perhaps if I had multiple List View controls active at the same time I would have come across this problem. The only problem I encountered was the incompatibility of mixing List View creation functions mentioned earlier (now resolved). What I am writing is unlikely to get to public release stage any time soon (if I ever release it at all), however I will thoroughly test it if I do release it.

Although the program is only half written, I started using it today. I have until the end of the Month to prepare my accounts (Government Deadline) and I find using Excel tedious as regards data input, besides being non portable and bloated as regards advanced macros. All I need is a simple table with an accumilative balance and column totals. I don't want to write cell formulas or keep upgrading (paying for) an office program which for my purposes is complete overkill. Although Office is a brilliant program, it's also generally very annoying.

It has only taken me two months to get to this stage, and seeing the program append an accumilative balance column on a years transactions in the blink of an eye makes me very happy. My app also doubles up as a DB and I'm already using it to store professional contact information. Eventually i will implement some easy to use features that normally would require advanced computer skills when done with MS Office. These will include a few basic accounting formulas and date formatting functions; plus a search engine which will include a diacritic case sensitivity option, since much of my work involves Spanish words and phrases. The program works with csv tsv and dat formats.

Thanks everyone for all your advice. I have reached a major stage in this project's development.

Edited January 14, 2012 by czardas

[czardas]

Just a note to say: BrewManNH, you were bang on the money. Passing the control handle to the UDF functions has solved my problems.