Disabling a group

[am632]

Hi,

Just a small problem I would like to know is how do you disable a group and its contents?

Here is my code,

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
$Form1 = GUICreate("Form1", 523, 220, 192, 124)
GUISetState(@SW_SHOW)
$Group1 = GUICtrlCreateGroup("Group1", 32, 24, 193, 129)
$Radio1 = GUICtrlCreateRadio("Radio1", 64, 56, 113, 17)
$Radio2 = GUICtrlCreateRadio("Radio2", 64, 80, 113, 17)
GUICtrlCreateGroup("", -99, -99, 1, 1)
$Group2 = GUICtrlCreateGroup("Group2", 288, 24, 193, 129)
$Radio3 = GUICtrlCreateRadio("Radio3", 320, 56, 113, 17)
$Radio4 = GUICtrlCreateRadio("Radio4", 320, 80, 113, 17)
GUICtrlCreateGroup("", -99, -99, 1, 1)
GUICtrlSetState($Group2,@SW_DISABLE)

While 1
$nMsg = GUIGetMsg()
Switch $nMsg
  Case $GUI_EVENT_CLOSE
   Exit
EndSwitch
WEnd

I thought it was just the 'GUICtrlSetState($Group2,@SW_DISABLE)' but its not doing anything. Id like the group to be grayed out as default which I can re-enable later in the script as necessary.

Thanks

[BrewManNH]

The Group in the above example is just a control, it doesn't actually group the controls under it the way you are thinking. It does group the radio buttons contained within it, but you can't disable them all at the same time by disabling the group control. You have to disable all of the controls individually, one at a time.

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
$Form1 = GUICreate("Form1", 523, 220, 192, 124)
GUISetState(@SW_SHOW)
$Group1 = GUICtrlCreateGroup("Group1", 32, 24, 193, 129)
$Radio1 = GUICtrlCreateRadio("Radio1", 64, 56, 113, 17)
$Radio2 = GUICtrlCreateRadio("Radio2", 64, 80, 113, 17)
GUICtrlCreateGroup("", -99, -99, 1, 1)
$Group2 = GUICtrlCreateGroup("Group2", 288, 24, 193, 129)
$Radio3 = GUICtrlCreateRadio("Radio3", 320, 56, 113, 17)
$Radio4 = GUICtrlCreateRadio("Radio4", 320, 80, 113, 17)
GUICtrlCreateGroup("", -99, -99, 1, 1)
;~ GUICtrlSetState($Group2,@SW_DISABLE)
For $I = $Radio1 To $Radio2
    GUICtrlSetState($I, $GUI_DISABLE) ; $GUI_DISABLE is needed to disable the control
Next

While 1
$nMsg = GUIGetMsg()
Switch $nMsg
  Case $GUI_EVENT_CLOSE
   Exit
EndSwitch
WEnd

EDIT: Want to clarify something. I used the controlIDs in the For/Next loop the way I did because they're created in sequence, if there were other controls in between these radio buttons, I'd have to do it another way.

Edited April 20, 2012 by BrewManNH

[am632]

ah right I see, thanks v much for your help