how to go to the end of the text in an edit control?

[Allow2010]

hi all,

i use an edit control to display a logfile.

This is update every few seconds and when i load the updated logfile to the edit, the cursor position in the edit is reset...is there an easy way to

1. keep the current curor position/view position

or

2. go to the end of the text after it has been loaded?

I was thinking about using send to send the end key, but i can not give focus to the edit control every few seconds to do this...

ideas are welcome...thanks !

Edited February 25, 2012 by Allow2010

[somdcomputerguy]

You could use ControlSend, then you might not have to give this control focus.

[Allow2010]

thanks, will try it...

Edit:

Local $iLines = _GUICtrlEdit_GetLineCount($hEdit)
_GUICtrlEdit_LineScroll($hEdit, 0, $iLines)

works like a charm....thanks !!

Edited February 26, 2012 by Allow2010

[Melba23]

Allow2010,

I would do it like this - the code fired by the button would be used by your update function:

#include <GUIConstantsEx.au3>
#include <GuiEdit.au3>
#include <ScrollBarConstants.au3>

$sText = "Line 1"
$iCount = 1

$hGUI = GUICreate("Test", 500, 500)

$cEdit = GUICtrlCreateEdit($sText, 10, 10, 200, 200)

$cButton = GUICtrlCreateButton("Update", 10, 300, 80, 30)

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cButton
            GUICtrlSetState($cEdit, $GUI_FOCUS)
            $iCount += 1
            $sText &= @CRLF & "Line " & $iCount
            GUICtrlSetData($cEdit, $sText)
            _GUICtrlEdit_SetSel($cEdit, -1, -1)
            _GUICtrlEdit_Scroll($cEdit, $SB_SCROLLCARET)

    EndSwitch

WEnd

M23

[Allow2010]

OK, but this sets focus, which might be a problem...thanks anyway...