Possible to check if "check/selection" boxes are ticked or not?

[st4vr0s]

Hi,

I'm writing a test scrip that opens an application, sets my variables by selecting certain options within preferences and then runs the program.

These options are selected by ticks in boxes.

As I will be running the program a number of times I do not want it to tick or untick my chosen preferences each time I run it.

Is it possible for the script to check if the tick is already present and not to select if it is?

Thanks

[hannes08]

If you know the position of the item you could use PixelGetColor() to see whether it's checked or not.

[bogQ]

• On some lvl it is if we are talking about normal check box

Here is example bassed on XP volume controll

If WinExists('Volume Control') Then
    WinActivate('Volume Control')
    WinWaitActive('Volume Control')
Else
    MsgBox(16,'No win to play with','Pls start volume control from notification area before you run the script next time' & @CRLF & 'Script will now exit')
    Exit
EndIf
$check = ControlCommand ( "Volume Control", "", '[CLASS:Button; INSTANCE:2]', "IsChecked", "" )
If $check Then
    MsgBox(32,'Status of box is '&$check&' Checked','we will attempt to change it')
    ControlCommand ( "Volume Control", "", '[CLASS:Button; INSTANCE:2]', "UnCheck", "" )
  
    $check = ControlCommand ( "Volume Control", "", '[CLASS:Button; INSTANCE:2]', "IsChecked", "" )
    If Not $check Then
        MsgBox(64,'Status of box is '&$check&' Unchecked','Script will now exit')
    Else
        MsgBox(16,'Status of box is '&$check&' Checked','Nothing happens, reason unknown, script will now exit')
    EndIf
Else
    MsgBox(32,'Status of box is '&$check&' Unchecked','we will attempt to change it')
    ControlCommand ( "Volume Control", "", '[CLASS:Button; INSTANCE:2]', "Check", "" )
    $check = ControlCommand ( "Volume Control", "", '[CLASS:Button; INSTANCE:2]', "IsChecked", "" )
  
    If $check Then
        MsgBox(64,'Status of box is '&$check&' Checked','Script will now exit')
    Else
        MsgBox(16,'Status of box is '&$check&' Unchecked','Nothing happens, reason unknown, script will now exit')
    EndIf
EndIf

Edited January 24, 2012 by bogQ

[st4vr0s]

Cheers guys,

Thanks for the help

If PixelGetColor(35, 333) = 0xFFFFFF Then
ControlClick ("general","3.4.7","[ID:1115]")
Else
EndIf