How to make a GUI similar to that of the Window's CMD?

[Mingre]

Hello AutoIt Forums,

Uhh, this is the code that I did:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <string.au3>
#include <array.au3>

Dim $area[2] = [300, 200]
$default = 'Input here>'
$title = 'CMD copycat'

$Form = GUICreate($title, $area[0], $area[1], 186, 398)
GUISetCursor(2)
GUISetBkColor(0x000000)

$text = GUICtrlCreateEdit($default, 8, 8, $area[0] - 25, $area[1] - 25)
GUICtrlSetFont(-1, 10, 400, 0, "Lucida Console")
GUICtrlSetColor(-1, 0xFFFFFF)
GUICtrlSetBkColor(-1, 0x000000)

$Button = GUICtrlCreateButton("Enter", 0, 0, 0, 0)
GUICtrlSetState($Button, $GUI_HIDE)

GUISetState(@SW_SHOW)

Dim $AccelKeys[1][2] = [['{ENTER}', $Button]]
GUISetAccelerators($AccelKeys)


While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg

        Case $Button
            $text_temp = GUICtrlRead($text)
            $input = StringSplit($text_temp, '>')
            $text_temp &= @CRLF & $input[UBound($input) - 1]
            ControlSetText($title, "", $text, $text_temp & @CRLF & $default)
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd

The problem with this one is that everytime I enter a text, the cursor(?) goes back to the start of the Edit CTRL.

How do I make it go to the end of the text instead?

Thanks!

[Melba23]

Lilbert,

The simplest way is to send "Ctrl-END" to the edit:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <string.au3>
#include <array.au3>

Dim $area[2] = [300, 200]
$default = 'Input here>'
$title = 'CMD copycat'

$Form = GUICreate($title, $area[0], $area[1], 186, 398)
GUISetCursor(2)
GUISetBkColor(0x000000)

$text = GUICtrlCreateEdit($default, 8, 8, $area[0] - 25, $area[1] - 25)
GUICtrlSetFont(-1, 10, 400, 0, "Lucida Console")
GUICtrlSetColor(-1, 0xFFFFFF)
GUICtrlSetBkColor(-1, 0x000000)

$Button = GUICtrlCreateButton("Enter", 0, 0, 0, 0)
GUICtrlSetState($Button, $GUI_HIDE)

GUISetState(@SW_SHOW)

Dim $AccelKeys[1][2] = [['{ENTER}', $Button]]
GUISetAccelerators($AccelKeys)

ControlSend($Form, "", $text, "^{END}") ; <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg

        Case $Button
            $text_temp = GUICtrlRead($text)
            $input = StringSplit($text_temp, '>')
            $text_temp &= @CRLF & $input[UBound($input) - 1]
            ControlSetText($title, "", $text, $text_temp & @CRLF & $default)
            ControlSend($Form, "", $text, "^{END}") ; <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Not very elegant, but it works!

M23

[Mingre]

Thank you, really!