[Solved] Child window won't close at same time as Parent window

[Kyan]

Hi everyone

I have a problem with window childs, to close the child window I need to click twice in the close button of the parent window

here's the code

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Global $Parent, $Child
$Parent = GUICreate("Parent", 370, 190,-1,-1)
$context = GUICtrlCreateContextMenu()
$contextItem1 = GUICtrlCreateMenuItem("Child", $context)
GUISetState()
While 1
$nMsg = GUIGetMsg(1)
Switch $nMsg[0]
  Case $GUI_EVENT_CLOSE
   If $nMsg[1] = $Child Then
    GUISwitch($Child)
    GUIDelete()
   ElseIf $nMsg[1] = $Parent Then
    GUISwitch($Parent)
    GUIDelete()
    Exit
   EndIf
  Case $contextItem1
   _Child()
EndSwitch
WEnd
Func _Child()
$Child = GUICreate("Child", 321, 70, -1, -1,BitXOR($GUI_SS_DEFAULT_GUI, $WS_MINIMIZEBOX),'',$Parent)
GUISetState()
While 1
  $Msg = GUIGetMsg()
  Switch $Msg
   Case $GUI_EVENT_CLOSE
    GUISwitch($Child)
    GUIDelete()
    ExitLoop
  EndSwitch
WEnd
EndFunc

I miss some thing?

Best regards

Diogo

Edited March 3, 2012 by DiOgO

[BrewManNH]

I have corrected your code below, see where I commented out the parts that are unnecessary and changed the parts where you made a mistake.

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Global $Parent, $Child
$Parent = GUICreate("Parent", 370, 190, -1, -1)
$context = GUICtrlCreateContextMenu()
$contextItem1 = GUICtrlCreateMenuItem("Child", $context)
GUISetState()
While 1
    $nMsg = GUIGetMsg(1)
    Switch $nMsg[0]
        Case $GUI_EVENT_CLOSE
            If $nMsg[1] = $Child Then
;~              GUISwitch($Child) <<<<<<<<<<<<< Not needed when coded correctly
                GUIDelete($Child) ; <<<<<<<<<<<<<<< Use the proper format and you don't need to switch windows to close
            ElseIf $nMsg[1] = $Parent Then
;~              GUISwitch($Parent) <<<<<<<<<<<<<<< This line and the next are unnecessary as you're exiting the script
;~              GUIDelete()
                Exit
            EndIf
        Case $contextItem1
            _Child()
    EndSwitch
WEnd
Func _Child()
    $Child = GUICreate("Child", 321, 70, -1, -1, BitXOR($GUI_SS_DEFAULT_GUI, $WS_MINIMIZEBOX), '', $Parent)
    GUISetState()
;~  While 1
;~      $Msg = GUIGetMsg() <<<<<<<<<<<<<<<< This is what was causing your script to malfunction, you shouldn't use 2 While Loops
;~      Switch $Msg
;~          Case $GUI_EVENT_CLOSE
;~              GUISwitch($Child)
;~              GUIDelete()
;~              ExitLoop
;~      EndSwitch
;~  WEnd
EndFunc   ;==>_Child

[Kyan]

so the problem is caused by use 2 while loops, how can I get the events from the child window in this case?

using a if and another select case?

[Melba23]

DiOgO,

Take a look at the Managing Multiple GUIs tutorial in the Wiki.

M23

[Kyan]

DiOgO,

Take a look at the Managing Multiple GUIs tutorial in the Wiki.

M23

thanks, this one works great

expandcollapse popup

#include <GUIConstantsEx.au3>
Global $hGUI2 = 9999, $hButton3 = 9999 ; Predeclare the variables with dummy values to prevent firing the Case statements
gui1()
Func gui1()
    $hGUI1 = GUICreate("Gui 1", 200, 200, 100, 100)
    $hButton1 = GUICtrlCreateButton("Msgbox 1", 10, 10, 80, 30)
    $hButton2 = GUICtrlCreateButton("Show Gui 2", 10, 60, 80, 30)
    GUISetState()
    While 1
        $aMsg = GUIGetMsg(1) ; Use advanced parameter to get array
        Switch $aMsg[1] ; check which GUI sent the message
            Case $hGUI1
                Switch $aMsg[0] ; Now check for the messages for $hGUI1
                    Case $GUI_EVENT_CLOSE ; If we get the CLOSE message from this GUI - we exit <<<<<<<<<<<<<<<
                        ExitLoop
                    Case $hButton1
                        MsgBox("", "MsgBox 1", "Test from Gui 1")
                    Case $hButton2
                        GUICtrlSetState($hButton2, $GUI_DISABLE)
                        gui2()
                EndSwitch
            Case $hGUI2
                Switch $aMsg[0] ; Now check for the messages for $hGUI2
                    Case $GUI_EVENT_CLOSE ; If we get the CLOSE message from this GUI - we just delete the GUI <<<<<<<<<<<<<<<
                        GUIDelete($hGUI2)
                        GUICtrlSetState($hButton2, $GUI_ENABLE)
                    Case $hButton3
                        MsgBox("", "MsgBox", "Test from Gui 2")
                EndSwitch
        EndSwitch
    WEnd
EndFunc   ;==>gui1
Func gui2()
    $hGUI2 = GUICreate("Gui 2", 200, 200, 350, 350)
    $hButton3 = GUICtrlCreateButton("MsgBox 2", 10, 10, 80, 30)
    GUISetState()
EndFunc   ;==>gui2