Help with Treeview

[DanielDaniel]

Hi all, hopefully this is an easy one!

I use the below code to show a msgbox with the text of the currently selected item in a treeview. However, what I'd like to do is this: if the item selected is a 1st level node, then display it's text. if an item is selected that is a sub-item of a node, then show the node name for that item rather than the text of the selected item.

Is this possible?

Thanks,

Daniel

<P>$Selected = _GUICtrlTreeView_GetSelection($treeView)<BR>msgbox(0,"test",
_GUICtrlTreeView_GetText($treeView, $Selected))</P>

[Melba23]

DanielDaniel,

Use _GUICtrlTreeView_GetParentHandle to get the "node" of the selected item.

Here is a simple example:

expandcollapse popup

#include <GUIConstants.au3>
#include <windowsconstants.au3>
#include <guitreeview.au3>
#include <guimenu.au3>

; Create GUI
$hGUI = GUICreate("Test", 500, 500)

$hTreeView = _GUICtrlTreeView_Create($hGUI, 10, 10, 200, 300, BitOR($TVS_HASLINES, $TVS_LINESATROOT, $TVS_SHOWSELALWAYS), $WS_EX_CLIENTEDGE)

$cButton = GUICtrlCreateButton("Node selected", 10, 460, 100, 30)

GUISetState()

; Fill Treeview
_GUICtrlTreeView_BeginUpdate($hTreeView)
For $j = 1 To 3
    $iNode = _GUICtrlTreeView_Add($hTreeView, 0, "Node " & $j)
    For $i = 1 To 5
        _GUICtrlTreeView_AddChild($hTreeView, $iNode, "Item " & $i)
    Next
Next
_GUICtrlTreeView_EndUpdate($hTreeView)
_GUICtrlTreeView_Expand($hTreeView)

; Loop
While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cButton
            $hItem = _GUICtrlTreeView_GetSelection($hTreeView)
            $hParent = _GUICtrlTreeView_GetParentHandle($hTreeView, $hItem)
            If $hParent Then
                ConsoleWrite("Node Selected: " & _GUICtrlTreeView_GetText($hTreeview, $hParent) & @CRLF)
            Else
                ConsoleWrite("Node Selected: " & _GUICtrlTreeView_GetText($hTreeview, $hItem) & @CRLF)
            EndIf
    EndSwitch
WEnd

All clear?

M23

[DanielDaniel]

perfect, thanks!