Can't stop the loop

[stefionesco]

Hi all.

I'm a beginner in Autoit. I make a little script that must press a key from keyboard until I do stop it.

But it doesn't stop, and I don't know where is the error.

Maybe somebody light my way.

Here is the script:

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
Global $MainWindow, $msg, $start, $stop, $key, $time
$MainWindow = GUICreate("Title", 240, 100)
GUICtrlCreateLabel("Push", 15, 15)
$key = GUICtrlCreateInput("", 75, 14, 20, 20)
GUICtrlCreateLabel("every", 98, 15)
$time = GUICtrlCreateInput("", 145, 14, 25, 20)
GUICtrlCreateLabel("seconds.", 175, 15)
$start = GUICtrlCreateButton("START", 45, 45, 55, 25)
$stop = GUICtrlCreateButton("STOP", 145, 45, 55, 25)
GUISetState(@SW_SHOW)
While 1
$msg = GUIGetMsg()
If $msg = $GUI_EVENT_CLOSE Then Exit
Select
Case $msg = $start
WinSetState("", "", @SW_MINIMIZE)
Do
  Send(GUICtrlRead($key))
  Sleep(GUICtrlRead($time) * 1000)
Until $msg = $stop
EndSelect
WEnd

[Jos]

You are not reading the GUI events anymore in your Do-Until loop.

Something like this?

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
Global $MainWindow, $msg, $start, $stop, $key, $time
$MainWindow = GUICreate("Title", 240, 100)
GUICtrlCreateLabel("Push", 15, 15)
$key = GUICtrlCreateInput("", 75, 14, 20, 20)
GUICtrlCreateLabel("every", 98, 15)
$time = GUICtrlCreateInput("", 145, 14, 25, 20)
GUICtrlCreateLabel("seconds.", 175, 15)
$start = GUICtrlCreateButton("START", 45, 45, 55, 25)
$stop = GUICtrlCreateButton("STOP", 145, 45, 55, 25)
GUISetState(@SW_SHOW)
While 1
$msg = GUIGetMsg()
If $msg = $GUI_EVENT_CLOSE Then Exit
Select
Case $msg = $start
WinSetState("", "", @SW_MINIMIZE)
Do
Send(GUICtrlRead($key))
Sleep(GUICtrlRead($time) * 1000)
$msg = GUIGetMsg()
Until $msg = $stop
EndSelect
WEnd

[stefionesco]

I have tried this too, but it still didn't stop.

[BrewManNH]

Try it this way:

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
Global $MainWindow, $msg, $start, $stop, $key, $time
$MainWindow = GUICreate("Title", 240, 100)
GUICtrlCreateLabel("Push", 15, 15)
$key = GUICtrlCreateInput("", 75, 14, 20, 20)
GUICtrlCreateLabel("every", 98, 15)
$time = GUICtrlCreateInput("", 145, 14, 25, 20)
GUICtrlCreateLabel("seconds.", 175, 15)
$start = GUICtrlCreateButton("START", 45, 45, 55, 25)
$stop = GUICtrlCreateButton("STOP", 145, 45, 55, 25)
GUISetState(@SW_SHOW)
While 1
    $msg = GUIGetMsg()
    If $msg = $GUI_EVENT_CLOSE Then Exit
    Select
        Case $msg = $start
            WinSetState("", "", @SW_MINIMIZE)
            $Timer = TimerInit()
            Do
                If TimerDiff($Timer) >= GUICtrlRead($time) * 1000 Then
                    Send(GUICtrlRead($key))
                    $Timer = TimerInit()
                EndIf
                $msg = GUIGetMsg()
            Until $msg = $stop
    EndSelect
WEnd

This allows the script to read the buttons every time through the Do loop but still only sends the key when your delay tells it to.

[stefionesco]

Now it's work. I will use this $Timer.

Thanks lot

Have a nice day.