ListView changes column names instead of populating?

[LPent]

I have the following:

$watchDirs = IniReadSection("program.ini", "Directories")

$lstWatch = GUICtrlCreateListView("Folder|Active", 336, 32, 265, 321)

For $x = 0 To UBound($watchDirs) - 1
   GUICtrlSetData($lstWatch, $watchDirs[$x][0] & "|" & $watchDirs[$x][1])
Next

Instead of my listview being populated with the read lines in the ini-file, it changes the column-names.

I may be misunderstanding something, but the help file does not mention anything like this?

So what am I doing wrong?

[Melba23]

LPent,

If you look at the Help file page for GUICtrlCreateListView, where do you see GUICtrlSetData used to fill the ListView?

The page in my help file uses GUICtrlCreateListViewItem which is what you should use:

#include <GUIConstantsEx.au3>

Global $watchDirs[2][2] = [[1, "One"], [2, "Two"]]

$hGUI = GUICreate("Test", 500, 500)

$lstWatch = GUICtrlCreateListView("Folder|Active", 10, 10, 265, 321)

For $x = 0 To UBound($watchDirs) - 1
   GUICtrlCreateListViewItem($watchDirs[$x][0] & "|" & $watchDirs[$x][1], $lstWatch)
Next

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

All clear?

M23

[LPent]

Hi Melba,

Under 'parameters' next to 'data' it states:

Combo, List, ListView, ListViewItem: An Opt("GUIDataSeparatorChar",...) separated list of items.

Which suggested to me it is used for all these things equally, esp. since none of these are explained separately (only the combo in the example). Hence I misunderstood.

thanks for the help.

[Melba23]

Lpent,

GUICtrlSetData is use to change the data of an already created control - that is why the first parameter is its ControlID. The only control you had was the ListView itself, so GUICtrlSetData changed its data - the column headings. Once you have created the ListViewItems as I showed above, you can alter their content by usung their returned ControlID like this:

#include <GUIConstantsEx.au3>

Global $watchDirs[2][2] = [[1, "One"], [2, "Two"]], $aItem_ControlID[2]

$hGUI = GUICreate("Test", 500, 500)

$lstWatch = GUICtrlCreateListView("Folder|Active", 10, 10, 265, 321)

For $x = 0 To UBound($watchDirs) - 1
   $aItem_ControlID[$x] = GUICtrlCreateListViewItem($watchDirs[$x][0] & "|" & $watchDirs[$x][1], $lstWatch)
Next

GUISetState()

Sleep(2000)

; Now change the data
GUICtrlSetData($aItem_ControlID[1], 3 & "|Three")

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Clearer?

M23

[LPent]

crystal Thanks.

[Melba23]

LPent,

My pleasure.

M23