Problem with _GUICtrlIpAddress_Create

[vickerps]

Hi Guys

Im trying to create a script that allow someone to enter a number of ip adresses.

when i use _GUICtrlIpAddress_Create on the 17th address the box disappears from the sub form.

Anyone tell me why this is?

expandcollapse popup

;Include Functions
#Include <GuiIPAddress.au3>
#INCLUDE <GUIConstants.au3>
#include <Array.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>
#include <ListviewConstants.au3>
Global $Avarray[30],$I_IP
$BMP = @ScriptDir & "\BackGround.bmp"
$TextColour = "0x000000"
$POSTotal = 20
$n=1
Opt("GUICoordMode",1)
$F = GuiCreate("Torex",@DesktopWidth,@DesktopHeight,0,0,$WS_SYSMENU,$WS_EX_TOPMOST)
GUICtrlCreatePic ($BMP,0,0,@DesktopWidth,@DesktopHeight)
GUICtrlSetState(-1,$GUI_DISABLE)

$E_Nodes_IPs = GUICtrlCreateListView("                      |                      ",60,210,295,450,$LVS_NOCOLUMNHEADER+$LVS_NOSORTHEADER)
  GUICtrlSetFont(-1,12)
  GUISetState(@SW_SHOW,$F)
   
  IF $n < $postotal Then
   Do
    Subform($n)
    $AVarray[$n] = GUICtrlCreateListViewItem($n & "|" & _GUICtrlIpAddress_Get($I_IP),$E_Nodes_IPs)
    ;$AVarray[$n] = GUICtrlCreateListViewItem("Till" & $n & "|" & GUICtrlRead($I_IP), $E_Nodes_IPs)
    $n = $n +1
   until $n > $POSTotal
  endif
Func Subform($x)
GUISetState(@SW_DISABLE,$F)

$SubF = GuiCreate("Manual Setup",400 ,200,500,230,$DS_CONTEXTHELP,$WS_EX_TOPMOST)
  GUICtrlCreatePic ($BMP,0,0,400,200)
   GUICtrlSetState(-1,$GUI_DISABLE)
  $Lbl_Message = GUICtrlCreateLabel($x ,10,10,390,20)
   GUICtrlSetBkColor(-1,$GUI_BKCOLOR_TRANSPARENT)
   GUICtrlSetFont(-1,12)
   GUICtrlSetColor (-1,$TextColour)
 
  $Lbl_IP = GUICtrlCreateLabel("IP address:",10,60,130,20)
   GUICtrlSetBkColor(-1,$GUI_BKCOLOR_TRANSPARENT)
   GUICtrlSetFont(-1,12)
   GUICtrlSetColor (-1,$TextColour)

  $I_IP = _GUICtrlIpAddress_Create ($SubF,140,60,110,20)
  ;$I_IP = GUICtrlCreateInput("",140,60,110,20)
   GUICtrlSetLimit(-1,15)
   GUICtrlSetFont(-1,10)

  $B_OK = GUICtrlCreateButton("&OK",300,137,90,35)

  GUISetState(@SW_SHOW,$SubF)
 
   While 1
    $Msg=GUIGetMsg()
  
    Switch $Msg
     Case $B_OK
       ExitLoop
    EndSwitch
   Wend
   
  GUISetState(@SW_HIDE,$SubF)
  GUISetState(@SW_ENABLE,$F)
ENdfunc

[BrewManNH]

It's because you're recreating the GUI for the sub form every time you loop through the Do loop. You should either move the GUI creation out of the function, or delete the GUI after the function finishes, or just don't use a separate GUI just to add an IP address control. Here's how to do it using GUIDelete and your code modified.

expandcollapse popup

;Include Functions
#include <GuiIPAddress.au3>
#include <GUIConstants.au3>
#include <Array.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>
#include <ListviewConstants.au3>
Global $Avarray[30], $I_IP
Global $SubF
$BMP = @ScriptDir & "BackGround.bmp"
$TextColour = "0x000000"
$POSTotal = 20
$n = 1
Opt("GUICoordMode", 1)
$F = GUICreate("Torex", @DesktopWidth, @DesktopHeight, 0, 0, $WS_SYSMENU, $WS_EX_TOPMOST)
GUICtrlCreatePic($BMP, 0, 0, @DesktopWidth, @DesktopHeight)
GUICtrlSetState(-1, $GUI_DISABLE)
$E_Nodes_IPs = GUICtrlCreateListView("                    |                   ", 60, 210, 295, 450, $LVS_NOCOLUMNHEADER + $LVS_NOSORTHEADER)
GUICtrlSetFont(-1, 12)
GUISetState(@SW_SHOW, $F)
If $n < $POSTotal Then
    Do
        Subform($n)
        $Avarray[$n] = GUICtrlCreateListViewItem($n & "|" & _GUICtrlIpAddress_Get($I_IP), $E_Nodes_IPs)
        ;$AVarray[$n] = GUICtrlCreateListViewItem("Till" & $n & "|" & GUICtrlRead($I_IP), $E_Nodes_IPs)
        $n = $n + 1
        GUIDelete($SubF)
    Until $n > $POSTotal
EndIf
Func Subform($x)
    GUISetState(@SW_DISABLE, $F)
    $SubF = GUICreate("Manual Setup", 400, 200, 500, 230, $DS_CONTEXTHELP, $WS_EX_TOPMOST)
    GUICtrlCreatePic($BMP, 0, 0, 400, 200)
    GUICtrlSetState(-1, $GUI_DISABLE)
    $Lbl_Message = GUICtrlCreateLabel($x, 10, 10, 390, 20)
    GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
    GUICtrlSetFont(-1, 12)
    GUICtrlSetColor(-1, $TextColour)
    $Lbl_IP = GUICtrlCreateLabel("IP address:", 10, 60, 130, 20)
    GUICtrlSetBkColor(-1, $GUI_BKCOLOR_TRANSPARENT)
    GUICtrlSetFont(-1, 12)
    GUICtrlSetColor(-1, $TextColour)
    $I_IP = _GUICtrlIpAddress_Create($SubF, 140, 60, 110, 20)
    ;$I_IP = GUICtrlCreateInput("",140,60,110,20)
    GUICtrlSetLimit(-1, 15)
    GUICtrlSetFont(-1, 10)
    $B_OK = GUICtrlCreateButton("&OK", 300, 137, 90, 35)
    GUISetState(@SW_SHOW, $SubF)
    While 1
        $Msg = GUIGetMsg()
        Switch $Msg
            Case $B_OK
                ExitLoop
        EndSwitch
    WEnd
    GUISetState(@SW_ENABLE, $F)
EndFunc   ;==>Subform