button activation when chose something from combo list

[sliwek]

how can i do something like that when i chose option from list then button will be active

how to do button2 not active on start gui and it will be active when i chose resolution "user define" from list.

and how to back to button2 not active when chose somthing else from lost.

$resolution = GUICtrlCreateCombo("", 88, 85, 105, 25, BitOR($CBS_DROPDOWNLIST,$CBS_AUTOHSCROLL))

GUICtrlSetData(-1, "1600x900|1024x768|user define ", "1600x900")

$button2 = GUICtrlCreateButton("Define", 404, 383, 81, 25, $WS_GROUP)

[Melba23]

sliwek,

Just set the state of the button depending on what the combo holds - like this:

#include <GUIConstantsEx.au3>

$hGUI = GUICreate("Test", 500, 500)

$hCombo = GUICtrlCreateCombo("", 10, 10, 200, 20)
GUICtrlSetData(-1, "1600x900|1024x768|user define", "1600x900")

$hButton = GUICtrlCreateButton("Define", 10, 50, 80, 30)
GUICtrlSetState(-1, $GUI_DISABLE)

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $hCombo
            Switch GUICtrlRead($hCombo)
                Case "user define"
                    GUICtrlSetState($hButton, $GUI_ENABLE)
                Case Else
                    GUICtrlSetState($hButton, $GUI_DISABLE)
            EndSwitch
    EndSwitch

WEnd

Next time post some code that actually runs - many people will not answer if they have to script a whole GUI for you.

M23

[sliwek]

thx

btw actualy runs code have 5k lines (gui 600 lines) :/

Edited February 14, 2012 by sliwek

[Melba23]

sliwek,

Nothing stopping you writng a small reproducer GUI with a combo and a button. I had to code exactly that to show you how it worked - you could have done it first to help us help you.

M23