Some Cyberslug Scraps

[CyberSlug]

expandcollapse popup

; A collection of clipboard utilities.
; 8 March 2004 - CyberSlug
;
; I assume that Ctrl+C and Ctrl+V perform Copy and Paste, respectively,
;    in the active application.
; Note:  The only reason for 'Send("{ShiftDown}{ShiftUp}")'
;    is to prevent a potential bug caused by running AutoSense 1.0....

HotKeySet("^+c", "append")  ;Ctrl+Shift+C
HotKeySet("^+v", "replace") ;Ctrl+Shift+V
HotKeySet("^+x", "clear")   ;Ctrl+Shift+X

While 1
   sleep(100)
WEnd


;--------------------------------------------------
; Clipboard "Append" Utility
; Appends linefeed plus selected text to clipboard.
;--------------------------------------------------
Func append()
   Send("{ShiftDown}{ShiftUp}") ;clear the Shift state [optional]

   Local $contents = ClipGet()
   
   Send("^c")
   
   If $contents <> "" Then ClipPut( $contents & @CRLF & ClipGet() )
EndFunc


;-------------------------------------------
; Clipboard "Replace" Utility
; Swap higlighted text with clipboard text.
;-------------------------------------------
Func replace()
   Send("{ShiftDown}{ShiftUp}") ;clear the Shift state [optional]

   Local $itemOne = ClipGet()

   Send("^c")
   Local $itemTwo = ClipGet()

   ClipPut($itemOne)
   Send("^v")

   ClipPut($itemTwo)
EndFunc


;--------------------------------------------------
; Clipboard "Clear" Utility
; Clear the clipboard and free up memory!
;--------------------------------------------------
Func clear()
   ClipPut("")
EndFunc

[i542]

I love reading old topics

i542