AutoIt Snippets

[water]

$sString = StringMid($sString, StringInStr($sString, $sDelimiter) + StringLen($sDelimiter))

Edited May 30, 2015 by water

[water]

Double post.

Edited June 1, 2015 by water

[iamtheky]

$sString = "ThisIsATestStringOfCharacters"
$sDelimiter = "String"

msgbox(0, 'Before Delim' , _StringBefore($sString , $sDelimiter))

Func _StringBefore($sString , $sDelimiter)
Return StringLeft($sString , StringInStr($sString, $sDelimiter) - 1)
EndFunc

 

Edited June 8, 2015 by boththose

[TheDcoder]

Thanks @water

Updated it, TD

[nitekram]

When you're working in a vmware system that does not have VMTools installed and you want to paste text from your system to the virtual system, you can use this script snippet to ghetto rig paste from your clipboard into the VM system using the send function:

#RequireAdmin
AutoItSetOption('TrayAutoPause', 0)
HotKeySet("^+v", 'Sender')

While 1
    Sleep(100)
WEnd

Func Sender()
    Send(ClipGet())
EndFunc

Not at work to test this, but does requie admin rights? 

[TheDcoder]

Second Contribution... Small but neat when you use it

; #FUNCTION# ====================================================================================================================
; Name ..........: CalcPercent
; Description ...: Calculates Percentage
; Syntax ........: CalcPercent($iPartDone, $iTotal[, $iRoundToDecimalPlace = 1])
; Parameters ....: $iPartDone           - Value of the part which is done.
;                  $iTotal              - The total value.
;                  $iRoundToDecimalPlace- [optional] Round upto which decimal place?. Default is 1.
; Return values .: Percentage (without % symbol)
; Author ........: TheDcoder
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........: http://bit.ly/CalcPercentForAutoIt
; Example .......: Yes, See below
; ===============================================================================================================================
Func CalcPercent($iPartDone, $iTotal, $iRoundToDecimalPlace = 1)
    Return Round(($iPartDone / $iTotal) * 100, $iRoundToDecimalPlace) ; Calculate percentage, round it & return it!
EndFunc   ;==>CalcPercent

; Example

$iCountdown = 60 * 5 ; the value is in seconds

ProgressOn("Example for CalcPercent function", "Countdown upto " & $iCountdown & " seconds")

$hTimer = TimerInit()
For $i = 1 To $iCountdown
    ProgressSet(CalcPercent($i, $iCountdown))
    Sleep(1000)
Next
$iTime = TimerDiff($hTimer)
$iTime /= 1000

ProgressOff()

MsgBox(64, "Done!", "The countdown has ended! That took ~" & Round($iTime, 1) & " Seconds.")

Hope it may help you, TD

 

P.S Don't reply to this with rude reasons like "Hey! that is so simple! even a newbie can do that." or "It ain't worth posting in snippets section"

Edited June 21, 2015 by TheDcoder
Updated links with shortend Bitly links :)

[water]

P.S Don't reply to this with rude reasons like "Hey! that is so simple! even a newbie can do that." or "It ain't worth posting in snippets section"

If you think this are rude commens then you should have a look at other forums and see how rude comments really look like

 

[TheDcoder]

@water

[Exit]

P.S Don't reply to this with rude reasons like "Hey! that is so simple! even a newbie can do that." or "It ain't worth posting in snippets section"

No need to reply. You gave the answer yourself.

[JLogan3o13]

P.S Don't reply to this with rude reasons like "Hey! that is so simple! even a newbie can do that." or "It ain't worth posting in snippets section"

So, you post something that is basically a rehashing of the example under ProgressSet, you're intelligent *cough* enough to foresee people are probably going to point out the snippet's lack of value, but you posted it anyway?

[TheDcoder]

@JLogan3o13 ...Well...I don't know what to say

[iamtheky]

Maybe explain how you feel your example differs from the progressset helpfile.  You should be encouraging discourse and then logically defending your position rather than trying to preempt, as the forum is a good place to hone your debate skills in addition to your coding.

[TheDcoder]

@JLogan3o13 Debate: How my example differs from ProgressSet's example

Explanation: The only common thing between the two examples is that both are countdown timers... And its just a example .

