Delete all values from array

[Dizzy]

Hi,

i thought, that there was a function to delete all values of an array (something with @ ???).

Using a filelist i read the *.txt file i an array to get some values into excel.

Before i read the next file, i want to be sure, that all old values are deleted (without loops like do-while, or for-next ...).

Thanks

[guinness]

Redeclare it >>

#include <Array.au3>

Local $aMain[10]
_ArrayDisplay($aMain)
_ArrayEmpty($aMain)
_ArrayDisplay($aMain)

Func _ArrayEmpty(ByRef $aArray)
    Switch UBound($aArray, 0) ; Dimension, 1D or 2D array are supported.
        Case 1
            Local $aEmpty1D[1]
            $aArray = $aEmpty1D

        Case 2
            Local $aEmpty2D[1][UBound($aArray, 2)]
            $aArray = $aEmpty2D
    EndSwitch
EndFunc   ;==>_ArrayEmpty

[guinness]

OR if you want to retain the same size >>

#include <Array.au3>

Local $aMain[11] = [10]
_ArrayEmpty($aMain)
_ArrayDisplay($aMain, "Empty 1D Array.")

Local $aMainEx[11][3] = [[10]]
_ArrayEmpty($aMainEx)
_ArrayDisplay($aMainEx, "Empty 2D Array.")

Func _ArrayEmpty(ByRef $aArray)
    Switch UBound($aArray, 0) ; Dimension, 1D or 2D array are supported.
        Case 1
            Local $aEmpty1D[UBound($aArray, 1)]
            $aArray = $aEmpty1D

        Case 2
            Local $aEmpty2D[UBound($aArray, 1)][UBound($aArray, 2)]
            $aArray = $aEmpty2D
    EndSwitch
EndFunc   ;==>_ArrayEmpty

[water]

If you use something like

_FileReadToArray($file, $aArray)

to read the file to an array you could simply destroy the array by something like

$aArray = 0

. The next call to _FileReadToArray recreates the array.

[guinness]

True if you want to destroy the Array.

[water]

I interpret the OPs request to be "sure, that all old values are deleted" that there are no remainings of the previous file in the array.

I think the fastest wway is to drop the array and let _FileReadToArray recreate the array.

[guinness]

No it was a good catch, though it is a little vague without any code to show what they're doing so at least all options have been covered.

[Dizzy]

Hi guinness,

hi water,

thanks for your fast reply.

Something like this i was looking for : $aArray = 0

It doesn't work for 2-dim arrays ($aArray[$i][%u]).

Do you have a solution for that?

But also really good and for later tasks i'll keep guinness solution in mind!

Thanks for help Dizzy

Edited March 14, 2012 by Dizzy

[Dizzy]

Water is going right : "I interpret the OPs request to be "sure, that all old values are deleted" that there are no remainings of the previous file in the array.

".

I want to be sure, that all values are deleted before the next loop fills the array again.

But i missed to say, that my array is a 2-dim array

Dizzy

[water]

Can you post the code you use to create and fill the array?

Edited March 14, 2012 by water

[Dizzy]

Of course ..

expandcollapse popup

#include <File.au3>
#include <Array.au3>
#include <Excel.au3>
Global $aRecords, $x, $file
$sFilePath1 = @ScriptDir & "\Server.xlsx"
$oExcel = _ExcelBookOpen($sFilePath1, 1)
; Find next empty line
for $x = 7 to 10000
if _ExcelReadCell($oExcel, $x, 3) = "" Then
  $eLine = $x
  ExitLoop
EndIf
Next
ConsoleWrite("Next line : " & $eServer & @crlf)
Local $FileList = _FileListToArray(@ScriptDir & "\test\", "*.txt",1)
If @error = 1 Then
    MsgBox(0, "", "No Folders Found.")
    Exit
EndIf
If @error = 4 Then
    MsgBox(0, "", "No Files Found.")
    Exit
EndIf
for $file = 1 to $FileList[0]-2
; Delete value from array's
$aRecords = 0 ; OK (should also be ok by reuse of "_FileReadToArray")

If Not _FileReadToArray(@ScriptDir & "\test\" & $FileList[$file], $aRecords) Then
  MsgBox(4096, "Error", " Error reading log to Array     error:" & @error)
  Exit
EndIf
If @error = 1 Then
  MsgBox(0, "Error!", "Error opening specified file")
  Exit
ElseIf @error = 2 Then
  MsgBox(0, "Error!", "Unable to Split the file")
  Exit
EndIf
Global $aArray[$aRecords[0]][4]
$i = 0
$array = 0
; Delete value from array's
; --> $aArray = 0 ; How can i be sure that all values are deleted?
Do
  $i = $i + 1
  $array = StringSplit($aRecords[$i], "|")
  if $array[0] > 2 Then
   $array[2] = StringStripWS ( $array[2], 3 )
   $array[3] = StringStripWS ( $array[3], 3 )
   $aArray[$i][2] = $array[2]
   $aArray[$i][3] = $array[3]
   Select
    Case $array[2] = "Computer Name"
     ; fill excel ...
   EndSelect
  EndIf
until $i > $aRecords[0]-2
Next

Thanks for your time & help!

[BrewManNH]

When you assign the return from StringSplit to the variable $array, it will always contain only what StringSplit returns. The array returned is always cleared and replaced by the return from StringSplit, you shouldn't ever have to worry about that. If it doesn't clear the array then there's a bug and should be reported as such.

EDIT: If you're really paranoid about the returned array's contents, just use $array = "" just before the StringSplit, that will definitely clear the array's contents.

Edited March 14, 2012 by BrewManNH

[water]

To empty an array and then re-define it with new dimensions use something like this:

#include <array.au3>
Global $aArray[2][4]
$aArray[0][0] = "00"
$aArray[0][3] = "03"
$aArray[1][0] = "10"
$aArray[1][3] = "13"
_ArrayDisplay($aArray)
$aArray = 0               ; clear the arrays content
Global $aArray[3][5]      ; re-define the array
_ArrayDisplay($aArray)

Edited March 14, 2012 by water

[guinness]

Just bare in mind if you do use Au3Check with advanced parameters that will display an error message.

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7

Edited March 14, 2012 by guinness

[water]

Just checked. Version 3.3.8.0, 3.3.9.0 and 3.3.9.2 don't give an error message for the code I posted above with your Au3Check parameters.

[guinness]

Weird, it seems it doesn't apply to Arrays, learnt something new today as I thought the same logic applied to Arrays as well.

Fails (of course!):

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7

Global $sString = "String"
$sString = ""
Global $sString = "String"

Doesn't Fail:

#AutoIt3Wrapper_Au3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7

Global $sString = "String"
$sString = ""
Global $sString[2][2]

Sorry for wasting your time water.

Edited March 14, 2012 by guinness

[Dizzy]

Hi BrewManNH, thanks for reply.

EDIT: If you're really paranoid about the returned array's contents, just use $array = "" just before the StringSplit, that will definitely clear the array's contents.

I don't think i'm paranoid ... but your're right. If autoit clears the array everything will be fine. To be sure, i thought i have to do it myself

So - i don't have to play around the array.

@guinness: I'll use the Au3Check - thanks

Thanks guys!

Dizzy

Edited March 14, 2012 by Dizzy

[water]

Sorry for wasting your time water.

You (and I) did learn something new today - so the time wasn't wasted at all

Once again I see why I like to try things myself - that's how I get most out of it