problem with optional parameters in a function

[kor 5]

Func _DisableInput($n1, $n2, $n3, $n4)
    GUICtrlSetState($n1, $GUI_DISABLE)
    GUICtrlSetState($n2, $GUI_DISABLE)
    GUICtrlSetState($n3, $GUI_DISABLE)
    GUICtrlSetState($n4, $GUI_DISABLE)
EndFunc   ;==>_DisableInput

_DisableInput($aInput[0][0], $aInput[1][0], $aInput[2][0], $aInput[3][0])

The above works if I want to disable all 4 inputs. But if I only want to disable 3 and thus remove the $aInput[3][0] from the function call I get an error saying incorrect number of parameters.

Basically I want to be able to disable X number of inputs up to a maximum of 4.

Edited March 14, 2012 by kor

[water 2,359]

To make a parameter optional you have to set a default value in the parameter list. In this case I used the keyword Default but it could be any other value like 0 or "".

Func _DisableInput($n1, $n2 = Default, $n3 = Default, $n4 = Default)
    GUICtrlSetState($n1, $GUI_DISABLE)
    If $n2 <> Default Then GUICtrlSetState($n2, $GUI_DISABLE)
    If $n3 <> Default Then GUICtrlSetState($n3, $GUI_DISABLE)
    If $n4 <> Default Then GUICtrlSetState($n4, $GUI_DISABLE)
EndFunc   ;==>_DisableInput

Edited March 14, 2012 by water

[guinness 1,517]

Like this, now only the first parameter is mandatory as why would you use this without using at least one parameter.

Func _DisableInput($n1, $n2 = -1, $n3 = -1, $n4 = -1)
    Local $aArray[5] = [4, $n1, $n2, $n3, $n4]
    For $i = 1 To $aArray[0]
        If $aArray[$i] = -1 Then
            ContinueLoop
        EndIf
        GUICtrlSetState($aArray[$i], $GUI_DISABLE)
    Next
EndFunc   ;==>_DisableInput

Plus I love using loops, because you can adapt this to 15 parameters without adding more lines.

Edited March 14, 2012 by guinness

[kor 5]

water, thank you!

it's working now.

[Melba23 3,396]

kor,

Use arrays. Put all the ControlIDs into one array and then pass another array as a parameter to the function. tehn you can have as many as you want:

expandcollapse popup

#include <guiconstantsex.au3>

Global $aInput[4], $aState[4]

$hGUI = GUICreate("Test", 500, 500)

For $i = 0 To 3
    $aInput[$i] = GUICtrlCreateInput("", 10, 10 + (30 * $i), 200, 20)
Next

$cButton_1 = GUICtrlCreateButton("Disable #3", 10, 200, 100, 30)
$cButton_2 = GUICtrlCreateButton("Disable #1 && #2", 10, 250, 100, 30)
$cButton_3 = GUICtrlCreateButton("Disable #2 && #4", 10, 300, 100, 30)
$cButton_4 = GUICtrlCreateButton("Enable all", 10, 350, 100, 30)


GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cButton_1
            Global $aState [4] = [1, 1, 0, 1]
            _Set_Input_State()
        Case $cButton_2
            Global $aState [4] = [0, 0, 1, 1]
            _Set_Input_State()
        Case $cButton_3
            Global $aState [4] = [1, 0, 1, 0]
            _Set_Input_State()
        Case $cButton_4
            Global $aState [4] = [1, 1, 1, 1]
            _Set_Input_State()
    EndSwitch
WEnd

Func _Set_Input_State()

    For $i = 0 To UBound($aState) - 1
        If $aState[$i] = 1 Then
            GUICtrlSetState($aInput[$i], $GUI_ENABLE)
        Else
            GUICtrlSetState($aInput[$i], $GUI_DISABLE)
        EndIf
    Next

EndFunc

M23

Edited March 14, 2012 by Melba23
Wrong button, too soon!