I posted it here because the threads title reads "AutoIt Snippets" (This isn't part of the debate)...

@boththose Thanks

 

P.S Don't take that debate seriously

[Melba23]

Hi all,

As I read the post which started all of this, I get the impression that it is the CalcPercent function which was the point of the exercise, not the ProgressSet section. To which end I feel some of the resultant comments are a little OTT - although I also feel that a snippet to calculate a percentage is also not exactly earthshattering in and of itself.  So please let us all decide to drop the matter - even though the OP was silly enough to make that ridiculous statement at the end of the post which quite frankly just begged the response it quite rightly got.

M23

[JohnOne]

Second Contribution... Small but neat when you use it

The name of the function is incorrect in your header.

 

[TheDcoder]

@JohnOne

[Iczer]

as vbscript do no like 64 bit i needed something to replace "unescape()"

Func decodeURIComponent($sURIComponent)
    If StringRegExp($sURIComponent, "%[0-9A-Fa-f]{2}", 0) Then
        $sURIComponent = Execute('"' & StringRegExpReplace($sURIComponent,"(%)([0-9A-Fa-f]{2})",'" & Chr(Dec(''$2'')) & "') & '"')
    EndIf
    Return $sURIComponent
EndFunc   ;==>decodeURIComponent

at first glance result is identical to vbscript's "unescape()"

[jchd]

[0-9A-Fa-f]

you can make that [[:xdigit:]]

[TheDcoder]

Third Contribution! Maybe useful when you need to convert an 1D Array to an 2D Array

expandcollapse popup

#include-once
#include <Array.au3> ; <----- ONLY NEEDED FOR EXAMPLE, REMOVE BEFORE USING!!!
#include <StringConstants.au3>


; #FUNCTION# ====================================================================================================================
; Name ..........: ArraySplit
; Description ...: Similar to StringSplit, Converts an 1D Array to an 2D Array based on delimiters
; Syntax ........: ArraySplit(ByRef $aArray, $sDelimiter)
; Parameters ....: $aArray              - Array to process.
;                  $sDelimiter          - Delimiter to split array.
; Return values .: Success: An 2D Array
;                  Failure: 0 & sets @error to:
;                  @error : 1 = Not an array
;                           2 = Delimiter was not found in an element (@extended contains the element's index no.)
; Author ........: TheDcoder
; Modified ......: N/A
; Remarks .......: There should be only 1 delimiter in each element of the Array!!! Only Text before & after the first delimiter will be present in col 1 & col 2
; Related .......: StringSplit
; Link ..........: bit.ly/ArraySplitForAutoIt
; Example .......: Yes
; ===============================================================================================================================
Func ArraySplit(ByRef $aArray, $sDelimiter)
    If Not IsArray($aArray) Then Return SetError(1, 0, 1) ; The statment itself states what it does 
    $iArrayLen = Ubound($aArray) ; We need Array's length (or no. of elements)
    Local $aReturn[$iArrayLen][2] ; Delare a 2D Array with 2 coloumns for returning
    For $i = 0 To $iArrayLen - 1 ; Loop through Array
        $aTempArray = StringSplit($aArray[$i], $sDelimiter, $STR_ENTIRESPLIT) ; StringSplit the string & store it in an array
        If $aTempArray[0] = 1 Then Return SetError(2, $i, 0)
        $aReturn[$i][0] = $aTempArray[1] ; Put the first string in Coloumn 0
        $aReturn[$i][1] = $aTempArray[2] ; Put the second string in Coloumn 1
    Next
    Return $aReturn ; Return the Array 
EndFunc

; Example

Local $aArray[3] = ["x=1", "y=2", "z=3"] ; Declare the Array
$aArray = ArraySplit($aArray, '=') ; Convert an 1D Array to an 2D Array based on a delimiter
_ArrayDisplay($aArray) ; Display the array 

#cs ---------------------- Visual example ----------------------

This is our $aArray:

    |    Data     |
-----------------------
0.  |   "x=1"     |
-----------------------
1.  |   "y=2"     |
-----------------------
2.  |   "z=3"     |
-----------------------

This is our $aArray after ArraySplit (with delimiter as "=" (Equal Sign)):

    |  Column 0  | Column 1 |
---------------------------------
0.  |    "x"      |     1     |
---------------------------------
1.  |    "y"      |     2     |
---------------------------------
2.  |    "z"      |     3     |
---------------------------------

#ce ---------------------- Visual example ----------------------

Hope you may find it useful, TD

Edited October 20, 2015 by TheDcoder
Added "Error Checking" & Minor Improvements, TD :D

[guinness]

Great. Array UDF has this by the way if people are interested.