progress bar addition

[kaasknak]

Hello,

I've created this program that calculates pi if you let it run an infinite number of calculations.

Because large numbers may take some time to calculate I want to add a progress bar.

Also I want the input to be numbers only.

Can someone help me?

This is my current script

while 1
$aantal=InputBox("Invoer", "Vul in hoeveel berekeneningen de computer moet uitvoeren."& @CRLF &"Hoe groter het getal hoe meer het van je computer vraagt.")
if $aantal = 0 then
Exit
Else
$benadering=0
$noemer=1
Do
$temp=1/($noemer^2)
$benadering=$benadering+$temp
$noemer=$noemer+1
Until $noemer=$aantal
EndIf
$stap1=$benadering*6
$pi=sqrt($stap1)
$u=MsgBox(325, "uitkomst", "Volgens je benadering:"& @CRLF &"pi="&$pi)
If $u=2 then Exit
WEnd

Can someone help me?

thanks

[kaasknak]

bump

[Melba23]

kaasknak,

Welcome to the AutoIt forum.

Here is how you could add a simple progressbar to your script:

While 1
    $aantal = InputBox("Invoer", "Vul in hoeveel berekeneningen de computer moet uitvoeren." & @CRLF & "Hoe groter het getal hoe meer het van je computer vraagt.")
    ProgressOn ("Calulating", "Progress", 0)
    If $aantal = 0 Then
        Exit
    Else
        $benadering = 0
        For $noemer = 1 To $aantal
            ProgressSet( $noemer / $aantal * 100, $noemer)
            $temp = 1 / ($noemer ^ 2)
            $benadering = $benadering + $temp

            ; Just to slow it down so you can see the progress increase for small numbers
            Sleep(1000)
            ; Remove these lines if you use BIG numbers!

        Next
    EndIf
    ProgressOff()
    $stap1 = $benadering * 6
    $pi = Sqrt($stap1)
    If MsgBox(325, "uitkomst", "Volgens je benadering:" & @CRLF & "pi=" & $pi) = 2 Then
        Exit
    EndIf
WEnd

If you want to limit the input to digits only then you will have to create your own GUI using an input control with the $ES_NUMBER style. But you could always use Number on $aantal to convert it.

M23

[kaasknak]

Thanks I am going to try this.

[kaasknak]

After some slight adaption it worked just the way I wanted it to work.

Thanks for your help.

Here is my new code.

While 1
    $aantal = InputBox("Invoer", "Vul in hoeveel berekeneningen de computer moet uitvoeren." & @CRLF & "Hoe groter het getal hoe meer het van je computer vraagt.")
    ProgressOn ("Berekenen", "Vooruitgang", 0)
    If $aantal = 0 Then
        Exit
    Else
        $benadering = 0
        For $noemer = 1 To $aantal
            ProgressSet( $noemer / $aantal * 100, Round ($noemer / $aantal * 100, 1) & "%")
            $temp = 1 / ($noemer ^ 2)
            $benadering = $benadering + $temp
        Next
    EndIf
    ProgressOff()
    $stap1 = $benadering * 6
    $pi = Sqrt($stap1)
    If MsgBox(325, "uitkomst", "Volgens je benadering:" & @CRLF & "pi=" & $pi) = 2 Then
        Exit
    EndIf
WEnd

[Zedna]

To avoid flickering and much higher calculation speed use this:

Global $percent_prev

While 1
    $aantal = InputBox("Invoer", "Vul in hoeveel berekeneningen de computer moet uitvoeren." & @CRLF & "Hoe groter het getal hoe meer het van je computer vraagt.")
    ProgressOn ("Berekenen", "Vooruitgang", 0)
    If $aantal = 0 Then
        Exit
    Else
        $benadering = 0
        For $noemer = 1 To $aantal
            $percent = Round ($noemer / $aantal * 100, 1)
            If $percent <> $percent_prev Then
                ProgressSet( $percent, $percent & "%")
                $percent_prev = $percent
            EndIf
            $temp = 1 / ($noemer ^ 2)
            $benadering = $benadering + $temp
        Next
    EndIf
    ProgressOff()
    $stap1 = $benadering * 6
    $pi = Sqrt($stap1)
    If MsgBox(325, "uitkomst", "Volgens je benadering:" & @CRLF & "pi=" & $pi) = 2 Then
        Exit
    EndIf
WEnd